content/browser/tracing/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//tools/grit/grit_rule.gni")
   6
   7 # generate_about_tracing puts its files in this directory
   8 tracing_gen_dir = "$root_gen_dir/content/browser/tracing"
   9
  10 # The script just writes filename with no dirs to the .grd, so we always need
  11 # this file to be in the same directory as the inputs.
  12 tracing_grd = "$tracing_gen_dir/tracing_resources.grd"
  13
  14 action("generate_tracing_grd") {
  15   visibility = [ ":*" ]
  16   script = "generate_trace_viewer_grd.py"
  17
  18   input_pages = [
  19     "$tracing_gen_dir/about_tracing.html",
  20     "$tracing_gen_dir/about_tracing.js",
  21   ]
  22   inputs = input_pages
  23   outputs = [
  24     tracing_grd,
  25   ]
  26
  27   args = rebase_path(input_pages, target_gen_dir) + [
  28            "--output",
  29            rebase_path(tracing_grd, root_build_dir),
  30          ]
  31
  32   deps = [
  33     "//third_party/trace-viewer:generate_about_tracing",
  34   ]
  35 }
  36
  37 grit("resources") {
  38   source = tracing_grd
  39   outputs = [
  40     "grit/tracing_resources.h",
  41     "tracing_resources.pak",
  42   ]
  43
  44   # resource_ids has an entry for our .grd file that looks like:
  45   # "<(SHARED_INTERMEDIATE_DIR)/content/browser/tracing/tracing_resources.grd"
  46   # and what we pass here should make that resolve to our .grd file.
  47   defines =
  48       [ "SHARED_INTERMEDIATE_DIR=" + rebase_path(root_gen_dir, root_build_dir) ]
  49
  50   deps = [
  51     ":generate_tracing_grd",
  52   ]
  53 }