base/test/test_support_ios.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import <UIKit/UIKit.h>
   6
   7 #include "base/debug/debugger.h"
   8 #include "base/logging.h"
   9 #include "base/mac/scoped_nsautorelease_pool.h"
  10 #include "base/mac/scoped_nsobject.h"
  11 #include "base/message_loop/message_loop.h"
  12 #include "base/message_loop/message_pump_default.h"
  13 #include "base/test/test_suite.h"
  14 #include "testing/coverage_util_ios.h"
  15
  16 // Springboard will kill any iOS app that fails to check in after launch within
  17 // a given time. Starting a UIApplication before invoking TestSuite::Run
  18 // prevents this from happening.
  19
  20 // InitIOSRunHook saves the TestSuite and argc/argv, then invoking
  21 // RunTestsFromIOSApp calls UIApplicationMain(), providing an application
  22 // delegate class: ChromeUnitTestDelegate. The delegate implements
  23 // application:didFinishLaunchingWithOptions: to invoke the TestSuite's Run
  24 // method.
  25
  26 // Since the executable isn't likely to be a real iOS UI, the delegate puts up a
  27 // window displaying the app name. If a bunch of apps using MainHook are being
  28 // run in a row, this provides an indication of which one is currently running.
  29
  30 static base::TestSuite* g_test_suite = NULL;
  31 static int g_argc;
  32 static char** g_argv;
  33
  34 @interface UIApplication (Testing)
  35 - (void) _terminateWithStatus:(int)status;
  36 @end
  37
  38 #if TARGET_IPHONE_SIMULATOR
  39 // Xcode 6 introduced behavior in the iOS Simulator where the software
  40 // keyboard does not appear if a hardware keyboard is connected. The following
  41 // declaration allows this behavior to be overriden when the app starts up.
  42 @interface UIKeyboardImpl
  43 + (instancetype)sharedInstance;
  44 - (void)setAutomaticMinimizationEnabled:(BOOL)enabled;
  45 - (void)setSoftwareKeyboardShownByTouch:(BOOL)enabled;
  46 @end
  47 #endif  // TARGET_IPHONE_SIMULATOR
  48
  49 @interface ChromeUnitTestDelegate : NSObject {
  50  @private
  51   base::scoped_nsobject<UIWindow> window_;
  52 }
  53 - (void)runTests;
  54 @end
  55
  56 @implementation ChromeUnitTestDelegate
  57
  58 - (BOOL)application:(UIApplication *)application
  59     didFinishLaunchingWithOptions:(NSDictionary *)launchOptions {
  60
  61 #if TARGET_IPHONE_SIMULATOR
  62   // Xcode 6 introduced behavior in the iOS Simulator where the software
  63   // keyboard does not appear if a hardware keyboard is connected. The following
  64   // calls override this behavior by ensuring that the software keyboard is
  65   // always shown.
  66   [[UIKeyboardImpl sharedInstance] setAutomaticMinimizationEnabled:NO];
  67   [[UIKeyboardImpl sharedInstance] setSoftwareKeyboardShownByTouch:YES];
  68 #endif  // TARGET_IPHONE_SIMULATOR
  69
  70   CGRect bounds = [[UIScreen mainScreen] bounds];
  71
  72   // Yes, this is leaked, it's just to make what's running visible.
  73   window_.reset([[UIWindow alloc] initWithFrame:bounds]);
  74   [window_ setBackgroundColor:[UIColor whiteColor]];
  75   [window_ makeKeyAndVisible];
  76
  77   // Add a label with the app name.
  78   UILabel* label = [[[UILabel alloc] initWithFrame:bounds] autorelease];
  79   label.text = [[NSProcessInfo processInfo] processName];
  80   label.textAlignment = NSTextAlignmentCenter;
  81   [window_ addSubview:label];
  82
  83   if ([self shouldRedirectOutputToFile])
  84     [self redirectOutput];
  85
  86   // Queue up the test run.
  87   [self performSelector:@selector(runTests)
  88              withObject:nil
  89              afterDelay:0.1];
  90   return YES;
  91 }
  92
  93 // Returns true if the gtest output should be redirected to a file, then sent
  94 // to NSLog when compleete. This redirection is used because gtest only writes
  95 // output to stdout, but results must be written to NSLog in order to show up in
  96 // the device log that is retrieved from the device by the host.
  97 - (BOOL)shouldRedirectOutputToFile {
  98 #if !TARGET_IPHONE_SIMULATOR
  99   return !base::debug::BeingDebugged();
 100 #endif  // TARGET_IPHONE_SIMULATOR
 101   return NO;
 102 }
 103
 104 // Returns the path to the directory to store gtest output files.
 105 - (NSString*)outputPath {
 106   NSArray* searchPath =
 107       NSSearchPathForDirectoriesInDomains(NSDocumentDirectory,
 108                                           NSUserDomainMask,
 109                                           YES);
 110   CHECK([searchPath count] > 0) << "Failed to get the Documents folder";
 111   return [searchPath objectAtIndex:0];
 112 }
 113
 114 // Returns the path to file that stdout is redirected to.
 115 - (NSString*)stdoutPath {
 116   return [[self outputPath] stringByAppendingPathComponent:@"stdout.log"];
 117 }
 118
 119 // Returns the path to file that stderr is redirected to.
 120 - (NSString*)stderrPath {
 121   return [[self outputPath] stringByAppendingPathComponent:@"stderr.log"];
 122 }
 123
 124 // Redirects stdout and stderr to files in the Documents folder in the app's
 125 // sandbox.
 126 - (void)redirectOutput {
 127   freopen([[self stdoutPath] UTF8String], "w+", stdout);
 128   freopen([[self stderrPath] UTF8String], "w+", stderr);
 129 }
 130
 131 // Reads the redirected gtest output from a file and writes it to NSLog.
 132 - (void)writeOutputToNSLog {
 133   // Close the redirected stdout and stderr files so that the content written to
 134   // NSLog doesn't end up in these files.
 135   fclose(stdout);
 136   fclose(stderr);
 137   for (NSString* path in @[ [self stdoutPath], [self stderrPath]]) {
 138     NSString* content = [NSString stringWithContentsOfFile:path
 139                                                   encoding:NSUTF8StringEncoding
 140                                                      error:NULL];
 141     NSArray* lines = [content componentsSeparatedByCharactersInSet:
 142         [NSCharacterSet newlineCharacterSet]];
 143
 144     NSLog(@"Writing contents of %@ to NSLog", path);
 145     for (NSString* line in lines) {
 146       NSLog(@"%@", line);
 147     }
 148   }
 149 }
 150
 151 - (void)runTests {
 152   int exitStatus = g_test_suite->Run();
 153
 154   if ([self shouldRedirectOutputToFile])
 155     [self writeOutputToNSLog];
 156
 157   // If a test app is too fast, it will exit before Instruments has has a
 158   // a chance to initialize and no test results will be seen.
 159   // TODO(ios): crbug.com/137010 Figure out how much time is actually needed,
 160   // and sleep only to make sure that much time has elapsed since launch.
 161   [NSThread sleepUntilDate:[NSDate dateWithTimeIntervalSinceNow:2.0]];
 162   window_.reset();
 163
 164   // Use the hidden selector to try and cleanly take down the app (otherwise
 165   // things can think the app crashed even on a zero exit status).
 166   UIApplication* application = [UIApplication sharedApplication];
 167   [application _terminateWithStatus:exitStatus];
 168
 169   coverage_util::FlushCoverageDataIfNecessary();
 170
 171   exit(exitStatus);
 172 }
 173
 174 @end
 175
 176 namespace {
 177
 178 scoped_ptr<base::MessagePump> CreateMessagePumpForUIForTests() {
 179   // A default MessagePump will do quite nicely in tests.
 180   return scoped_ptr<base::MessagePump>(new base::MessagePumpDefault());
 181 }
 182
 183 }  // namespace
 184
 185 namespace base {
 186
 187 void InitIOSTestMessageLoop() {
 188   MessageLoop::InitMessagePumpForUIFactory(&CreateMessagePumpForUIForTests);
 189 }
 190
 191 void InitIOSRunHook(TestSuite* suite, int argc, char* argv[]) {
 192   g_test_suite = suite;
 193   g_argc = argc;
 194   g_argv = argv;
 195 }
 196
 197 void RunTestsFromIOSApp() {
 198   // When TestSuite::Run is invoked it calls RunTestsFromIOSApp(). On the first
 199   // invocation, this method fires up an iOS app via UIApplicationMain. Since
 200   // UIApplicationMain does not return until the app exits, control does not
 201   // return to the initial TestSuite::Run invocation, so the app invokes
 202   // TestSuite::Run a second time and since |ran_hook| is true at this point,
 203   // this method is a no-op and control returns to TestSuite:Run so that test
 204   // are executed. Once the app exits, RunTestsFromIOSApp calls exit() so that
 205   // control is not returned to the initial invocation of TestSuite::Run.
 206   static bool ran_hook = false;
 207   if (!ran_hook) {
 208     ran_hook = true;
 209     mac::ScopedNSAutoreleasePool pool;
 210     int exit_status = UIApplicationMain(g_argc, g_argv, nil,
 211                                         @"ChromeUnitTestDelegate");
 212     exit(exit_status);
 213   }
 214 }
 215
 216 }  // namespace base