| blob | 412c421ec29d9f88184fd28ce540ddf15a96fa7d |
1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
2 # Use of this source code is governed by a BSD-style license that can be
3 # found in the LICENSE file.
5 import("//build/config/android/config.gni")
6 import("//build/config/chrome_build.gni")
7 if (current_cpu == "arm") {
8 import("//build/config/arm.gni")
9 }
10 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
11 import("//build/config/mips.gni")
12 }
13 if (is_posix) {
14 import("//build/config/gcc/gcc_version.gni")
15 }
16 if (is_win) {
17 import("//build/config/win/visual_studio_version.gni")
18 }
20 import("//build/toolchain/ccache.gni")
21 import("//build/config/sanitizers/sanitizers.gni")
23 declare_args() {
24 # Normally, Android builds are lightly optimized, even for debug builds, to
25 # keep binary size down. Setting this flag to true disables such optimization
26 android_full_debug = false
28 # Whether to use the binary binutils checked into third_party/binutils.
29 # These are not multi-arch so cannot be used except on x86 and x86-64 (the
30 # only two architectures that are currently checked in). Turn this off when
31 # you are using a custom toolchain and need to control -B in cflags.
32 linux_use_bundled_binutils = is_linux && current_cpu == "x64"
33 binutils_path = rebase_path("//third_party/binutils/Linux_x64/Release/bin",
34 root_build_dir)
36 # Compile in such a way as to enable profiling of the generated code. For
37 # example, don't omit the frame pointer and leave in symbols.
38 enable_profiling = false
40 # Compile in such a way as to make it possible for the profiler to unwind full
41 # stack frames. Setting this flag has a large effect on the performance of the
42 # generated code than just setting profiling, but gives the profiler more
43 # information to analyze.
44 # Requires profiling to be set to true.
45 enable_full_stack_frames_for_profiling = false
47 # Use gold for linking on 64-bit Linux only (on 32-bit it runs out of
48 # address space, and it doesn't support cross-compiling).
49 use_gold = is_linux && current_cpu == "x64"
51 # When we are going to use gold we need to find it.
52 if (use_gold) {
53 gold_path = rebase_path("//third_party/binutils/Linux_x64/Release/bin",
54 root_build_dir)
55 } else {
56 gold_path = ""
57 }
59 # use_debug_fission: whether to use split DWARF debug info
60 # files. This can reduce link time significantly, but is incompatible
61 # with some utilities such as icecc and ccache. Requires gold and
62 # gcc >= 4.8 or clang.
63 # http://gcc.gnu.org/wiki/DebugFission
64 use_debug_fission = is_debug && !is_win && use_gold &&
65 linux_use_bundled_binutils && !use_ccache
67 if (is_win) {
68 # Whether the VS xtree header has been patched to disable warning 4702. If
69 # it has, then we don't need to disable 4702 (unreachable code warning).
70 # The patch is preapplied to the internal toolchain and hence all bots.
71 msvs_xtree_patched = false
72 }
73 }
75 # default_include_dirs ---------------------------------------------------------
76 #
77 # This is a separate config so that third_party code (which would not use the
78 # source root and might have conflicting versions of some headers) can remove
79 # this and specify their own include paths.
80 config("default_include_dirs") {
81 include_dirs = [
82 "//",
83 root_gen_dir,
84 ]
85 }
87 # TODO(GYP): is_ubsan, is_ubsan_vptr
88 if (!is_win) {
89 using_sanitizer = is_asan || is_lsan || is_tsan || is_msan
90 }
92 # compiler ---------------------------------------------------------------------
93 #
94 # Base compiler configuration.
95 #
96 # See also "runtime_library" below for related stuff and a discussion about
97 # where stuff should go. Put warning related stuff in the "warnings" config.
99 config("compiler") {
100 cflags = []
101 cflags_c = []
102 cflags_cc = []
103 cflags_objc = []
104 cflags_objcc = []
105 ldflags = []
106 defines = []
108 # In general, Windows is totally different, but all the other builds share
109 # some common GCC configuration. This section sets up Windows and the common
110 # GCC flags, and then we handle the other non-Windows platforms specifically
111 # below.
112 if (is_win) {
113 # Windows compiler flags setup.
114 # -----------------------------
115 cflags += [
116 "/Gy", # Enable function-level linking.
117 "/GS", # Enable buffer security checking.
118 "/FS", # Preserve previous PDB behavior.
119 "/bigobj", # Some of our files are bigger than the regular limits.
120 ]
122 # Force C/C++ mode for the given GN detected file type. This is necessary
123 # for precompiled headers where the same source file is compiled in both
124 # modes.
125 cflags_c += [ "/TC" ]
126 cflags_cc += [ "/TP" ]
128 # Building with Clang on Windows is a work in progress and very
129 # experimental. See crbug.com/82385.
130 # Keep this in sync with the similar block in build/common.gypi
131 if (is_clang) {
132 cflags += [
133 # Many files use intrinsics without including this header.
134 # TODO(hans): Fix those files, or move this to sub-GYPs.
135 "/FIIntrin.h",
136 ]
138 if (visual_studio_version == "2013") {
139 cflags += [ "-fmsc-version=1800" ]
140 } else if (visual_studio_version == "2015") {
141 cflags += [ "-fmsc-version=1900" ]
142 }
144 if (current_cpu == "x86") {
145 cflags += [ "-m32" ]
146 } else {
147 cflags += [ "-m64" ]
148 }
150 if (exec_script("//build/win/use_ansi_codes.py", [], "trim string") ==
151 "True") {
152 cflags += [
153 # cmd.exe doesn't understand ANSI escape codes by default,
154 # so only enable them if something emulating them is around.
155 "-fansi-escape-codes",
156 ]
157 }
158 }
160 if (is_syzyasan) {
161 # SyzyAsan needs /PROFILE turned on to produce appropriate pdbs.
162 assert(!is_win_fastlink, "/PROFILE and /DEBUG:FASTLINK are incompatible")
163 ldflags += [ "/PROFILE" ]
164 }
165 } else {
166 # Common GCC compiler flags setup.
167 # --------------------------------
168 cflags += [ "-fno-strict-aliasing" ] # See http://crbug.com/32204
169 cflags_cc += [
170 "-fno-threadsafe-statics",
172 # Not exporting C++ inline functions can generally be applied anywhere
173 # so we do so here. Normal function visibility is controlled by
174 # //build/config/gcc:symbol_visibility_hidden.
175 "-fvisibility-inlines-hidden",
176 ]
178 # Stack protection.
179 if (is_mac) {
180 cflags += [ "-fstack-protector-all" ]
181 } else if (is_posix && !is_chromeos && !is_nacl) {
182 # TODO(phajdan.jr): Use -fstack-protector-strong when our gcc supports it.
183 cflags += [ "--param=ssp-buffer-size=4" ]
184 if (is_android && (current_cpu == "arm64" || current_cpu == "x86")) {
185 cflags += [ "-fno-stack-protector" ]
186 } else {
187 cflags += [ "-fstack-protector" ]
188 }
189 }
191 # Linker warnings.
192 if (!(is_chromeos && current_cpu == "arm") && !is_mac && !is_ios) {
193 # TODO(jochen): Enable this on chromeos on arm. http://crbug.com/356580
194 ldflags += [ "-Wl,--fatal-warnings" ]
195 }
197 # Common options for AddressSanitizer, LeakSanitizer, ThreadSanitizer and
198 # MemorySanitizer
199 if (using_sanitizer) {
200 cflags += [
201 "-fno-omit-frame-pointer",
202 "-gline-tables-only",
203 ]
204 }
205 if (is_asan) {
206 asan_blacklist_path =
207 rebase_path("//tools/memory/asan/blacklist.txt", root_build_dir)
208 cflags += [
209 "-fsanitize=address",
210 "-fsanitize-blacklist=$asan_blacklist_path",
211 ]
212 if (is_mac) {
213 cflags += [ "-mllvm -asan-globals=0" ] # http://crbug.com/352073
214 # TODO(GYP): deal with mac_bundles.
215 }
216 }
217 if (is_lsan) {
218 cflags += [ "-fsanitize=leak" ]
219 }
220 if (is_tsan) {
221 tsan_blacklist_path =
222 rebase_path("//tools/memory/tsan_v2/ignores.txt", root_build_dir)
223 cflags += [
224 "-fsanitize=thread",
225 "-fsanitize-blacklist=$tsan_blacklist_path",
226 ]
227 }
228 if (is_msan) {
229 msan_blacklist_path =
230 rebase_path("//tools/msan/blacklist.txt", root_build_dir)
231 cflags += [
232 "-fsanitize=memory",
233 "-fsanitize-memory-track-origins=$msan_track_origins",
234 "-fsanitize-blacklist=$msan_blacklist_path",
235 ]
236 }
238 if (use_custom_libcxx) {
239 cflags_cc += [ "-nostdinc++" ]
240 include_dirs = [
241 "//buildtools/third_party/libc++/trunk/include",
242 "//buildtools/third_party/libc++abi/trunk/include",
243 ]
244 }
245 }
247 if (is_clang && is_debug) {
248 # Allow comparing the address of references and 'this' against 0
249 # in debug builds. Technically, these can never be null in
250 # well-defined C/C++ and Clang can optimize such checks away in
251 # release builds, but they may be used in asserts in debug builds.
252 cflags_cc += [
253 "-Wno-undefined-bool-conversion",
254 "-Wno-tautological-undefined-compare",
255 ]
256 }
258 if (is_clang && !is_nacl) {
259 # This is here so that all files get recompiled after a clang roll and
260 # when turning clang on or off. (defines are passed via the command line,
261 # and build system rebuild things when their commandline changes). Nothing
262 # should ever read this define.
263 defines +=
264 [ "CR_CLANG_REVISION=" + exec_script("//tools/clang/scripts/update.py",
265 [ "--print-revision" ],
266 "trim string") ]
267 }
269 # Mac-specific compiler flags setup.
270 # ----------------------------------
271 if (is_mac || is_ios) {
272 # These flags are shared between the C compiler and linker.
273 common_mac_flags = []
275 # CPU architecture.
276 if (current_cpu == "x64") {
277 common_mac_flags += [
278 "-arch",
279 "x86_64",
280 ]
281 } else if (current_cpu == "x86") {
282 common_mac_flags += [
283 "-arch",
284 "i386",
285 ]
286 } else if (current_cpu == "arm") {
287 # TODO(GYP): we may need to distinguish between "arm64", "armv7",
288 # and "armv7s" for iOS, and hence need multiple current_cpu values
289 # rather than just "arm".
290 common_mac_flags += [
291 "-arch",
292 "arm64",
293 ]
294 }
296 cflags += common_mac_flags
298 # Without this, the constructors and destructors of a C++ object inside
299 # an Objective C struct won't be called, which is very bad.
300 cflags_objcc += [ "-fobjc-call-cxx-cdtors" ]
302 cflags_c += [ "-std=c99" ]
304 ldflags += common_mac_flags
305 } else if (is_posix) {
306 # Non-Mac Posix compiler flags setup.
307 # -----------------------------------
308 if (enable_profiling && !is_debug) {
309 # The GYP build spams this define into every compilation unit, as we do
310 # here, but it only appears to be used in base and a couple other places.
311 # TODO(abarth): Should we move this define closer to where it's used?
312 defines += [ "ENABLE_PROFILING" ]
314 cflags += [
315 "-fno-omit-frame-pointer",
316 "-g",
317 ]
319 if (enable_full_stack_frames_for_profiling) {
320 cflags += [
321 "-fno-inline",
322 "-fno-optimize-sibling-calls",
323 ]
324 }
325 }
327 # CPU architecture. We may or may not be doing a cross compile now, so for
328 # simplicity we always explicitly set the architecture.
329 if (current_cpu == "x64") {
330 cflags += [
331 "-m64",
332 "-march=x86-64",
333 ]
334 ldflags += [ "-m64" ]
335 } else if (current_cpu == "x86") {
336 cflags += [ "-m32" ]
337 ldflags += [ "-m32" ]
338 if (is_clang) {
339 cflags += [
340 # Else building libyuv gives clang's register allocator issues,
341 # see llvm.org/PR15798 / crbug.com/233709
342 "-momit-leaf-frame-pointer",
344 # Align the stack on 16-byte boundaries, http://crbug.com/418554.
345 "-mstack-alignment=16",
346 "-mstackrealign",
347 ]
348 }
349 } else if (current_cpu == "arm") {
350 cflags += [
351 "-march=$arm_arch",
352 "-mfloat-abi=$arm_float_abi",
353 ]
354 if (arm_tune != "") {
355 cflags += [ "-mtune=$arm_tune" ]
356 }
357 if (arm_use_thumb) {
358 cflags += [ "-mthumb" ]
359 if (is_android && !is_clang) { # Clang doesn't support this option.
360 cflags += [ "-mthumb-interwork" ]
361 }
362 }
363 if (!is_clang) {
364 # Clang doesn't support these flags.
365 cflags += [
366 # The tree-sra optimization (scalar replacement for
367 # aggregates enabling subsequent optimizations) leads to
368 # invalid code generation when using the Android NDK's
369 # compiler (r5-r7). This can be verified using
370 # webkit_unit_tests' WTF.Checked_int8_t test.
371 "-fno-tree-sra",
373 # The following option is disabled to improve binary
374 # size and performance in gcc 4.9.
375 "-fno-caller-saves",
376 ]
377 }
378 } else if (current_cpu == "mipsel") {
379 if (mips_arch_variant == "r6") {
380 cflags += [
381 "-mips32r6",
382 "-Wa,-mips32r6",
383 ]
384 if (is_android) {
385 ldflags += [
386 "-mips32r6",
387 "-Wl,-melf32ltsmip",
388 ]
389 }
390 } else if (mips_arch_variant == "r2") {
391 cflags += [
392 "-mips32r2",
393 "-Wa,-mips32r2",
394 ]
395 if (mips_float_abi == "hard" && mips_fpu_mode != "") {
396 cflags += [ "-m$mips_fpu_mode" ]
397 }
398 } else if (mips_arch_variant == "r1") {
399 cflags += [
400 "-mips32",
401 "-Wa,-mips32",
402 ]
403 }
405 if (mips_dsp_rev == 1) {
406 cflags += [ "-mdsp" ]
407 } else if (mips_dsp_rev == 2) {
408 cflags += [ "-mdspr2" ]
409 }
411 cflags += [ "-m${mips_float_abi}-float" ]
412 } else if (current_cpu == "mips64el") {
413 if (mips_arch_variant == "r6") {
414 cflags += [
415 "-mips64r6",
416 "-Wa,-mips64r6",
417 ]
418 ldflags += [ "-mips64r6" ]
419 } else if (mips_arch_variant == "r2") {
420 cflags += [
421 "-mips64r2",
422 "-Wa,-mips64r2",
423 ]
424 ldflags += [ "-mips64r2" ]
425 }
426 }
428 defines += [ "_FILE_OFFSET_BITS=64" ]
430 if (!is_android) {
431 defines += [
432 "_LARGEFILE_SOURCE",
433 "_LARGEFILE64_SOURCE",
434 ]
435 }
437 # Omit unwind support in official builds to save space. We can use breakpad
438 # for these builds.
439 if (is_chrome_branded && is_official_build) {
440 cflags += [
441 "-fno-unwind-tables",
442 "-fno-asynchronous-unwind-tables",
443 ]
444 defines += [ "NO_UNWIND_TABLES" ]
445 } else {
446 cflags += [ "-funwind-tables" ]
447 }
448 }
450 # Linux/Android common flags setup.
451 # ---------------------------------
452 if (is_linux || is_android) {
453 cflags += [
454 "-fPIC",
455 "-pipe", # Use pipes for communicating between sub-processes. Faster.
456 ]
458 ldflags += [
459 "-fPIC",
460 "-Wl,-z,noexecstack",
461 "-Wl,-z,now",
462 "-Wl,-z,relro",
463 ]
464 if (!using_sanitizer) {
465 ldflags += [ "-Wl,-z,defs" ]
466 }
467 }
469 # Linux-specific compiler flags setup.
470 # ------------------------------------
471 if (is_linux) {
472 cflags += [ "-pthread" ]
473 ldflags += [ "-pthread" ]
474 }
475 if (use_gold) {
476 ldflags += [
477 "-B$gold_path",
479 # Newer gccs and clangs support -fuse-ld, use the flag to force gold
480 # selection.
481 # gcc -- http://gcc.gnu.org/onlinedocs/gcc-4.8.0/gcc/Optimize-Options.html
482 "-fuse-ld=gold",
484 # Experimentation found that using four linking threads
485 # saved ~20% of link time.
486 # https://groups.google.com/a/chromium.org/group/chromium-dev/browse_thread/thread/281527606915bb36
487 # Only apply this to the target linker, since the host
488 # linker might not be gold, but isn't used much anyway.
489 # TODO(raymes): Disable threading because gold is frequently
490 # crashing on the bots: crbug.com/161942.
491 #"-Wl,--threads",
492 #"-Wl,--thread-count=4",
493 ]
495 if (!is_asan && !is_msan && !is_lsan && !is_tsan) {
496 # TODO(brettw) common.gypi has this only for target toolset.
497 ldflags += [ "-Wl,--icf=all" ]
498 }
500 # TODO(thestig): Make this flag work with GN.
501 #if (!is_official_build && !is_chromeos && !(is_asan || is_lsan || is_tsan || is_msan)) {
502 # ldflags += [
503 # "-Wl,--detect-odr-violations",
504 # ]
505 #}
506 }
508 if (linux_use_bundled_binutils) {
509 cflags += [ "-B$binutils_path" ]
510 }
512 # Clang-specific compiler flags setup.
513 # ------------------------------------
514 if (is_clang) {
515 cflags += [ "-fcolor-diagnostics" ]
516 }
518 # C++11 compiler flags setup.
519 # ---------------------------
520 if (is_linux || is_android || is_nacl) {
521 # gnu++11 instead of c++11 is needed because some code uses typeof() (a
522 # GNU extension).
523 # TODO(thakis): Eventually switch this to c++11 instead,
524 # http://crbug.com/427584
525 cflags_cc += [ "-std=gnu++11" ]
526 } else if (!is_win) {
527 cflags_cc += [ "-std=c++11" ]
528 }
530 # Android-specific flags setup.
531 # -----------------------------
532 if (is_android) {
533 cflags += [
534 "-ffunction-sections",
535 "-funwind-tables",
536 "-fno-short-enums",
537 ]
538 if (!is_clang) {
539 # Clang doesn't support these flags.
540 cflags += [ "-finline-limit=64" ]
541 }
542 if (is_clang) {
543 rebased_android_toolchain_root =
544 rebase_path(android_toolchain_root, root_build_dir)
545 if (current_cpu == "arm") {
546 cflags += [
547 # TODO(hans) Enable integrated-as (crbug.com/124610).
548 "-no-integrated-as",
549 "-B${rebased_android_toolchain_root}/bin", # Else /usr/bin/as gets picked up.
550 ]
551 }
552 }
553 if (is_asan) {
554 # Android build relies on -Wl,--gc-sections removing unreachable code.
555 # ASan instrumentation for globals inhibits this and results in a library
556 # with unresolvable relocations.
557 # TODO(eugenis): find a way to reenable this.
558 cflags += [ "-mllvm -asan-globals=0" ]
559 }
561 defines += [ "ANDROID" ]
563 # The NDK has these things, but doesn't define the constants
564 # to say that it does. Define them here instead.
565 defines += [ "HAVE_SYS_UIO_H" ]
567 # Use gold for Android for most CPU architectures.
568 if (current_cpu == "x86" || current_cpu == "x64" || current_cpu == "arm") {
569 ldflags += [ "-fuse-ld=gold" ]
570 if (is_clang) {
571 # Let clang find the ld.gold in the NDK.
572 ldflags += [ "--gcc-toolchain=$rebased_android_toolchain_root" ]
573 }
575 # Use -mstackrealign due to a bug on ia32 Jelly Bean.
576 # See crbug.com/521527
577 if (current_cpu == "x86") {
578 cflags += [ "-mstackrealign" ]
579 }
580 }
582 ldflags += [
583 "-Wl,--no-undefined",
585 # Don't allow visible symbols from libgcc or libc++ to be
586 # re-exported.
587 "-Wl,--exclude-libs=libgcc.a",
588 "-Wl,--exclude-libs=libc++_static.a",
590 # Don't allow visible symbols from libraries that contain
591 # assembly code with symbols that aren't hidden properly.
592 # http://crbug.com/448386
593 "-Wl,--exclude-libs=libvpx_assembly_arm.a",
594 ]
595 if (current_cpu == "arm") {
596 ldflags += [
597 # Enable identical code folding to reduce size.
598 "-Wl,--icf=safe",
599 ]
600 }
602 if (is_clang) {
603 if (current_cpu == "arm") {
604 _abi_target = "arm-linux-androideabi"
605 } else if (current_cpu == "x86") {
606 _abi_target = "i686-linux-androideabi"
607 } else if (current_cpu == "arm64") {
608 # Place holder for arm64 support, not tested.
609 _abi_target = "aarch64-linux-androideabi"
610 } else if (current_cpu == "x64") {
611 # Place holder for x64 support, not tested.
612 # TODO: Enable clang support for Android x64. http://crbug.com/346626
613 _abi_target = "x86_64-linux-androideabi"
614 } else if (current_cpu == "mipsel") {
615 # Place holder for mips support, not tested.
616 _abi_target = "mipsel-linux-androideabi"
617 } else if (current_cpu == "mips64el") {
618 # Place holder for mips64 support, not tested.
619 _abi_target = "mips64el-linux-androideabi"
620 } else {
621 assert(false, "Architecture not supported")
622 }
623 cflags += [
624 "-target",
625 _abi_target,
626 ]
627 ldflags += [
628 "-target",
629 _abi_target,
630 ]
631 }
632 }
634 # Pass the same C/C++ flags to the objective C/C++ compiler.
635 cflags_objc += cflags_c
636 cflags_objcc += cflags_cc
637 }
639 config("compiler_arm_fpu") {
640 if (current_cpu == "arm" && !is_ios) {
641 cflags = [ "-mfpu=$arm_fpu" ]
642 }
643 }
645 # runtime_library -------------------------------------------------------------
646 #
647 # Sets the runtime library and associated options.
648 #
649 # How do you determine what should go in here vs. "compiler" above? Consider if
650 # a target might choose to use a different runtime library (ignore for a moment
651 # if this is possible or reasonable on your system). If such a target would want
652 # to change or remove your option, put it in the runtime_library config. If a
653 # target wants the option regardless, put it in the compiler config.
655 config("runtime_library") {
656 cflags = []
657 defines = []
658 ldflags = []
659 lib_dirs = []
660 libs = []
662 if (is_component_build) {
663 # Component mode: dynamic CRT.
664 defines += [ "COMPONENT_BUILD" ]
665 if (is_win) {
666 # Since the library is shared, it requires exceptions or will give errors
667 # about things not matching, so keep exceptions on.
668 if (is_debug) {
669 cflags += [ "/MDd" ]
670 } else {
671 cflags += [ "/MD" ]
672 }
673 }
674 } else {
675 if (is_win && current_os != "win") {
676 # WindowsRT: use the dynamic CRT.
677 if (is_debug) {
678 cflags += [ "/MDd" ]
679 } else {
680 cflags += [ "/MD" ]
681 }
682 } else if (is_win) {
683 # Desktop Windows: static CRT.
684 if (is_debug) {
685 cflags += [ "/MTd" ]
686 } else {
687 cflags += [ "/MT" ]
688 }
689 }
690 }
692 if (is_win) {
693 defines += [
694 "__STD_C",
695 "_CRT_RAND_S",
696 "_CRT_SECURE_NO_DEPRECATE",
697 "_HAS_EXCEPTIONS=0",
698 "_SCL_SECURE_NO_DEPRECATE",
699 ]
700 }
702 # Android standard library setup.
703 if (is_android) {
704 if (is_clang) {
705 # Work around incompatibilities between bionic and clang headers.
706 defines += [
707 "__compiler_offsetof=__builtin_offsetof",
708 "nan=__builtin_nan",
709 ]
710 }
712 defines += [ "__GNU_SOURCE=1" ] # Necessary for clone().
714 # TODO(jdduke) Re-enable on mips after resolving linking
715 # issues with libc++ (crbug.com/456380).
716 if (current_cpu != "mipsel" && current_cpu != "mips64el") {
717 ldflags += [ "-Wl,--warn-shared-textrel" ]
718 }
719 ldflags += [ "-nostdlib" ]
721 # NOTE: The libc++ header include paths below are specified in cflags
722 # rather than include_dirs because they need to come after include_dirs.
723 # Think of them like system headers, but don't use '-isystem' because the
724 # arm-linux-androideabi-4.4.3 toolchain (circa Gingerbread) will exhibit
725 # strange errors. The include ordering here is important; change with
726 # caution.
727 cflags += [
728 "-isystem" +
729 rebase_path("$android_libcpp_root/libcxx/include", root_build_dir),
730 "-isystem" + rebase_path(
731 "$android_ndk_root/sources/cxx-stl/llvm-libc++abi/libcxxabi/include",
732 root_build_dir),
733 "-isystem" +
734 rebase_path("$android_ndk_root/sources/android/support/include",
735 root_build_dir),
736 ]
738 lib_dirs += [ "$android_libcpp_root/libs/$android_app_abi" ]
739 libs += [ "$android_libcpp_library" ]
741 if (current_cpu == "mipsel") {
742 libs += [
743 # ld linker is used for mips Android, and ld does not accept library
744 # absolute path prefixed by "-l"; Since libgcc does not exist in mips
745 # sysroot the proper library will be linked.
746 # TODO(gordanac): Remove once gold linker is used for mips Android.
747 "gcc",
748 ]
749 } else {
750 libs += [
751 # Manually link the libgcc.a that the cross compiler uses. This is
752 # absolute because the linker will look inside the sysroot if it's not.
753 rebase_path(android_libgcc_file),
754 ]
755 }
757 libs += [
758 "c",
759 "dl",
760 "m",
761 ]
763 # Clang with libc++ does not require an explicit atomic library reference.
764 if (!is_clang) {
765 libs += [ "atomic" ]
766 }
767 }
768 }
770 # default_warning_flags collects all warning flags that are used by default.
771 # This is in a variable instead of a config so that it can be used in
772 # both chromium_code and no_chromium_code. This way these flags are guaranteed
773 # to appear on the compile command line after -Wall.
775 default_warning_flags = []
776 default_warning_flags_cc = []
777 if (is_win) {
778 default_warning_flags += [
779 # Treat warnings as errors.
780 "/WX",
782 # Warnings permanently disabled:
784 # C4127: conditional expression is constant
785 # This warning can in theory catch dead code and other problems, but
786 # triggers in far too many desirable cases where the conditional
787 # expression is either set by macros or corresponds some legitimate
788 # compile-time constant expression (due to constant template args,
789 # conditionals comparing the sizes of different types, etc.). Some of
790 # these can be worked around, but it's not worth it.
791 "/wd4127",
793 # C4251: 'identifier' : class 'type' needs to have dll-interface to be
794 # used by clients of class 'type2'
795 # This is necessary for the shared library build.
796 "/wd4251",
798 # C4351: new behavior: elements of array 'array' will be default
799 # initialized
800 # This is a silly "warning" that basically just alerts you that the
801 # compiler is going to actually follow the language spec like it's
802 # supposed to, instead of not following it like old buggy versions did.
803 # There's absolutely no reason to turn this on.
804 "/wd4351",
806 # C4355: 'this': used in base member initializer list
807 # It's commonly useful to pass |this| to objects in a class' initializer
808 # list. While this warning can catch real bugs, most of the time the
809 # constructors in question don't attempt to call methods on the passed-in
810 # pointer (until later), and annotating every legit usage of this is
811 # simply more hassle than the warning is worth.
812 "/wd4355",
814 # C4503: 'identifier': decorated name length exceeded, name was
815 # truncated
816 # This only means that some long error messages might have truncated
817 # identifiers in the presence of lots of templates. It has no effect on
818 # program correctness and there's no real reason to waste time trying to
819 # prevent it.
820 "/wd4503",
822 # Warning C4589 says: "Constructor of abstract class ignores
823 # initializer for virtual base class." Disable this warning because it
824 # is flaky in VS 2015 RTM. It triggers on compiler generated
825 # copy-constructors in some cases.
826 "/wd4589",
828 # C4611: interaction between 'function' and C++ object destruction is
829 # non-portable
830 # This warning is unavoidable when using e.g. setjmp/longjmp. MSDN
831 # suggests using exceptions instead of setjmp/longjmp for C++, but
832 # Chromium code compiles without exception support. We therefore have to
833 # use setjmp/longjmp for e.g. JPEG decode error handling, which means we
834 # have to turn off this warning (and be careful about how object
835 # destruction happens in such cases).
836 "/wd4611",
838 # Warnings to evaluate and possibly fix/reenable later:
840 "/wd4100", # Unreferenced formal function parameter.
841 "/wd4121", # Alignment of a member was sensitive to packing.
842 "/wd4244", # Conversion: possible loss of data.
843 "/wd4481", # Nonstandard extension: override specifier.
844 "/wd4505", # Unreferenced local function has been removed.
845 "/wd4510", # Default constructor could not be generated.
846 "/wd4512", # Assignment operator could not be generated.
847 "/wd4610", # Class can never be instantiated, constructor required.
848 "/wd4995", # 'X': name was marked as #pragma deprecated
849 "/wd4996", # Deprecated function warning.
850 ]
852 # VS xtree header file needs to be patched or 4702 (unreachable code
853 # warning) is reported if _HAS_EXCEPTIONS=0. Disable the warning if xtree is
854 # not patched.
855 if (!msvs_xtree_patched &&
856 exec_script("../../win_is_xtree_patched.py", [], "value") == 0) {
857 default_warning_flags += [ "/wd4702" ] # Unreachable code.
858 }
860 # Building with Clang on Windows is a work in progress and very
861 # experimental. See crbug.com/82385.
862 # Keep this in sync with the similar block in build/common.gypi
863 if (is_clang) {
864 default_warning_flags += [
865 # TODO(hans): Make this list shorter eventually, http://crbug.com/504657
866 "-Qunused-arguments", # http://crbug.com/504658
867 "-Wno-microsoft", # http://crbug.com/505296
868 "-Wno-unknown-pragmas", # http://crbug.com/505314
869 "-Wno-unused-value", # http://crbug.com/505318
870 ]
871 }
872 } else {
873 # Common GCC warning setup.
874 default_warning_flags += [
875 # Enables.
876 "-Wendif-labels", # Weird old-style text after an #endif.
877 "-Werror", # Warnings as errors.
879 # Disables.
880 "-Wno-missing-field-initializers", # "struct foo f = {0};"
881 "-Wno-unused-parameter", # Unused function parameters.
882 ]
884 if (is_mac) {
885 default_warning_flags += [ "-Wnewline-eof" ]
886 if (!is_nacl) {
887 # When compiling Objective-C, warns if a method is used whose
888 # availability is newer than the deployment target. This is not
889 # required when compiling Chrome for iOS.
890 default_warning_flags += [ "-Wpartial-availability" ]
891 }
892 }
894 if (gcc_version >= 48) {
895 default_warning_flags_cc += [
896 # See comment for -Wno-c++11-narrowing.
897 "-Wno-narrowing",
898 ]
899 if (!is_clang) {
900 default_warning_flags_cc += [
901 # TODO(thakis): Remove, http://crbug.com/263960
902 "-Wno-literal-suffix",
903 ]
904 }
905 }
907 # Suppress warnings about ABI changes on ARM (Clang doesn't give this
908 # warning).
909 if (current_cpu == "arm" && !is_clang) {
910 default_warning_flags += [ "-Wno-psabi" ]
911 }
913 if (is_android) {
914 # Disable any additional warnings enabled by the Android build system but
915 # which chromium does not build cleanly with (when treating warning as
916 # errors).
917 default_warning_flags += [
918 "-Wno-extra",
919 "-Wno-ignored-qualifiers",
920 "-Wno-type-limits",
921 ]
922 default_warning_flags_cc += [
923 # Disabling c++0x-compat should be handled in WebKit, but
924 # this currently doesn't work because gcc_version is not set
925 # correctly when building with the Android build system.
926 # TODO(torne): Fix this in WebKit.
927 "-Wno-error=c++0x-compat",
929 # Other things unrelated to -Wextra:
930 "-Wno-non-virtual-dtor",
931 "-Wno-sign-promo",
932 ]
933 }
935 if (gcc_version >= 48) {
936 # Don't warn about the "typedef 'foo' locally defined but not used"
937 # for gcc 4.8.
938 # TODO: remove this flag once all builds work. See crbug.com/227506
939 default_warning_flags += [ "-Wno-unused-local-typedefs" ]
940 }
941 }
942 if (is_clang) {
943 default_warning_flags += [
944 # This warns on using ints as initializers for floats in
945 # initializer lists (e.g. |int a = f(); CGSize s = { a, a };|),
946 # which happens in several places in chrome code. Not sure if
947 # this is worth fixing.
948 "-Wno-c++11-narrowing",
950 # Don't die on dtoa code that uses a char as an array index.
951 # This is required solely for base/third_party/dmg_fp/dtoa.cc.
952 # TODO(brettw) move this to that project then!
953 "-Wno-char-subscripts",
955 # Warns on switches on enums that cover all enum values but
956 # also contain a default: branch. Chrome is full of that.
957 "-Wno-covered-switch-default",
959 # Clang considers the `register` keyword as deprecated, but e.g.
960 # code generated by flex (used in angle) contains that keyword.
961 # http://crbug.com/255186
962 "-Wno-deprecated-register",
964 # TODO(thakis): This used to be implied by -Wno-unused-function,
965 # which we no longer use. Check if it makes sense to remove
966 # this as well. http://crbug.com/316352
967 "-Wno-unneeded-internal-declaration",
968 ]
970 if (is_posix && !is_mac && !is_ios) {
971 default_warning_flags += [
972 # TODO(thakis): Remove, http://crbug.com/263960
973 "-Wno-reserved-user-defined-literal",
974 ]
975 }
977 # NaCl's Clang compiler and Chrome's hermetic Clang compiler will almost
978 # always have different versions. Certain flags may not be recognized by
979 # one version or the other.
980 if (!is_nacl) {
981 # Flags NaCl does not recognize.
982 default_warning_flags += [
983 # TODO(hans): Get this cleaned up, http://crbug.com/428099
984 "-Wno-inconsistent-missing-override",
986 # TODO(thakis): Enable this, crbug.com/507717
987 "-Wno-shift-negative-value",
988 ]
989 }
990 }
992 # chromium_code ---------------------------------------------------------------
993 #
994 # Toggles between higher and lower warnings for code that is (or isn't)
995 # part of Chromium.
997 config("chromium_code") {
998 if (is_win) {
999 cflags = [ "/W4" ] # Warning level 4.
1000 } else {
1001 cflags = [
1002 "-Wall",
1004 # GCC turns on -Wsign-compare for C++ under -Wall, but clang doesn't,
1005 # so we specify it explicitly.
1006 # TODO(fischman): remove this if http://llvm.org/PR10448 obsoletes it.
1007 # http://code.google.com/p/chromium/issues/detail?id=90453
1008 "-Wsign-compare",
1009 ]
1011 # In Chromium code, we define __STDC_foo_MACROS in order to get the
1012 # C99 macros on Mac and Linux.
1013 defines = [
1014 "__STDC_CONSTANT_MACROS",
1015 "__STDC_FORMAT_MACROS",
1016 ]
1018 if (!is_debug && !using_sanitizer &&
1019 (!is_linux || !is_clang || is_official_build)) {
1020 # _FORTIFY_SOURCE isn't really supported by Clang now, see
1021 # http://llvm.org/bugs/show_bug.cgi?id=16821.
1022 # It seems to work fine with Ubuntu 12 headers though, so use it in
1023 # official builds.
1024 #
1025 # Non-chromium code is not guaranteed to compile cleanly with
1026 # _FORTIFY_SOURCE. Also, fortified build may fail when optimizations are
1027 # disabled, so only do that for Release build.
1028 defines += [ "_FORTIFY_SOURCE=2" ]
1029 }
1030 }
1031 cflags += default_warning_flags
1032 cflags_cc = default_warning_flags_cc
1033 }
1034 config("no_chromium_code") {
1035 cflags = []
1036 cflags_cc = []
1037 defines = []
1039 if (is_win) {
1040 cflags += [
1041 "/W3", # Warning level 3.
1042 "/wd4800", # Disable warning when forcing value to bool.
1043 "/wd4267", # TODO(jschuh): size_t to int.
1044 "/wd4996", # Deprecated function warning.
1045 ]
1046 defines += [
1047 "_CRT_NONSTDC_NO_WARNINGS",
1048 "_CRT_NONSTDC_NO_DEPRECATE",
1049 ]
1050 }
1052 if (is_linux) {
1053 # Don't warn about ignoring the return value from e.g. close(). This is
1054 # off by default in some gccs but on by default in others. BSD systems do
1055 # not support this option, since they are usually using gcc 4.2.1, which
1056 # does not have this flag yet.
1057 cflags += [ "-Wno-unused-result" ]
1058 }
1060 if (is_clang) {
1061 cflags += [
1062 # TODO(thakis): Move this suppression into individual third-party
1063 # libraries as required. http://crbug.com/505316.
1064 "-Wno-unused-function",
1066 # Lots of third-party libraries have unused variables. Instead of
1067 # suppressing them individually, we just blanket suppress them here.
1068 "-Wno-unused-variable",
1069 ]
1070 }
1072 if (is_linux || is_android) {
1073 cflags += [
1074 # Don't warn about printf format problems. This is off by default in gcc
1075 # but on in Ubuntu's gcc(!).
1076 "-Wno-format",
1077 ]
1078 cflags_cc += [
1079 # Don't warn about hash_map in third-party code.
1080 "-Wno-deprecated",
1081 ]
1082 }
1083 cflags += default_warning_flags
1084 cflags_cc += default_warning_flags_cc
1085 }
1087 # rtti ------------------------------------------------------------------------
1088 #
1089 # Allows turning Run-Time Type Identification on or off.
1091 config("rtti") {
1092 if (is_win) {
1093 cflags_cc = [ "/GR" ]
1094 }
1095 }
1096 config("no_rtti") {
1097 if (is_win) {
1098 cflags_cc = [ "/GR-" ]
1099 } else {
1100 cflags_cc = [ "-fno-rtti" ]
1101 cflags_objcc = cflags_cc
1102 }
1103 }
1105 # Warnings ---------------------------------------------------------------------
1107 # This will generate warnings when using Clang if code generates exit-time
1108 # destructors, which will slow down closing the program.
1109 # TODO(thakis): Make this a blacklist instead, http://crbug.com/101600
1110 config("wexit_time_destructors") {
1111 # TODO: Enable on Windows too, http://crbug.com/404525
1112 if (is_clang && !is_win) {
1113 cflags = [ "-Wexit-time-destructors" ]
1114 }
1115 }
1117 # On Windows compiling on x64, VC will issue a warning when converting
1118 # size_t to int because it will truncate the value. Our code should not have
1119 # these warnings and one should use a static_cast or a checked_cast for the
1120 # conversion depending on the case. However, a lot of code still needs to be
1121 # fixed. Apply this config to such targets to disable the warning.
1122 #
1123 # Note that this can be applied regardless of platform and architecture to
1124 # clean up the call sites. This will only apply the flag when necessary.
1125 #
1126 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
1127 config("no_size_t_to_int_warning") {
1128 if (is_win && current_cpu == "x64") {
1129 cflags = [ "/wd4267" ]
1130 }
1131 }
1133 # Some code presumes that pointers to structures/objects are compatible
1134 # regardless of whether what they point to is already known to be valid.
1135 # gcc 4.9 and earlier had no way of suppressing this warning without
1136 # supressing the rest of them. Here we centralize the identification of
1137 # the gcc 4.9 toolchains.
1138 config("no_incompatible_pointer_warnings") {
1139 cflags = []
1140 if (is_clang) {
1141 cflags += [ "-Wno-incompatible-pointer-types" ]
1142 } else if (current_cpu == "mipsel") {
1143 cflags += [ "-w" ]
1144 } else if (is_chromeos && current_cpu == "arm") {
1145 cflags += [ "-w" ]
1146 }
1147 }
1149 # Optimization -----------------------------------------------------------------
1150 #
1151 # Note that BUILDCONFIG.gn sets up a variable "default_optimization_config"
1152 # which it will assign to the config it implicitly applies to every target. If
1153 # you want to override the optimization level for your target, remove this
1154 # config (which will expand differently for debug or release builds), and then
1155 # add back the one you want to override it with:
1156 #
1157 # configs -= default_optimization_config
1158 # configs += [ "//build/config/compiler/optimize_max" ]
1160 # Shared settings for both "optimize" and "optimize_max" configs.
1161 # IMPORTANT: On Windows "/O1" and "/O2" must go before the common flags.
1162 if (is_win) {
1163 common_optimize_on_cflags = [
1164 "/Ob2", # Both explicit and auto inlining.
1165 "/Oy-", # Disable omitting frame pointers, must be after /O2.
1166 ]
1167 if (!is_asan) {
1168 common_optimize_on_cflags += [
1169 # Put data in separate COMDATs. This allows the linker
1170 # to put bit-identical constants at the same address even if
1171 # they're unrelated constants, which saves binary size.
1172 # This optimization can't be used when ASan is enabled because
1173 # it is not compatible with the ASan ODR checker.
1174 "/Gw",
1175 ]
1176 }
1177 common_optimize_on_ldflags = [ "/OPT:REF" ]
1178 } else {
1179 common_optimize_on_cflags = [
1180 # Don't emit the GCC version ident directives, they just end up in the
1181 # .comment section taking up binary size.
1182 "-fno-ident",
1184 # Put data and code in their own sections, so that unused symbols
1185 # can be removed at link time with --gc-sections.
1186 "-fdata-sections",
1187 "-ffunction-sections",
1188 ]
1189 common_optimize_on_ldflags = []
1191 if (is_android) {
1192 if (!using_sanitizer) {
1193 common_optimize_on_cflags += [ "-fomit-frame-pointer" ]
1194 }
1196 # TODO(jdduke) Re-enable on mips after resolving linking
1197 # issues with libc++ (crbug.com/456380).
1198 if (current_cpu != "mipsel" && current_cpu != "mips64el") {
1199 common_optimize_on_ldflags += [
1200 # Warn in case of text relocations.
1201 "-Wl,--warn-shared-textrel",
1202 ]
1203 }
1204 }
1206 if (is_mac || is_ios) {
1207 if (symbol_level == 2) {
1208 # Mac dead code stripping requires symbols.
1209 common_optimize_on_ldflags += [ "-Wl,-dead_strip" ]
1210 }
1211 } else {
1212 # Non-Mac Posix linker flags.
1213 common_optimize_on_ldflags += [
1214 # Specifically tell the linker to perform optimizations.
1215 # See http://lwn.net/Articles/192624/ .
1216 "-Wl,-O1",
1217 "-Wl,--gc-sections",
1218 ]
1220 if (!using_sanitizer) {
1221 # Functions interposed by the sanitizers can make ld think
1222 # that some libraries aren't needed when they actually are,
1223 # http://crbug.com/234010. As workaround, disable --as-needed.
1224 common_optimize_on_ldflags += [ "-Wl,--as-needed" ]
1225 }
1226 }
1227 }
1229 # Default "optimization on" config. On Windows, this favors size over speed.
1230 config("optimize") {
1231 if (is_win) {
1232 # Favor size over speed, /O1 must be before the common flags. The GYP
1233 # build also specifies /Os and /GF but these are implied by /O1.
1234 cflags = [ "/O1" ] + common_optimize_on_cflags + [ "/Oi" ]
1235 } else if (is_android || is_ios) {
1236 cflags = [ "-Os" ] + common_optimize_on_cflags # Favor size over speed.
1237 } else {
1238 cflags = [ "-O2" ] + common_optimize_on_cflags
1239 }
1240 ldflags = common_optimize_on_ldflags
1241 }
1243 # Turn off optimizations.
1244 config("no_optimize") {
1245 if (is_win) {
1246 cflags = [
1247 "/Od", # Disable optimization.
1248 "/Ob0", # Disable all inlining (on by default).
1249 "/RTC1", # Runtime checks for stack frame and uninitialized variables.
1250 ]
1251 } else if (is_android && !android_full_debug) {
1252 # On Android we kind of optimize some things that don't affect debugging
1253 # much even when optimization is disabled to get the binary size down.
1254 cflags = [
1255 "-Os",
1256 "-fdata-sections",
1257 "-ffunction-sections",
1258 ]
1259 if (!using_sanitizer) {
1260 cflags += [ "-fomit-frame-pointer" ]
1261 }
1262 ldflags = common_optimize_on_ldflags
1263 } else {
1264 cflags = [ "-O0" ]
1265 }
1266 }
1268 # Turns up the optimization level. On Windows, this implies whole program
1269 # optimization and link-time code generation which is very expensive and should
1270 # be used sparingly.
1271 config("optimize_max") {
1272 ldflags = common_optimize_on_ldflags
1273 if (is_win) {
1274 # Favor speed over size, /O2 must be before the common flags. The GYP
1275 # build also specifies /Ot, /Oi, and /GF, but these are implied by /O2.
1276 cflags = [ "/O2" ] + common_optimize_on_cflags
1277 if (is_official_build) {
1278 # TODO(GYP): TODO(dpranke): Should these only be on in an official
1279 # build, or on all the time? For now we'll require official build so
1280 # that the compile is clean.
1281 cflags += [
1282 "/GL", # Whole program optimization.
1284 # Disable Warning 4702 ("Unreachable code") for the WPO/PGO builds.
1285 # Probably anything that this would catch that wouldn't be caught in a
1286 # normal build isn't going to actually be a bug, so the incremental
1287 # value of C4702 for PGO builds is likely very small.
1288 "/wd4702",
1289 ]
1290 ldflags += [ "/LTCG" ]
1291 }
1292 } else {
1293 cflags = [ "-O2" ] + common_optimize_on_cflags
1294 }
1295 }
1297 # Symbols ----------------------------------------------------------------------
1299 config("symbols") {
1300 if (is_win) {
1301 import("//build/toolchain/goma.gni")
1302 if (use_goma) {
1303 cflags = [ "/Z7" ] # No PDB file
1304 } else {
1305 cflags = [ "/Zi" ] # Produce PDB file, no edit and continue.
1306 }
1307 if (is_win_fastlink) {
1308 # Tell VS 2015+ to create a PDB that references debug
1309 # information in .obj and .lib files instead of copying
1310 # it all. This flag is incompatible with /PROFILE
1311 ldflags = [ "/DEBUG:FASTLINK" ]
1312 } else {
1313 ldflags = [ "/DEBUG" ]
1314 }
1315 } else {
1316 cflags = [ "-g2" ]
1317 if (use_debug_fission) {
1318 cflags += [ "-gsplit-dwarf" ]
1319 }
1320 }
1321 }
1323 config("minimal_symbols") {
1324 if (is_win) {
1325 # Linker symbols for backtraces only.
1326 if (is_win_fastlink) {
1327 # Tell VS 2015+ to create a PDB that references debug
1328 # information in .obj and .lib files instead of copying
1329 # it all. This flag is incompatible with /PROFILE
1330 ldflags = [ "/DEBUG:FASTLINK" ]
1331 } else {
1332 ldflags = [ "/DEBUG" ]
1333 }
1334 } else {
1335 cflags = [ "-g1" ]
1336 if (use_debug_fission) {
1337 cflags += [ "-gsplit-dwarf" ]
1338 }
1339 }
1340 }
1342 config("no_symbols") {
1343 if (!is_win) {
1344 cflags = [ "-g0" ]
1345 }
1346 }