media/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/arm.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/linux/pkg_config.gni")
   9 import("//build/config/ui.gni")
  10 import("//media/media_options.gni")
  11 import("//testing/test.gni")
  12
  13 # Common configuration for targets in the media directory.
  14 # NOT for exporting.
  15 config("media_config") {
  16   defines = [ "MEDIA_IMPLEMENTATION" ]
  17   if (!media_use_libvpx) {
  18     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  19   }
  20   if (!media_use_ffmpeg) {
  21     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  22   }
  23   if (current_cpu == "arm" && arm_use_neon) {
  24     defines += [ "USE_NEON" ]
  25   }
  26   if (use_pulseaudio) {
  27     defines += [ "USE_PULSEAUDIO" ]
  28     if (!link_pulseaudio) {
  29       defines += [ "DLOPEN_PULSEAUDIO" ]
  30     }
  31   }
  32   if (use_cras) {
  33     defines += [ "USE_CRAS" ]
  34   }
  35   if (use_alsa) {
  36     defines += [ "USE_ALSA" ]
  37   }
  38 }
  39
  40 config("media_dependent_config") {
  41   defines = []
  42   if (!media_use_libvpx) {
  43     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  44   }
  45   if (!media_use_ffmpeg) {
  46     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  47   }
  48   if (is_win) {
  49     ldflags = [
  50       "/DELAYLOAD:mf.dll",
  51       "/DELAYLOAD:mfplat.dll",
  52       "/DELAYLOAD:mfreadwrite.dll",
  53     ]
  54   }
  55 }
  56
  57 if (use_ozone) {
  58   action("generate_ozone_constructor_list") {
  59     # Ozone platform objects are auto-generated using similar
  60     # patterns for naming and classes constructors. Here we build the
  61     # object MediaOzonePlatform.
  62     script = "../ui/ozone/generate_constructor_list.py"
  63
  64     platform_list_txt_file = "$target_gen_dir/../ui/ozone/platform_list.txt"
  65     constructor_list_cc_file =
  66         "$target_gen_dir/../media/ozone/constructor_list.cc"
  67
  68     sources = [
  69       platform_list_txt_file,
  70     ]
  71     outputs = [
  72       constructor_list_cc_file,
  73     ]
  74     args = [
  75       "--platform_list=" + rebase_path(platform_list_txt_file, root_build_dir),
  76       "--output_cc=" + rebase_path(constructor_list_cc_file, root_build_dir),
  77       "--namespace=media",
  78       "--typename=MediaOzonePlatform",
  79       "--include=\"media/ozone/media_ozone_platform.h\"",
  80     ]
  81   }
  82 }
  83
  84 component("media") {
  85   sources = [
  86     "blink/skcanvas_video_renderer.cc",
  87     "blink/skcanvas_video_renderer.h",
  88     "cdm/aes_decryptor.cc",
  89     "cdm/aes_decryptor.h",
  90     "cdm/cenc_utils.cc",
  91     "cdm/cenc_utils.h",
  92     "cdm/default_cdm_factory.cc",
  93     "cdm/default_cdm_factory.h",
  94     "cdm/json_web_key.cc",
  95     "cdm/json_web_key.h",
  96     "cdm/key_system_names.cc",
  97     "cdm/key_system_names.h",
  98     "cdm/player_tracker_impl.cc",
  99     "cdm/player_tracker_impl.h",
 100     "cdm/proxy_decryptor.cc",
 101     "cdm/proxy_decyrptor.h",
 102     "ffmpeg/ffmpeg_deleters.h",
 103     "filters/audio_clock.cc",
 104     "filters/audio_clock.h",
 105     "filters/audio_renderer_algorithm.cc",
 106     "filters/audio_renderer_algorithm.h",
 107     "filters/chunk_demuxer.cc",
 108     "filters/chunk_demuxer.h",
 109     "filters/context_3d.h",
 110     "filters/decoder_selector.cc",
 111     "filters/decoder_selector.h",
 112     "filters/decoder_stream.cc",
 113     "filters/decoder_stream.h",
 114     "filters/decoder_stream_traits.cc",
 115     "filters/decoder_stream_traits.h",
 116     "filters/decrypting_audio_decoder.cc",
 117     "filters/decrypting_audio_decoder.h",
 118     "filters/decrypting_demuxer_stream.cc",
 119     "filters/decrypting_demuxer_stream.h",
 120     "filters/decrypting_video_decoder.cc",
 121     "filters/decrypting_video_decoder.h",
 122     "filters/default_media_permission.cc",
 123     "filters/default_media_permission.h",
 124     "filters/file_data_source.cc",
 125     "filters/file_data_source.h",
 126     "filters/frame_processor.cc",
 127     "filters/frame_processor.h",
 128     "filters/gpu_video_decoder.cc",
 129     "filters/gpu_video_decoder.h",
 130     "filters/h264_bit_reader.cc",
 131     "filters/h264_bit_reader.h",
 132     "filters/h264_parser.cc",
 133     "filters/h264_parser.h",
 134     "filters/jpeg_parser.cc",
 135     "filters/jpeg_parser.h",
 136     "filters/source_buffer_platform.cc",
 137     "filters/source_buffer_platform.h",
 138     "filters/source_buffer_range.cc",
 139     "filters/source_buffer_range.h",
 140     "filters/source_buffer_stream.cc",
 141     "filters/source_buffer_stream.h",
 142     "filters/stream_parser_factory.cc",
 143     "filters/stream_parser_factory.h",
 144     "filters/video_frame_scheduler.h",
 145     "filters/video_frame_scheduler_impl.cc",
 146     "filters/video_frame_scheduler_impl.h",
 147     "filters/video_frame_scheduler_proxy.cc",
 148     "filters/video_frame_scheduler_proxy.h",
 149     "filters/vp8_bool_decoder.cc",
 150     "filters/vp8_bool_decoder.h",
 151     "filters/vp8_parser.cc",
 152     "filters/vp8_parser.h",
 153     "filters/webvtt_util.h",
 154     "filters/wsola_internals.cc",
 155     "filters/wsola_internals.h",
 156     "formats/common/offset_byte_queue.cc",
 157     "formats/common/offset_byte_queue.h",
 158     "formats/webm/webm_audio_client.cc",
 159     "formats/webm/webm_audio_client.h",
 160     "formats/webm/webm_cluster_parser.cc",
 161     "formats/webm/webm_cluster_parser.h",
 162     "formats/webm/webm_constants.cc",
 163     "formats/webm/webm_constants.h",
 164     "formats/webm/webm_content_encodings.cc",
 165     "formats/webm/webm_content_encodings.h",
 166     "formats/webm/webm_content_encodings_client.cc",
 167     "formats/webm/webm_content_encodings_client.h",
 168     "formats/webm/webm_crypto_helpers.cc",
 169     "formats/webm/webm_crypto_helpers.h",
 170     "formats/webm/webm_info_parser.cc",
 171     "formats/webm/webm_info_parser.h",
 172     "formats/webm/webm_parser.cc",
 173     "formats/webm/webm_parser.h",
 174     "formats/webm/webm_stream_parser.cc",
 175     "formats/webm/webm_stream_parser.h",
 176     "formats/webm/webm_tracks_parser.cc",
 177     "formats/webm/webm_tracks_parser.h",
 178     "formats/webm/webm_video_client.cc",
 179     "formats/webm/webm_video_client.h",
 180     "formats/webm/webm_webvtt_parser.cc",
 181     "formats/webm/webm_webvtt_parser.h",
 182     "midi/midi_manager.cc",
 183     "midi/midi_manager.h",
 184     "midi/midi_manager_mac.cc",
 185     "midi/midi_manager_mac.h",
 186     "midi/midi_manager_usb.cc",
 187     "midi/midi_manager_usb.h",
 188     "midi/midi_manager_win.cc",
 189     "midi/midi_manager_win.h",
 190     "midi/midi_message_queue.cc",
 191     "midi/midi_message_queue.h",
 192     "midi/midi_message_util.cc",
 193     "midi/midi_message_util.h",
 194     "midi/midi_port_info.cc",
 195     "midi/midi_port_info.h",
 196     "midi/midi_scheduler.cc",
 197     "midi/midi_scheduler.h",
 198     "midi/usb_midi_descriptor_parser.cc",
 199     "midi/usb_midi_descriptor_parser.h",
 200     "midi/usb_midi_device.h",
 201     "midi/usb_midi_input_stream.cc",
 202     "midi/usb_midi_input_stream.h",
 203     "midi/usb_midi_jack.h",
 204     "midi/usb_midi_output_stream.cc",
 205     "midi/usb_midi_output_stream.h",
 206     "renderers/audio_renderer_impl.cc",
 207     "renderers/audio_renderer_impl.h",
 208     "renderers/gpu_video_accelerator_factories.h",
 209     "renderers/renderer_impl.cc",
 210     "renderers/renderer_impl.h",
 211     "renderers/video_renderer_impl.cc",
 212     "renderers/video_renderer_impl.h",
 213     "video/capture/fake_video_capture_device.cc",
 214     "video/capture/fake_video_capture_device.h",
 215     "video/capture/fake_video_capture_device_factory.cc",
 216     "video/capture/fake_video_capture_device_factory.h",
 217     "video/capture/file_video_capture_device.cc",
 218     "video/capture/file_video_capture_device.h",
 219     "video/capture/file_video_capture_device_factory.cc",
 220     "video/capture/file_video_capture_device_factory.h",
 221     "video/capture/linux/v4l2_capture_delegate.cc",
 222     "video/capture/linux/v4l2_capture_delegate.h",
 223     "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 224     "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 225     "video/capture/linux/v4l2_capture_delegate_single_plane.cc",
 226     "video/capture/linux/v4l2_capture_delegate_single_plane.h",
 227     "video/capture/linux/video_capture_device_chromeos.cc",
 228     "video/capture/linux/video_capture_device_chromeos.h",
 229     "video/capture/linux/video_capture_device_factory_linux.cc",
 230     "video/capture/linux/video_capture_device_factory_linux.h",
 231     "video/capture/linux/video_capture_device_linux.cc",
 232     "video/capture/linux/video_capture_device_linux.h",
 233     "video/capture/mac/platform_video_capturing_mac.h",
 234     "video/capture/mac/video_capture_device_avfoundation_mac.h",
 235     "video/capture/mac/video_capture_device_avfoundation_mac.mm",
 236     "video/capture/mac/video_capture_device_decklink_mac.h",
 237     "video/capture/mac/video_capture_device_decklink_mac.mm",
 238     "video/capture/mac/video_capture_device_factory_mac.h",
 239     "video/capture/mac/video_capture_device_factory_mac.mm",
 240     "video/capture/mac/video_capture_device_mac.h",
 241     "video/capture/mac/video_capture_device_mac.mm",
 242     "video/capture/mac/video_capture_device_qtkit_mac.h",
 243     "video/capture/mac/video_capture_device_qtkit_mac.mm",
 244     "video/capture/video_capture_device.cc",
 245     "video/capture/video_capture_device.h",
 246     "video/capture/video_capture_device_factory.cc",
 247     "video/capture/video_capture_device_factory.h",
 248     "video/capture/video_capture_device_info.cc",
 249     "video/capture/video_capture_device_info.h",
 250     "video/capture/win/capability_list_win.cc",
 251     "video/capture/win/capability_list_win.h",
 252     "video/capture/win/filter_base_win.cc",
 253     "video/capture/win/filter_base_win.h",
 254     "video/capture/win/pin_base_win.cc",
 255     "video/capture/win/pin_base_win.h",
 256     "video/capture/win/sink_filter_observer_win.h",
 257     "video/capture/win/sink_filter_win.cc",
 258     "video/capture/win/sink_filter_win.h",
 259     "video/capture/win/sink_input_pin_win.cc",
 260     "video/capture/win/sink_input_pin_win.h",
 261     "video/capture/win/video_capture_device_factory_win.cc",
 262     "video/capture/win/video_capture_device_factory_win.h",
 263     "video/capture/win/video_capture_device_mf_win.cc",
 264     "video/capture/win/video_capture_device_mf_win.h",
 265     "video/capture/win/video_capture_device_win.cc",
 266     "video/capture/win/video_capture_device_win.h",
 267     "video/fake_video_encode_accelerator.cc",
 268     "video/fake_video_encode_accelerator.h",
 269     "video/h264_poc.cc",
 270     "video/h264_poc.h",
 271     "video/picture.cc",
 272     "video/picture.h",
 273     "video/video_decode_accelerator.cc",
 274     "video/video_decode_accelerator.h",
 275     "video/video_encode_accelerator.cc",
 276     "video/video_encode_accelerator.h",
 277   ]
 278
 279   configs += [
 280     ":media_config",
 281
 282     # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 283     # See http://crbug.com/171009
 284     "//build/config/compiler:no_size_t_to_int_warning",
 285   ]
 286   all_dependent_configs = [ ":media_dependent_config" ]
 287
 288   cflags = []
 289   libs = []
 290   defines = []
 291   deps = []
 292
 293   include_dirs = [ "." ]
 294   if (media_use_ffmpeg) {
 295     deps += [ "//third_party/ffmpeg" ]
 296     sources += [
 297       "ffmpeg/ffmpeg_common.cc",
 298       "ffmpeg/ffmpeg_common.h",
 299       "filters/audio_file_reader.cc",
 300       "filters/audio_file_reader.h",
 301       "filters/blocking_url_protocol.cc",
 302       "filters/blocking_url_protocol.h",
 303       "filters/ffmpeg_audio_decoder.cc",
 304       "filters/ffmpeg_audio_decoder.h",
 305       "filters/ffmpeg_bitstream_converter.h",
 306       "filters/ffmpeg_demuxer.cc",
 307       "filters/ffmpeg_demuxer.h",
 308       "filters/ffmpeg_glue.cc",
 309       "filters/ffmpeg_glue.h",
 310       "filters/ffmpeg_video_decoder.cc",
 311       "filters/ffmpeg_video_decoder.h",
 312       "filters/in_memory_url_protocol.cc",
 313       "filters/in_memory_url_protocol.h",
 314     ]
 315     if (proprietary_codecs) {
 316       sources += [
 317         "filters/ffmpeg_aac_bitstream_converter.cc",
 318         "filters/ffmpeg_aac_bitstream_converter.h",
 319         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.cc",
 320         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.h",
 321       ]
 322     }
 323   }
 324
 325   if (current_cpu == "arm" && arm_use_neon) {
 326     defines += [ "USE_NEON" ]
 327   }
 328
 329   if (media_use_libvpx) {
 330     sources += [
 331       "filters/vpx_video_decoder.cc",
 332       "filters/vpx_video_decoder.h",
 333     ]
 334     deps += [ "//third_party/libvpx" ]
 335   }
 336
 337   if (!is_android) {
 338     sources += [
 339       "filters/opus_audio_decoder.cc",
 340       "filters/opus_audio_decoder.h",
 341       "renderers/default_renderer_factory.cc",
 342       "renderers/default_renderer_factory.h",
 343     ]
 344   } else {
 345     sources += [
 346       "midi/midi_manager_android.cc",
 347       "midi/usb_midi_device_android.cc",
 348       "midi/usb_midi_device_android.h",
 349       "midi/usb_midi_device_factory_android.cc",
 350       "midi/usb_midi_device_factory_android.h",
 351       "video/capture/android/video_capture_device_android.cc",
 352       "video/capture/android/video_capture_device_android.h",
 353       "video/capture/android/video_capture_device_factory_android.cc",
 354       "video/capture/android/video_capture_device_factory_android.h",
 355     ]
 356     deps += [
 357       "//media/base/android",
 358       "//media/base/android:media_java",
 359       "//media/base/android:media_jni_headers",
 360       "//media/base/android:video_capture_jni_headers",
 361     ]
 362   }
 363
 364   if (current_cpu != "arm" && is_chromeos) {
 365     sources += [
 366       "filters/h264_bitstream_buffer.cc",
 367       "filters/h264_bitstream_buffer.h",
 368     ]
 369   }
 370
 371   if (use_alsa) {
 372     libs += [ "asound" ]
 373     sources += [
 374       "midi/midi_manager_alsa.cc",
 375       "midi/midi_manager_alsa.h",
 376     ]
 377   }
 378
 379   if (use_udev) {
 380     deps += [ "//device/udev_linux" ]
 381   }
 382
 383   # A simple WebM encoder for animated avatars on ChromeOS.
 384
 385   if (use_ozone) {
 386     # Used for the generated listing header (ui/ozone/platform_list.h)
 387     include_dirs += [ target_gen_dir ]
 388
 389     sources += [
 390                  "ozone/media_ozone_platform.cc",
 391                  "ozone/media_ozone_platform.h",
 392                ] + get_target_outputs(":generate_ozone_constructor_list")
 393
 394     deps += [
 395       ":generate_ozone_constructor_list",
 396       "//ui/ozone",
 397     ]
 398   }
 399
 400   if (is_mac) {
 401     deps += [
 402       "//media/base/mac",
 403       "//third_party/decklink",
 404     ]
 405     libs += [
 406       "CoreMIDI.framework",
 407       "CoreVideo.framework",
 408       "OpenGL.framework",
 409       "QTKit.framework",
 410     ]
 411   }
 412
 413   if (is_openbsd) {
 414     sources -= [
 415       "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 416       "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 417     ]
 418   }
 419
 420   if (is_ios) {
 421     deps += [ "//media/base/mac" ]
 422   }
 423
 424   if (is_win) {
 425     deps += [ "//device/usb" ]
 426
 427     libs += [
 428       "mf.lib",
 429       "mfplat.lib",
 430       "mfreadwrite.lib",
 431       "mfuuid.lib",
 432     ]
 433   }
 434
 435   if (proprietary_codecs) {
 436     sources += [
 437       "filters/h264_to_annex_b_bitstream_converter.cc",
 438       "filters/h264_to_annex_b_bitstream_converter.h",
 439       "formats/mp2t/es_adapter_video.cc",
 440       "formats/mp2t/es_adapter_video.h",
 441       "formats/mp2t/es_parser.cc",
 442       "formats/mp2t/es_parser.h",
 443       "formats/mp2t/es_parser_adts.cc",
 444       "formats/mp2t/es_parser_adts.h",
 445       "formats/mp2t/es_parser_h264.cc",
 446       "formats/mp2t/es_parser_h264.h",
 447       "formats/mp2t/es_parser_mpeg1audio.cc",
 448       "formats/mp2t/es_parser_mpeg1audio.h",
 449       "formats/mp2t/mp2t_common.h",
 450       "formats/mp2t/mp2t_stream_parser.cc",
 451       "formats/mp2t/mp2t_stream_parser.h",
 452       "formats/mp2t/timestamp_unroller.cc",
 453       "formats/mp2t/timestamp_unroller.h",
 454       "formats/mp2t/ts_packet.cc",
 455       "formats/mp2t/ts_packet.h",
 456       "formats/mp2t/ts_section.h",
 457       "formats/mp2t/ts_section_pat.cc",
 458       "formats/mp2t/ts_section_pat.h",
 459       "formats/mp2t/ts_section_pes.cc",
 460       "formats/mp2t/ts_section_pes.h",
 461       "formats/mp2t/ts_section_pmt.cc",
 462       "formats/mp2t/ts_section_pmt.h",
 463       "formats/mp2t/ts_section_psi.cc",
 464       "formats/mp2t/ts_section_psi.h",
 465       "formats/mp4/aac.cc",
 466       "formats/mp4/aac.h",
 467       "formats/mp4/avc.cc",
 468       "formats/mp4/avc.h",
 469       "formats/mp4/box_definitions.cc",
 470       "formats/mp4/box_definitions.h",
 471       "formats/mp4/box_reader.cc",
 472       "formats/mp4/box_reader.h",
 473       "formats/mp4/cenc.cc",
 474       "formats/mp4/cenc.h",
 475       "formats/mp4/es_descriptor.cc",
 476       "formats/mp4/es_descriptor.h",
 477       "formats/mp4/mp4_stream_parser.cc",
 478       "formats/mp4/mp4_stream_parser.h",
 479       "formats/mp4/sample_to_group_iterator.cc",
 480       "formats/mp4/sample_to_group_iterator.h",
 481       "formats/mp4/track_run_iterator.cc",
 482       "formats/mp4/track_run_iterator.h",
 483       "formats/mpeg/adts_constants.cc",
 484       "formats/mpeg/adts_constants.h",
 485       "formats/mpeg/adts_stream_parser.cc",
 486       "formats/mpeg/adts_stream_parser.h",
 487       "formats/mpeg/mpeg1_audio_stream_parser.cc",
 488       "formats/mpeg/mpeg1_audio_stream_parser.h",
 489       "formats/mpeg/mpeg_audio_stream_parser_base.cc",
 490       "formats/mpeg/mpeg_audio_stream_parser_base.h",
 491     ]
 492   }
 493
 494   public_deps = [
 495     "//media/base",
 496     "//media/audio",
 497   ]
 498
 499   deps += [
 500     ":shared_memory_support",
 501     "//base",
 502     "//base:i18n",
 503     "//base/third_party/dynamic_annotations",
 504     "//crypto",
 505     "//crypto:platform",  # TODO(ajwong): This used to be provided by crypto.gyp via export_dependent_settings
 506     "//gpu/command_buffer/common",
 507     "//skia",
 508     "//third_party/libyuv",
 509     "//third_party/opus",
 510     "//ui/events:events_base",
 511     "//ui/gfx",
 512     "//ui/gfx/geometry",
 513     "//url",
 514   ]
 515 }
 516
 517 # Minimal media component for media/cast on iOS.
 518 if (is_ios) {
 519   component("media_for_cast_ios") {
 520     configs += [ ":media_config" ]
 521     all_dependent_configs = [ ":media_dependent_config" ]
 522     include_dirs = [ "." ]
 523     libs = [ "CoreVideo.framework" ]
 524
 525     deps = [
 526       ":shared_memory_support",
 527       "//base",
 528       "//media/base:base_for_cast_ios",
 529       "//media/base/mac",
 530       "//ui/gfx/geometry",
 531     ]
 532   }
 533 }
 534
 535 test("media_unittests") {
 536   sources = [
 537     "blink/skcanvas_video_renderer_unittest.cc",
 538     "cdm/aes_decryptor_unittest.cc",
 539     "cdm/cenc_utils_unittest.cc",
 540     "cdm/json_web_key_unittest.cc",
 541     "filters/audio_clock_unittest.cc",
 542     "filters/audio_decoder_selector_unittest.cc",
 543     "filters/audio_renderer_algorithm_unittest.cc",
 544     "filters/chunk_demuxer_unittest.cc",
 545     "filters/decrypting_audio_decoder_unittest.cc",
 546     "filters/decrypting_demuxer_stream_unittest.cc",
 547     "filters/decrypting_video_decoder_unittest.cc",
 548     "filters/fake_demuxer_stream.cc",
 549     "filters/fake_demuxer_stream.h",
 550     "filters/fake_demuxer_stream_unittest.cc",
 551     "filters/fake_video_decoder.cc",
 552     "filters/fake_video_decoder.h",
 553     "filters/fake_video_decoder_unittest.cc",
 554     "filters/file_data_source_unittest.cc",
 555     "filters/frame_processor_unittest.cc",
 556     "filters/h264_bit_reader_unittest.cc",
 557     "filters/h264_parser_unittest.cc",
 558     "filters/jpeg_parser_unittest.cc",
 559     "filters/source_buffer_stream_unittest.cc",
 560     "filters/video_decoder_selector_unittest.cc",
 561     "filters/video_frame_scheduler_impl_unittest.cc",
 562     "filters/video_frame_scheduler_unittest.cc",
 563     "filters/video_frame_stream_unittest.cc",
 564     "filters/vp8_bool_decoder_unittest.cc",
 565     "filters/vp8_parser_unittest.cc",
 566     "formats/common/offset_byte_queue_unittest.cc",
 567     "formats/webm/cluster_builder.cc",
 568     "formats/webm/cluster_builder.h",
 569     "formats/webm/opus_packet_builder.cc",
 570     "formats/webm/opus_packet_builder.h",
 571     "formats/webm/tracks_builder.cc",
 572     "formats/webm/tracks_builder.h",
 573     "formats/webm/webm_cluster_parser_unittest.cc",
 574     "formats/webm/webm_content_encodings_client_unittest.cc",
 575     "formats/webm/webm_parser_unittest.cc",
 576     "formats/webm/webm_tracks_parser_unittest.cc",
 577     "formats/webm/webm_webvtt_parser_unittest.cc",
 578     "midi/midi_manager_unittest.cc",
 579     "midi/midi_manager_usb_unittest.cc",
 580     "midi/midi_message_queue_unittest.cc",
 581     "midi/midi_message_util_unittest.cc",
 582     "midi/usb_midi_descriptor_parser_unittest.cc",
 583     "midi/usb_midi_input_stream_unittest.cc",
 584     "midi/usb_midi_output_stream_unittest.cc",
 585     "renderers/audio_renderer_impl_unittest.cc",
 586     "renderers/renderer_impl_unittest.cc",
 587     "renderers/video_renderer_impl_unittest.cc",
 588     "video/capture/fake_video_capture_device_unittest.cc",
 589     "video/capture/video_capture_device_unittest.cc",
 590     "video/h264_poc_unittest.cc",
 591   ]
 592
 593   # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 594   # See http://crbug.com/171009
 595   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 596
 597   deps = [
 598     ":media",
 599     ":test_support",
 600     "//base/allocator",
 601     "//base/test:test_support",
 602     "//media/audio:unittests",
 603     "//media/audio:test_support",
 604     "//media/base:unittests",
 605     "//media/base:test_support",
 606     "//media/test:pipeline_integration_tests",
 607     "//skia",  # Direct dependency required to inherit config.
 608     "//testing/gmock",
 609     "//testing/gtest",
 610     "//third_party/widevine/cdm:version_h",
 611     "//ui/gfx:test_support",
 612     "//url",
 613   ]
 614
 615   if (is_android) {
 616     deps += [
 617       "//media/base/android",
 618       # TODO(GYP)
 619       #"//testing/android/native_test:native_test_native_code"
 620     ]
 621   }
 622
 623   if (media_use_ffmpeg) {
 624     sources += [
 625       "ffmpeg/ffmpeg_common_unittest.cc",
 626       "filters/audio_decoder_unittest.cc",
 627       "filters/audio_file_reader_unittest.cc",
 628       "filters/blocking_url_protocol_unittest.cc",
 629       "filters/ffmpeg_demuxer_unittest.cc",
 630       "filters/ffmpeg_glue_unittest.cc",
 631       "filters/ffmpeg_video_decoder_unittest.cc",
 632       "filters/in_memory_url_protocol_unittest.cc",
 633     ]
 634   }
 635
 636   if (current_cpu != "arm" && is_chromeos) {
 637     sources += [ "filters/h264_bitstream_buffer_unittest.cc" ]
 638   }
 639
 640   if (proprietary_codecs) {
 641     sources += [
 642       "filters/ffmpeg_aac_bitstream_converter_unittest.cc",
 643       "filters/ffmpeg_h264_to_annex_b_bitstream_converter_unittest.cc",
 644       "filters/h264_to_annex_b_bitstream_converter_unittest.cc",
 645       "formats/common/stream_parser_test_base.cc",
 646       "formats/common/stream_parser_test_base.h",
 647       "formats/mp2t/es_adapter_video_unittest.cc",
 648       "formats/mp2t/es_parser_adts_unittest.cc",
 649       "formats/mp2t/es_parser_h264_unittest.cc",
 650       "formats/mp2t/es_parser_mpeg1audio_unittest.cc",
 651       "formats/mp2t/es_parser_test_base.cc",
 652       "formats/mp2t/es_parser_test_base.h",
 653       "formats/mp2t/mp2t_stream_parser_unittest.cc",
 654       "formats/mp2t/timestamp_unroller_unittest.cc",
 655       "formats/mp4/aac_unittest.cc",
 656       "formats/mp4/avc_unittest.cc",
 657       "formats/mp4/box_reader_unittest.cc",
 658       "formats/mp4/es_descriptor_unittest.cc",
 659       "formats/mp4/mp4_stream_parser_unittest.cc",
 660       "formats/mp4/sample_to_group_iterator_unittest.cc",
 661       "formats/mp4/track_run_iterator_unittest.cc",
 662       "formats/mpeg/adts_stream_parser_unittest.cc",
 663       "formats/mpeg/mpeg1_audio_stream_parser_unittest.cc",
 664     ]
 665   }
 666
 667   if (is_mac || is_ios) {
 668     deps += [ "//media/base/mac" ]
 669   }
 670
 671   if (is_mac) {
 672     sources += [
 673       "midi/midi_manager_mac_unittest.cc",
 674       "video/capture/mac/video_capture_device_factory_mac_unittest.mm",
 675     ]
 676     libs = [
 677       # Required by midi_manager_mac_unittest.cc.
 678       "CoreMIDI.framework",
 679     ]
 680   }
 681
 682   if (use_alsa) {
 683     sources += [ "midi/midi_manager_alsa_unittest.cc" ]
 684   }
 685
 686   #      include_dirs += [
 687   #        # Needed by media_drm_bridge.cc.
 688   #        target_gen_dir,
 689   #      ],
 690
 691   configs += [ ":media_config" ]
 692
 693   if (media_use_ffmpeg) {
 694     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 695   }
 696 }
 697
 698 test("media_perftests") {
 699   configs += [ ":media_config" ]
 700   deps = [
 701     ":media",
 702     ":shared_memory_support",
 703     ":test_support",
 704     "//base/test:test_support",
 705     "//media/audio:test_support",
 706     "//media/base:perftests",
 707     "//media/base:test_support",
 708     "//media/test:pipeline_integration_perftests",
 709     "//testing/gmock",
 710     "//testing/gtest",
 711     "//testing/perf",
 712     "//third_party/widevine/cdm:version_h",
 713     "//ui/gfx:test_support",
 714   ]
 715   if (is_android) {
 716     deps += [ "//ui/gl" ]
 717   }
 718   if (media_use_ffmpeg) {
 719     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 720   }
 721 }
 722
 723 source_set("test_support") {
 724   testonly = true
 725   sources = [
 726     "filters/clockless_video_frame_scheduler.cc",
 727     "filters/clockless_video_frame_scheduler.h",
 728     "filters/test_video_frame_scheduler.cc",
 729     "filters/test_video_frame_scheduler.h",
 730     "renderers/mock_gpu_video_accelerator_factories.cc",
 731     "renderers/mock_gpu_video_accelerator_factories.h",
 732     "video/mock_video_decode_accelerator.cc",
 733     "video/mock_video_decode_accelerator.h",
 734   ]
 735   deps = [
 736     ":media",
 737     ":shared_memory_support",
 738     "//base",
 739     "//skia",
 740     "//testing/gmock",
 741     "//testing/gtest",
 742   ]
 743 }
 744
 745 # TODO(dalecurtis): How to split this across audio/base directories??
 746 component("shared_memory_support") {
 747   sources = [
 748     "audio/audio_parameters.cc",
 749     "audio/audio_parameters.h",
 750     "base/audio_bus.cc",
 751     "base/audio_bus.h",
 752     "base/channel_layout.cc",
 753     "base/channel_layout.h",
 754     "base/limits.h",
 755     "base/media_export.h",
 756     "base/vector_math.cc",
 757     "base/vector_math.h",
 758   ]
 759   configs += [ ":media_config" ]
 760   defines = [ "MEDIA_IMPLEMENTATION" ]
 761   deps = [
 762     "//base",
 763   ]
 764 }
 765
 766 if (media_use_ffmpeg) {
 767   test("ffmpeg_regression_tests") {
 768     sources = [
 769       "base/run_all_unittests.cc",
 770       "ffmpeg/ffmpeg_regression_tests.cc",
 771     ]
 772
 773     configs += [ "//media:media_config" ]
 774
 775     deps = [
 776       "//base/test:test_support",
 777       "//media",
 778       "//media:test_support",
 779       "//media/audio:test_support",
 780       "//media/base:test_support",
 781       "//media/test:pipeline_integration_tests",
 782       "//testing/gmock",
 783       "//testing/gtest",
 784       "//third_party/ffmpeg",
 785       "//ui/gfx/geometry",
 786       "//ui/gfx:test_support",
 787     ]
 788   }
 789 }