content/common/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//content/common/common.gni")
   8 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
   9
  10 if (is_chromeos && current_cpu != "arm") {
  11   action("libva_generate_stubs") {
  12     extra_header = "gpu/media/va_stub_header.fragment"
  13
  14     script = "../../tools/generate_stubs/generate_stubs.py"
  15     sources = [
  16       "gpu/media/va.sigs",
  17     ]
  18     inputs = [
  19       extra_header,
  20     ]
  21     if (use_x11) {
  22       sources += [ "gpu/media/va_x11.sigs" ]
  23     }
  24     if (use_ozone) {
  25       sources += [ "gpu/media/va_drm.sigs" ]
  26     }
  27     stubs_filename_root = "va_stubs"
  28
  29     outputs = [
  30       "$target_gen_dir/gpu/media/$stubs_filename_root.cc",
  31       "$target_gen_dir/gpu/media/$stubs_filename_root.h",
  32     ]
  33     args = [
  34       "-i",
  35       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  36       "-o",
  37       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  38       "-t",
  39       "posix_stubs",
  40       "-e",
  41       rebase_path(extra_header, root_build_dir),
  42       "-s",
  43       stubs_filename_root,
  44       "-p",
  45       "content/common/gpu/media",
  46     ]
  47
  48     args += rebase_path(sources, root_build_dir)
  49   }
  50 }
  51
  52 if (is_chromeos && use_v4lplugin) {
  53   action("libv4l2_generate_stubs") {
  54     extra_header = "gpu/media/v4l2_stub_header.fragment"
  55
  56     script = "../../tools/generate_stubs/generate_stubs.py"
  57     sources = [
  58       "gpu/media/v4l2.sig",
  59     ]
  60     inputs = [
  61       extra_header,
  62     ]
  63     stubs_filename_root = "v4l2_stubs"
  64
  65     outputs = [
  66       "$target_gen_dir/gpu/media/$stubs_filename_root.cc",
  67       "$target_gen_dir/gpu/media/$stubs_filename_root.h",
  68     ]
  69     args = [
  70       "-i",
  71       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  72       "-o",
  73       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  74       "-t",
  75       "posix_stubs",
  76       "-e",
  77       rebase_path(extra_header, root_build_dir),
  78       "-s",
  79       stubs_filename_root,
  80       "-p",
  81       "content/common/gpu/media",
  82     ]
  83
  84     args += rebase_path(sources, root_build_dir)
  85   }
  86 }
  87
  88 if (is_mac) {
  89   action("libvt_generate_stubs") {
  90     extra_header = "gpu/media/vt_stubs_header.fragment"
  91
  92     script = "../../tools/generate_stubs/generate_stubs.py"
  93     sources = [
  94       "gpu/media/vt.sig",
  95     ]
  96     inputs = [
  97       extra_header,
  98     ]
  99     stubs_filename_root = "vt_stubs"
 100
 101     outputs = [
 102       "$target_gen_dir/gpu/media/$stubs_filename_root.cc",
 103       "$target_gen_dir/gpu/media/$stubs_filename_root.h",
 104     ]
 105     args = [
 106       "-i",
 107       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
 108       "-o",
 109       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
 110       "-t",
 111       "posix_stubs",
 112       "-e",
 113       rebase_path(extra_header, root_build_dir),
 114       "-s",
 115       stubs_filename_root,
 116       "-p",
 117       "content/common/gpu/media",
 118     ]
 119
 120     args += rebase_path(sources, root_build_dir)
 121   }
 122 }
 123
 124 source_set("common") {
 125   # Only the public target should depend on this. All other targets (even
 126   # internal content ones) should depend on the public one.
 127   visibility = [ "//content/public/common:common_sources" ]
 128
 129   sources = rebase_path(content_common_gypi_values.private_common_sources,
 130                         ".",
 131                         "//content")
 132
 133   configs += [
 134     "//content:content_implementation",
 135     "//build/config/compiler:no_size_t_to_int_warning",
 136   ]
 137
 138   public_deps = [
 139     "//gpu/command_buffer/common",
 140     "//third_party/WebKit/public:blink_headers",
 141   ]
 142   deps = [
 143     "//base",
 144     "//build/util:webkit_version",
 145     "//components/tracing",
 146     "//components/tracing:startup_tracing",
 147     "//gpu/command_buffer/client:gles2_interface",
 148     "//gpu/command_buffer/common:gles2_utils",
 149     "//net",
 150     "//skia",
 151     "//third_party/icu",
 152     "//ui/accessibility",
 153     "//ui/base",
 154     "//ui/base/ime",
 155     "//ui/events/ipc",
 156     "//ui/gfx",
 157     "//ui/gfx/geometry",
 158     "//ui/gfx/ipc",
 159     "//ui/shell_dialogs",
 160     "//url",
 161     "//third_party/libjingle",
 162   ]
 163
 164   if (!is_ios) {
 165     deps += [
 166       "//cc",
 167       "//ipc",
 168       "//ipc/mojo",
 169
 170       # TODO: the dependency on gl_in_process_context should be decoupled from
 171       # content and moved to android_webview. See crbug.com/365797.
 172       "//gpu/blink",
 173       "//gpu/command_buffer/client:gl_in_process_context",
 174       "//gpu/command_buffer/client:gles2_c_lib",
 175       "//gpu/command_buffer/client:gles2_cmd_helper",
 176       "//gpu/command_buffer/client:gles2_implementation",
 177       "//gpu/command_buffer/service",
 178       "//gpu/ipc",
 179       "//gpu/skia_bindings",
 180       "//media",
 181       "//media/midi",
 182       "//media:shared_memory_support",
 183       "//mojo/application/public/interfaces",
 184       "//mojo/environment:chromium",
 185       "//sandbox",
 186       "//storage/common",
 187       "//third_party/WebKit/public:blink",
 188       "//third_party/mojo/src/mojo/edk/system",
 189       "//ui/gl",
 190     ]
 191   }
 192
 193   defines = []
 194   include_dirs = []
 195   libs = []
 196   ldflags = []
 197
 198   if (is_android && use_seccomp_bpf) {
 199     set_sources_assignment_filter([])
 200     sources += [
 201       "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
 202       "sandbox_linux/sandbox_bpf_base_policy_linux.h",
 203     ]
 204     set_sources_assignment_filter(sources_assignment_filter)
 205   }
 206
 207   if (is_mac) {
 208     sources += [
 209                  "gpu/client/gpu_memory_buffer_impl_io_surface.cc",
 210                  "gpu/client/gpu_memory_buffer_impl_io_surface.h",
 211                  "gpu/gpu_memory_buffer_factory_io_surface.cc",
 212                  "gpu/gpu_memory_buffer_factory_io_surface.h",
 213                  "gpu/media/vt.h",
 214                  "gpu/media/vt_video_decode_accelerator.cc",
 215                  "gpu/media/vt_video_decode_accelerator.h",
 216                ] + get_target_outputs(":libvt_generate_stubs")
 217
 218     sources -= [ "plugin_list_posix.cc" ]
 219
 220     deps += [
 221       ":libvt_generate_stubs",
 222       "//content/app/resources",
 223       "//content:resources",
 224       "//third_party/WebKit/public:image_resources",
 225       "//third_party/WebKit/public:resources",
 226       "//ui/accelerated_widget_mac",
 227     ]
 228     libs += [
 229       "IOSurface.framework",
 230       "OpenGL.framework",
 231       "QuartzCore.framework",
 232     ]
 233   }
 234
 235   if (is_android) {
 236     sources += [
 237       "gpu/client/gpu_memory_buffer_impl_surface_texture.cc",
 238       "gpu/client/gpu_memory_buffer_impl_surface_texture.h",
 239       "gpu/gpu_memory_buffer_factory_surface_texture.cc",
 240       "gpu/gpu_memory_buffer_factory_surface_texture.h",
 241     ]
 242
 243     deps += [
 244       "//content/public/android:jni",
 245       "//content/public/android:common_aidl",
 246     ]
 247
 248     libs += [ "android" ]
 249   }
 250
 251   if (is_debug && !is_component_build) {
 252     # Content depends on the PPAPI message logging stuff; if this isn't here,
 253     # some unit test binaries won't compile. This only worked in release mode
 254     # because logging is disabled there.
 255     deps += [ "//ppapi/proxy:ipc_sources" ]
 256   }
 257
 258   if (is_ios) {
 259     sources -= [ "user_agent.cc" ]
 260     assert(false, "Need to add lots of conditions here")
 261   }
 262
 263   if (use_ozone) {
 264     deps += [
 265       "//ui/ozone:ozone",
 266       "//ui/ozone:ozone_base",
 267       "//ui/ozone/gpu",
 268     ]
 269   } else {
 270     sources -= [
 271       "cursors/webcursor_ozone.cc",
 272       "font_list_ozone.cc",
 273       "gpu/client/gpu_memory_buffer_impl_ozone_native_buffer.cc",
 274       "gpu/client/gpu_memory_buffer_impl_ozone_native_buffer.h",
 275       "gpu/gpu_memory_buffer_factory_ozone_native_buffer.cc",
 276       "gpu/gpu_memory_buffer_factory_ozone_native_buffer.h",
 277     ]
 278   }
 279
 280   if (!use_aura) {
 281     sources -= [ "cursors/webcursor_aura.cc" ]
 282   }
 283
 284   if (!use_aura || !use_x11) {
 285     sources -= [ "cursors/webcursor_aurax11.cc" ]
 286   }
 287
 288   if (use_pango) {
 289     configs += [ "//build/config/linux:pangocairo" ]
 290     if (use_ozone) {
 291       # If we're using pango, never use this ozone file (it was removed in all
 292       # non-ozone cases above).
 293       sources -= [ "font_list_ozone.cc" ]
 294     }
 295   } else {
 296     sources -= [ "font_list_pango.cc" ]
 297   }
 298
 299   if (use_x11) {
 300     configs += [
 301       "//build/config/linux:xcomposite",
 302       "//third_party/khronos:khronos_headers",
 303     ]
 304
 305     if (current_cpu != "arm" || !is_chromeos) {
 306       sources += [ "gpu/x_util.h" ]
 307     }
 308   }
 309
 310   if (enable_plugins) {
 311     deps += [ "//ppapi/shared_impl" ]
 312   } else {
 313     sources -= [
 314       "pepper_file_util.cc",
 315       "pepper_file_util.h",
 316       "pepper_messages.h",
 317       "pepper_plugin_list.cc",
 318       "pepper_plugin_list.h",
 319       "pepper_renderer_instance_data.cc",
 320       "pepper_renderer_instance_data.h",
 321       "plugin_list.cc",
 322       "plugin_list.h",
 323       "plugin_list_posix.cc",
 324       "sandbox_util.cc",
 325     ]
 326   }
 327
 328   if (is_android) {
 329     sources += [
 330       "gpu/media/android_video_decode_accelerator.cc",
 331       "gpu/media/android_video_decode_accelerator.h",
 332     ]
 333
 334     if (enable_webrtc) {
 335       deps += [ "//third_party/libyuv" ]
 336     }
 337   }
 338
 339   if (is_chromeos) {
 340     sources += [
 341       "gpu/media/accelerated_video_decoder.h",
 342       "gpu/media/h264_decoder.cc",
 343       "gpu/media/h264_decoder.h",
 344       "gpu/media/h264_dpb.cc",
 345       "gpu/media/h264_dpb.h",
 346       "gpu/media/vp8_decoder.cc",
 347       "gpu/media/vp8_decoder.h",
 348       "gpu/media/vp8_picture.cc",
 349       "gpu/media/vp8_picture.h",
 350     ]
 351     if (use_v4lplugin) {
 352       defines += [ "USE_LIBV4L2" ]
 353       sources += get_target_outputs(":libv4l2_generate_stubs")
 354       deps += [ ":libv4l2_generate_stubs" ]
 355     }
 356     if (use_v4l2_codec) {
 357       defines += [ "USE_V4L2_CODEC" ]
 358       sources += [
 359         "gpu/media/generic_v4l2_device.cc",
 360         "gpu/media/generic_v4l2_device.h",
 361         "gpu/media/v4l2_device.cc",
 362         "gpu/media/v4l2_device.h",
 363         "gpu/media/v4l2_image_processor.cc",
 364         "gpu/media/v4l2_image_processor.h",
 365         "gpu/media/v4l2_jpeg_decode_accelerator.cc",
 366         "gpu/media/v4l2_jpeg_decode_accelerator.h",
 367         "gpu/media/v4l2_slice_video_decode_accelerator.cc",
 368         "gpu/media/v4l2_slice_video_decode_accelerator.h",
 369         "gpu/media/v4l2_video_decode_accelerator.cc",
 370         "gpu/media/v4l2_video_decode_accelerator.h",
 371         "gpu/media/v4l2_video_encode_accelerator.cc",
 372         "gpu/media/v4l2_video_encode_accelerator.h",
 373       ]
 374       libs = [
 375         "EGL",
 376         "GLESv2",
 377       ]
 378     }
 379     if (current_cpu == "arm") {
 380       sources += [
 381         "gpu/media/tegra_v4l2_device.cc",
 382         "gpu/media/tegra_v4l2_device.h",
 383       ]
 384     }
 385     if (current_cpu != "arm") {
 386       sources += [
 387                    "gpu/media/va_surface.h",
 388                    "gpu/media/vaapi_jpeg_decode_accelerator.cc",
 389                    "gpu/media/vaapi_jpeg_decode_accelerator.h",
 390                    "gpu/media/vaapi_jpeg_decoder.cc",
 391                    "gpu/media/vaapi_jpeg_decoder.h",
 392                    "gpu/media/vaapi_picture.cc",
 393                    "gpu/media/vaapi_picture.h",
 394                    "gpu/media/vaapi_video_decode_accelerator.cc",
 395                    "gpu/media/vaapi_video_decode_accelerator.h",
 396                    "gpu/media/vaapi_video_encode_accelerator.cc",
 397                    "gpu/media/vaapi_video_encode_accelerator.h",
 398                    "gpu/media/vaapi_wrapper.cc",
 399                    "gpu/media/vaapi_wrapper.h",
 400                  ] + get_target_outputs(":libva_generate_stubs")
 401       configs += [
 402         "//third_party/libva:libva_config",
 403         "//third_party/libyuv:libyuv_config",
 404       ]
 405       deps += [
 406         ":libva_generate_stubs",
 407         "//media",
 408         "//third_party/libyuv",
 409       ]
 410       if (use_x11) {
 411         sources += [
 412           "gpu/media/vaapi_tfp_picture.cc",
 413           "gpu/media/vaapi_tfp_picture.h",
 414         ]
 415       }
 416       if (use_ozone) {
 417         sources += [
 418           "gpu/media/vaapi_drm_picture.cc",
 419           "gpu/media/vaapi_drm_picture.h",
 420         ]
 421       }
 422     }
 423   }
 424
 425   if (is_win) {
 426     sources += [
 427       "gpu/media/dxva_video_decode_accelerator.cc",
 428       "gpu/media/dxva_video_decode_accelerator.h",
 429     ]
 430     configs += [ "//third_party/khronos:khronos_headers" ]
 431     deps += [ "//ui/gl" ]
 432     libs += [
 433       "d3d9.lib",
 434       "d3d11.lib",
 435       "dxva2.lib",
 436       "strmiids.lib",
 437       "mf.lib",
 438       "mfplat.lib",
 439       "mfuuid.lib",
 440     ]
 441     ldflags += [
 442       "/DELAYLOAD:d3d9.dll",
 443       "/DELAYLOAD:d3d11.dll",
 444       "/DELAYLOAD:dxva2.dll",
 445       "/DELAYLOAD:mf.dll",
 446       "/DELAYLOAD:mfplat.dll",
 447     ]
 448
 449     # TODO(GYP): extract_xinput action.
 450   }
 451
 452   if (!is_win || !use_aura) {
 453     sources -= [ "cursors/webcursor_aurawin.cc" ]
 454   }
 455
 456   if (use_seccomp_bpf) {
 457     defines += [ "USE_SECCOMP_BPF" ]
 458   } else {
 459     if (is_linux) {
 460       sources -= [
 461         "sandbox_linux/bpf_cros_arm_gpu_policy_linux.cc",
 462         "sandbox_linux/bpf_cros_arm_gpu_policy_linux.h",
 463         "sandbox_linux/bpf_gpu_policy_linux.cc",
 464         "sandbox_linux/bpf_gpu_policy_linux.h",
 465         "sandbox_linux/bpf_ppapi_policy_linux.cc",
 466         "sandbox_linux/bpf_ppapi_policy_linux.h",
 467         "sandbox_linux/bpf_renderer_policy_linux.cc",
 468         "sandbox_linux/bpf_renderer_policy_linux.h",
 469         "sandbox_linux/bpf_utility_policy_linux.cc",
 470         "sandbox_linux/bpf_utility_policy_linux.h",
 471         "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
 472         "sandbox_linux/sandbox_bpf_base_policy_linux.h",
 473       ]
 474     }
 475     if (is_android) {
 476       sources -= [
 477         "sandbox_linux/android/sandbox_bpf_base_policy_android.cc",
 478         "sandbox_linux/android/sandbox_bpf_base_policy_android.h",
 479       ]
 480     }
 481   }
 482
 483   if (is_win && current_cpu == "x64") {
 484     # TODO(jschuh): Remove this after crbug.com/173851 gets fixed.
 485     cflags = [ "/bigobj" ]
 486   }
 487 }
 488
 489 mojom("mojo_bindings") {
 490   sources = [
 491     "application_setup.mojom",
 492     "background_sync_service.mojom",
 493     "geolocation_service.mojom",
 494     "image_downloader/image_downloader.mojom",
 495     "permission_service.mojom",
 496     "presentation/presentation_service.mojom",
 497     "process_control.mojom",
 498     "render_frame_setup.mojom",
 499     "service_port_service.mojom",
 500     "vr_service.mojom",
 501   ]
 502
 503   import_dirs = [ "//mojo/services" ]
 504
 505   deps = [
 506     "//content/public/common:mojo_bindings",
 507     "//mojo/application/public/interfaces",
 508     "//skia/public/interfaces",
 509     "//ui/mojo/geometry:interfaces",
 510   ]
 511 }