third_party/cld_2/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6
   7 gypi_values = exec_script("//build/gypi_to_gn.py",
   8                           [ rebase_path("cld_2.gyp") ],
   9                           "scope",
  10                           [ "cld_2.gyp" ])
  11
  12 # This variable controls which dependency is resolved by the pass-through
  13 # target 'cld2_platform_impl', and allows the embedder to choose which
  14 # kind of CLD2 support is required at build time:
  15 #
  16 # - If the value is 'static', then the cld2_platform_impl target will depend
  17 #   upon the cld2_static target
  18 # - If the value is 'dynamic', then the cld2_platform_impl target will
  19 #   depend upon the cld2_dynamic target.
  20 #
  21 # High-level targets for Chromium unit tests hard-code a dependency upon
  22 # cld2_static because doing so makes sense for use cases that aren't
  23 # affected by the loading of language detection data; however, most other
  24 # targets (e.g. the final executables and interactive UI tests) should be
  25 # linked against whatever the embedder needs.
  26 #
  27 # Maintainers:
  28 # This value may be reasonably tweaked on a per-platform basis.
  29 # Don't forget to update this file as well to match:
  30 #   components/translate/content/browser/browser_cld_utils.cc
  31 #   components/translate/content/renderer/renderer_cld_utils.cc
  32 cld2_platform_support = "static"
  33
  34 cld2_table_size = 2
  35
  36 source_set("cld2_data") {
  37   sources = gypi_values.cld2_data_sources
  38   if (cld2_table_size == 0) {
  39     sources += gypi_values.cld2_data_smallest_sources
  40   } else if (cld2_table_size == 2) {
  41     sources += gypi_values.cld2_data_largest_sources
  42   }
  43
  44   include_dirs = [
  45     "src/internal",
  46     "src/public",
  47   ]
  48
  49   config("cld2_data_warnings") {
  50     if (is_clang) {
  51       # The generated files don't have braces around subobject initializers.
  52       cflags = [ "-Wno-missing-braces" ]
  53     }
  54   }
  55   configs -= [ "//build/config/compiler:chromium_code" ]
  56   configs += [ "//build/config/compiler:no_chromium_code" ]
  57   configs += [ ":cld2_data_warnings" ]
  58 }
  59
  60 # As in the corresponding gyp file, this just builds the core interfaces for
  61 # CLD2. You must still declare a dependency on a specific data set, either
  62 # cld2_dynamic or cld2_static.
  63 source_set("cld_2") {
  64   sources = gypi_values.cld2_core_sources
  65   include_dirs = [
  66     "src/internal",
  67     "src/public",
  68   ]
  69
  70   configs -= [ "//build/config/compiler:chromium_code" ]
  71   configs += [ "//build/config/compiler:no_chromium_code" ]
  72 }
  73
  74 source_set("cld2_platform_impl") {
  75   deps = []
  76   if (cld2_platform_support == "static") {
  77     deps += [ ":cld2_static" ]
  78   } else if (cld2_platform_support == "dynamic") {
  79     deps += [ ":cld2_dynamic" ]
  80   }
  81 }
  82
  83 config("cld2_warnings") {
  84   if (is_clang) {
  85     cflags = [
  86       # cld_2 has unused private fields.
  87       "-Wno-unused-private-field",
  88     ]
  89   }
  90 }
  91
  92 static_library("cld2_static") {
  93   sources = gypi_values.cld2_core_impl_sources
  94   include_dirs = [
  95     "src/internal",
  96     "src/public",
  97   ]
  98
  99   deps = [
 100     ":cld_2",
 101     ":cld2_data",
 102   ]
 103   configs -= [ "//build/config/compiler:chromium_code" ]
 104   configs += [
 105     "//build/config/compiler:no_chromium_code",
 106     ":cld2_warnings",
 107   ]
 108 }
 109
 110 config("cld2_dynamic_mode_config") {
 111   defines = [ "CLD2_DYNAMIC_MODE" ]
 112 }
 113
 114 static_library("cld2_dynamic") {
 115   sources = gypi_values.cld2_core_sources + gypi_values.cld2_core_impl_sources +
 116             gypi_values.cld2_dynamic_data_loader_sources
 117   include_dirs = [
 118     "src/internal",
 119     "src/public",
 120   ]
 121
 122   configs -= [ "//build/config/compiler:chromium_code" ]
 123   configs += [
 124     ":cld2_dynamic_mode_config",
 125     "//build/config/compiler:no_chromium_code",
 126     ":cld2_warnings",
 127   ]
 128 }
 129
 130 # Does not build on Windows.
 131 if (!is_win) {
 132   executable("cld_2_dynamic_data_tool") {
 133     sources = [
 134       "src/internal/cld2_dynamic_data_extractor.cc",
 135       "src/internal/cld2_dynamic_data_extractor.h",
 136       "src/internal/cld2_dynamic_data_tool.cc",
 137     ]
 138
 139     include_dirs = [
 140       "src/internal",
 141       "src/public",
 142     ]
 143
 144     deps = [
 145       ":cld2_data",
 146       ":cld2_dynamic",
 147     ]
 148
 149     configs -= [ "//build/config/compiler:chromium_code" ]
 150     configs += [
 151       ":cld2_dynamic_mode_config",
 152       "//build/config/compiler:no_chromium_code",
 153     ]
 154   }
 155 }