ui/accessibility/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//build/json_schema_api.gni")
   7 import("//testing/test.gni")
   8 if (is_android) {
   9   import("//build/config/android/rules.gni")
  10 }
  11
  12 component("accessibility") {
  13   sources = [
  14     "ax_node.cc",
  15     "ax_node.h",
  16     "ax_node_data.cc",
  17     "ax_node_data.h",
  18     "ax_serializable_tree.cc",
  19     "ax_serializable_tree.h",
  20     "ax_text_utils.cc",
  21     "ax_text_utils.h",
  22     "ax_tree.cc",
  23     "ax_tree.h",
  24     "ax_tree_serializer.cc",
  25     "ax_tree_serializer.h",
  26     "ax_tree_source.h",
  27     "ax_tree_update.cc",
  28     "ax_tree_update.h",
  29     "ax_view_state.cc",
  30     "ax_view_state.h",
  31     "platform/ax_platform_node.cc",
  32     "platform/ax_platform_node.h",
  33     "platform/ax_platform_node_base.cc",
  34     "platform/ax_platform_node_base.h",
  35     "platform/ax_platform_node_delegate.h",
  36     "platform/ax_platform_node_mac.h",
  37     "platform/ax_platform_node_mac.mm",
  38     "platform/ax_platform_node_win.cc",
  39     "platform/ax_platform_node_win.h",
  40   ]
  41
  42   defines = [ "ACCESSIBILITY_IMPLEMENTATION" ]
  43
  44   public_deps = [
  45     ":ax_gen",
  46     "//base",
  47     "//ui/gfx",
  48     "//ui/gfx/geometry",
  49   ]
  50
  51   if (is_win) {
  52     public_deps += [ "//third_party/iaccessible2" ]
  53   }
  54
  55   if (use_aura && !is_chromeos && is_linux && use_x11) {
  56     sources += [
  57       "platform/atk_util_auralinux.cc",
  58       "platform/atk_util_auralinux.h",
  59       "platform/ax_platform_node_auralinux.cc",
  60       "platform/ax_platform_node_auralinux.h",
  61     ]
  62
  63     configs += [
  64       "//build/config/linux:atk",
  65       "//build/config/linux:atk_warnings",
  66       "//build/config/linux:gconf",
  67       "//build/config/linux:glib",
  68     ]
  69   }
  70 }
  71
  72 if (is_android) {
  73   android_library("ui_accessibility_java") {
  74     deps = []
  75     srcjar_deps = [ ":ax_enumerations_srcjar" ]
  76   }
  77
  78   java_cpp_enum("ax_enumerations_srcjar") {
  79     sources = [
  80       "ax_enums.idl",
  81     ]
  82     outputs = [
  83       "org/chromium/ui/accessibility/AXTextStyle.java",
  84     ]
  85   }
  86 }
  87
  88 source_set("test_support") {
  89   sources = [
  90     "platform/test_ax_node_wrapper.cc",
  91     "platform/test_ax_node_wrapper.h",
  92     "tree_generator.cc",
  93     "tree_generator.h",
  94   ]
  95
  96   deps = [
  97     ":accessibility",
  98   ]
  99 }
 100
 101 test("accessibility_unittests") {
 102   sources = [
 103     "ax_generated_tree_unittest.cc",
 104     "ax_text_utils_unittest.cc",
 105     "ax_tree_serializer_unittest.cc",
 106     "ax_tree_unittest.cc",
 107     "platform/ax_platform_node_win_unittest.cc",
 108   ]
 109
 110   deps = [
 111     ":accessibility",
 112     ":test_support",
 113     "//base",
 114     "//base/test:run_all_unittests",
 115     "//testing/gtest",
 116     "//ui/gfx",
 117     "//ui/gfx/geometry",
 118   ]
 119
 120   if (is_win) {
 121     deps += [ "//third_party/iaccessible2" ]
 122   }
 123 }
 124
 125 json_schema_api("ax_gen") {
 126   sources = [
 127     "ax_enums.idl",
 128   ]
 129   deps = [
 130     "//base/third_party/dynamic_annotations",
 131   ]
 132   root_namespace = "ui"
 133   schemas = true
 134 }