ui/ozone/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//ui/ozone/ozone.gni")
   6
   7 # The list of platforms that will be built.
   8 ozone_platforms = []
   9
  10 # Extra dependencies to pull into ui/ozone for built platforms.
  11 ozone_platform_deps = []
  12
  13 # Extra dependencies to pull into ozone_unittests for built platforms.
  14 ozone_platform_test_deps = []
  15
  16 if (ozone_platform_egltest) {
  17   ozone_platforms += [ "egltest" ]
  18   ozone_platform_deps += [ "platform/egltest" ]
  19 }
  20
  21 if (ozone_platform_test) {
  22   ozone_platforms += [ "test" ]
  23   ozone_platform_deps += [ "platform/test" ]
  24 }
  25
  26 if (ozone_platform_caca) {
  27   ozone_platforms += [ "caca" ]
  28   ozone_platform_deps += [ "platform/caca" ]
  29 }
  30
  31 if (ozone_platform_dri) {
  32   ozone_platforms += [ "dri" ]
  33   ozone_platform_deps += [ "platform/dri" ]
  34   ozone_platform_test_deps += [ "platform/dri:dri_unittests" ]
  35 }
  36
  37 if (ozone_platform_gbm) {
  38   ozone_platforms += [ "gbm" ]
  39   ozone_platform_deps += [ "platform/dri:gbm" ]
  40 }
  41
  42 platform_list_cc_file = "$target_gen_dir/platform_list.cc"
  43 platform_list_h_file = "$target_gen_dir/platform_list.h"
  44 platform_list_txt_file = "$target_gen_dir/platform_list.txt"
  45 constructor_list_cc_file = "$target_gen_dir/constructor_list.cc"
  46
  47 # GYP version: ui/ozone/ozone.gyp:ozone_base
  48 component("ozone_base") {
  49   sources = [
  50     "public/cursor_factory_ozone.cc",
  51     "public/cursor_factory_ozone.h",
  52     "public/gpu_platform_support.cc",
  53     "public/gpu_platform_support.h",
  54     "public/gpu_platform_support_host.cc",
  55     "public/gpu_platform_support_host.h",
  56     "public/overlay_candidates_ozone.cc",
  57     "public/overlay_candidates_ozone.h",
  58     "public/surface_factory_ozone.cc",
  59     "public/surface_factory_ozone.h",
  60     "public/surface_ozone_canvas.h",
  61     "public/surface_ozone_egl.h",
  62   ]
  63
  64   defines = [ "OZONE_BASE_IMPLEMENTATION" ]
  65
  66   deps = [
  67     "//base",
  68     "//skia",
  69     "//ui/gfx/geometry",
  70   ]
  71 }
  72
  73 component("ozone") {
  74   sources = [
  75     platform_list_cc_file,
  76     platform_list_h_file,
  77     constructor_list_cc_file,
  78
  79     "common/display_mode_proxy.cc",
  80     "common/display_mode_proxy.h",
  81     "common/display_snapshot_proxy.cc",
  82     "common/display_snapshot_proxy.h",
  83     "common/display_util.cc",
  84     "common/display_util.h",
  85     "common/gpu/ozone_gpu_message_generator.cc",
  86     "common/gpu/ozone_gpu_message_generator.h",
  87     "common/gpu/ozone_gpu_message_params.cc",
  88     "common/gpu/ozone_gpu_message_params.h",
  89     "common/gpu/ozone_gpu_messages.h",
  90     "common/native_display_delegate_ozone.cc",
  91     "common/native_display_delegate_ozone.h",
  92     "public/ozone_platform.cc",
  93     "public/ozone_platform.h",
  94     "public/ozone_switches.cc",
  95     "public/ozone_switches.h",
  96     "public/ui_thread_gpu.cc",
  97     "public/ui_thread_gpu.h",
  98     "platform_selection.cc",
  99     "platform_selection.h",
 100   ]
 101
 102   defines = [ "OZONE_IMPLEMENTATION" ]
 103
 104   deps = [
 105     ":generate_constructor_list",
 106     ":generate_ozone_platform_list",
 107     ":ozone_base",
 108     "//base",
 109     "//ipc",
 110     "//skia",
 111     "//ui/display/types",
 112     "//ui/display/util",
 113     "//ui/events",
 114     "//ui/events/ozone:events_ozone",
 115     "//ui/gfx",
 116     "//ui/gfx/geometry",
 117     "//ui/gfx/ipc",
 118     # TODO(GYP) the GYP version has a way to add additional dependencies via
 119     # build flags.
 120   ] + ozone_platform_deps
 121
 122 }
 123
 124 # GYP version: ui/ozone/ozone.gyp:generate_ozone_platform_list
 125 action("generate_ozone_platform_list") {
 126   script = "generate_ozone_platform_list.py"
 127   outputs = [
 128     platform_list_cc_file,
 129     platform_list_h_file,
 130     platform_list_txt_file
 131   ]
 132
 133   args = [
 134     "--output_cc=" + rebase_path(platform_list_cc_file, root_build_dir),
 135     "--output_h=" + rebase_path(platform_list_h_file, root_build_dir),
 136     "--output_txt=" + rebase_path(platform_list_txt_file, root_build_dir),
 137     "--default=$ozone_platform",
 138   ] + ozone_platforms
 139 }
 140
 141 # GYP version: ui/ozone/ozone.gyp:generate_constructor_list
 142 action("generate_constructor_list") {
 143   script = "generate_constructor_list.py"
 144
 145   source_prereqs = [
 146     platform_list_txt_file,
 147   ]
 148   outputs = [
 149     constructor_list_cc_file,
 150   ]
 151
 152   args = [
 153     "--platform_list=" + rebase_path(platform_list_txt_file, root_build_dir),
 154     "--output_cc=" + rebase_path(constructor_list_cc_file, root_build_dir),
 155     "--namespace=ui",
 156     "--typename=OzonePlatform",
 157     "--include=\"ui/ozone/public/ozone_platform.h\"",
 158   ]
 159
 160   deps = [ ":generate_ozone_platform_list" ]
 161 }
 162
 163 test("ozone_unittests") {
 164   sources = [
 165     "run_all_unittests.cc",
 166   ]
 167
 168   deps = [
 169     "//base/test:test_support",
 170     "//testing/gtest",
 171   ] + ozone_platform_test_deps
 172 }