remoting/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//remoting/remoting_version.gni")
   8 import("//testing/test.gni")
   9
  10 enable_remoting_host = is_win || is_mac || is_chromeos || use_x11
  11
  12 # Various remoting targets need this version definition.
  13 config("version") {
  14   defines = [ "VERSION=$version_full" ]
  15 }
  16
  17 # GYP version: remoting/remoting_test.gypi:remoting_test_common
  18 source_set("test_support") {
  19   testonly = true
  20
  21   sources = [
  22     # Files from remoting_test_common not in separate test_support targets.
  23     "signaling/fake_signal_strategy.cc",
  24     "signaling/fake_signal_strategy.h",
  25     "signaling/mock_signal_strategy.cc",
  26     "signaling/mock_signal_strategy.h",
  27     "test/access_token_fetcher.cc",
  28     "test/app_remoting_test_driver_environment.cc",
  29     "test/fake_access_token_fetcher.cc",
  30     "test/fake_network_dispatcher.cc",
  31     "test/fake_network_dispatcher.h",
  32     "test/fake_network_manager.cc",
  33     "test/fake_network_manager.h",
  34     "test/fake_port_allocator.cc",
  35     "test/fake_port_allocator.h",
  36     "test/fake_remote_host_info_fetcher.cc",
  37     "test/fake_socket_factory.cc",
  38     "test/fake_socket_factory.h",
  39     "test/leaky_bucket.cc",
  40     "test/leaky_bucket.h",
  41     "test/mock_access_token_fetcher.cc",
  42     "test/refresh_token_store.cc",
  43     "test/remote_host_info.cc",
  44     "test/remote_host_info_fetcher.cc",
  45   ]
  46
  47   deps = [
  48     "//base",
  49     "//components/policy:test_support",
  50     "//net",
  51     "//remoting/base",
  52     "//remoting/client",
  53     "//remoting/codec",
  54     "//remoting/protocol:test_support",
  55     "//remoting/resources",
  56     "//testing/gmock",
  57     "//testing/gtest",
  58   ]
  59
  60   if (enable_remoting_host) {
  61     deps += [ "//remoting/host:test_support" ]
  62   }
  63 }
  64
  65 # TODO(GYP) remoting_unittests on Mac/Windows. Currently this fails with a
  66 # duplicate resource error on linking on Windows. Just needs to be checked on
  67 # Mac.
  68 if (!is_win && !is_mac) {
  69   test("remoting_unittests") {
  70     # Sources not included in one of the more specific unit_tests deps.
  71     sources = [
  72       "signaling/iq_sender_unittest.cc",
  73       "signaling/log_to_server_unittest.cc",
  74       "signaling/server_log_entry_unittest.cc",
  75       "signaling/server_log_entry_unittest.h",
  76       "test/access_token_fetcher_unittest.cc",
  77       "test/app_remoting_test_driver_environment_unittest.cc",
  78       "test/remote_host_info_fetcher_unittest.cc",
  79     ]
  80
  81     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  82     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  83
  84     deps = [
  85       ":test_support",
  86       "//base/allocator",
  87       "//google_apis",
  88       "//remoting/base:unit_tests",
  89       "//remoting/client:unit_tests",
  90       "//remoting/protocol:unit_tests",
  91       "//testing/gmock",
  92       "//testing/gtest",
  93       "//third_party/webrtc",
  94     ]
  95
  96     if (is_android) {
  97       deps += [ "//testing/android:native_test_native_code" ]
  98     } else {
  99       deps += [ "//remoting/client/plugin" ]
 100     }
 101
 102     if (enable_remoting_host) {
 103       deps += [
 104         "//remoting/codec:unit_tests",
 105         "//remoting/host:unit_tests",
 106       ]
 107     }
 108
 109     if (enable_webrtc) {
 110       deps += [
 111         "//third_party/libjingle:libjingle_webrtc",
 112         "//third_party/libjingle:libpeerconnection",
 113       ]
 114     }
 115   }
 116 } else {
 117   group("remoting_unittests") {
 118   }
 119 }