chrome/utility/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7
   8 gypi_values = exec_script("//build/gypi_to_gn.py",
   9                           [ rebase_path("../chrome_utility.gypi") ],
  10                           "scope",
  11                           [ "../chrome_utility.gypi" ])
  12
  13 static_library("utility") {
  14   sources = rebase_path(gypi_values.chrome_utility_sources, ".", "..")
  15   defines = []
  16
  17   public_deps = []
  18   deps = [
  19     "//base",
  20     "//components/search_engines",
  21     "//components/strings",
  22     "//components/url_fixer",
  23     "//content/public/common",
  24     "//content/public/utility",
  25     "//media",
  26     "//skia",
  27     "//third_party/libxml",
  28     "//chrome:resources",
  29     "//chrome:strings",
  30     "//chrome/common",
  31   ]
  32
  33   if (is_android) {
  34     if (use_seccomp_bpf) {
  35       deps += [ "//sandbox/linux:seccomp_bpf" ]
  36       defines += [ "USE_SECCOMP_BPF" ]
  37     }
  38   } else {
  39     deps += [
  40       "//chrome/common:mojo_bindings",
  41       "//net:net_utility_services",
  42     ]
  43     sources +=
  44         rebase_path(gypi_values.chrome_utility_importer_sources, ".", "..")
  45   }
  46
  47   if (enable_extensions) {
  48     deps += [
  49       "//chrome/common/extensions/api",
  50       "//extensions/utility",
  51     ]
  52
  53     public_deps += [ "//chrome/common/extensions/api" ]
  54
  55     sources +=
  56         rebase_path(gypi_values.chrome_utility_extensions_sources, ".", "..")
  57     sources +=
  58         rebase_path(gypi_values.chrome_utility_shared_media_sources, ".", "..")
  59
  60     # Prevent wininet from loading in the renderer. http://crbug.com/460679
  61     if (is_win) {
  62       ldflags = [ "/DELAYLOAD:wininet.dll" ]
  63     }
  64
  65     if (is_win || is_mac) {
  66       sources +=
  67           rebase_path(gypi_values.chrome_utility_win_mac_media_gallery_sources,
  68                       ".",
  69                       "..")
  70       deps += [ "//components/wifi" ]
  71     } else {
  72       sources += [ "image_writer/image_writer_stub.cc" ]
  73     }
  74
  75     if (is_mac) {
  76       sources +=
  77           rebase_path(gypi_values.chrome_utility_mac_media_gallery_sources,
  78                       ".",
  79                       "..")
  80     }
  81
  82     # Linux should use system libexif
  83     if (!is_linux) {
  84       # TODO(thestig): Properly support building on Linux and ChromeOS.
  85       deps += [ "//third_party/libexif" ]
  86     }
  87   }
  88
  89   if (use_nss_certs) {
  90     sources += [
  91       "importer/nss_decryptor_system_nss.cc",
  92       "importer/nss_decryptor_system_nss.h",
  93     ]
  94     deps += [
  95       "//crypto",
  96       "//crypto:platform",
  97     ]
  98   }
  99
 100   if (!enable_print_preview) {
 101     sources -= [
 102       "printing_handler.cc",
 103       "printing_handler.h",
 104     ]
 105   }
 106
 107   if (!enable_mdns) {
 108     sources -= [
 109       "local_discovery/service_discovery_message_handler.cc",
 110       "local_discovery/service_discovery_message_handler.h",
 111     ]
 112   }
 113 }