net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//build/module_args/v8.gni")
   9 import("//url/config.gni")
  10 import("//testing/test.gni")
  11 import("//third_party/icu/config.gni")
  12 import("//third_party/protobuf/proto_library.gni")
  13
  14 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  15 # Currently, that file can't be imported multiple times.  Make this always
  16 # imported when http://crbug.com/393704 is fixed.
  17 if (!is_android) {
  18   import("//tools/grit/grit_rule.gni")
  19 }
  20
  21 if (is_android) {
  22   import("//build/config/android/config.gni")
  23   import("//build/config/android/rules.gni")
  24 } else if (is_mac) {
  25   import("//build/config/mac/mac_sdk.gni")
  26 }
  27
  28 # The list of net files is kept in net.gypi. Read it.
  29 gypi_values = exec_script("//build/gypi_to_gn.py",
  30                           [ rebase_path("net.gypi") ],
  31                           "scope",
  32                           [ "net.gypi" ])
  33
  34 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  35 # configuration (krb5.conf and so on).
  36 use_kerberos = !is_chromeos && !is_android && !is_ios
  37
  38 # The way the cache uses mmap() is inefficient on some Android devices. If
  39 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  40 # pretty confident that mmap-ing the index would not hurt any existing x86
  41 # android devices, but we cannot be so sure about the variety of ARM devices.
  42 # So enable it for x86 only for now.
  43 posix_avoid_mmap = is_android && current_cpu != "x86"
  44
  45 # WebSockets and socket stream code are used everywhere except iOS.
  46 enable_websockets = !is_ios
  47 use_v8_in_net = !is_ios
  48 enable_built_in_dns = !is_ios
  49 disable_ftp_support = is_ios
  50
  51 declare_args() {
  52   # Disables support for file URLs.  File URL support requires use of icu.
  53   disable_file_support = false
  54 }
  55
  56 config("net_config") {
  57   defines = []
  58   if (posix_avoid_mmap) {
  59     defines += [ "POSIX_AVOID_MMAP" ]
  60   }
  61   if (disable_file_support) {
  62     defines += [ "DISABLE_FILE_SUPPORT" ]
  63   }
  64 }
  65
  66 component("net") {
  67   sources =
  68       gypi_values.net_nacl_common_sources + gypi_values.net_non_nacl_sources
  69
  70   cflags = []
  71   defines = [
  72     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  73     # 0) which implies that we run pkg_config on kerberos and link to that
  74     # rather than setting this define which will dynamically open it. That
  75     # doesn't seem to be set in the regular builds, so we're skipping this
  76     # capability here.
  77     "DLOPEN_KERBEROS",
  78     "NET_IMPLEMENTATION",
  79   ]
  80
  81   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  82   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  83   public_configs = [ ":net_config" ]
  84   include_dirs = []
  85
  86   public_deps = [
  87     ":net_quic_proto",
  88     "//crypto",
  89     "//crypto:platform",
  90     "//url",
  91   ]
  92   deps = [
  93     ":net_resources",
  94     "//base",
  95     "//base:prefs",
  96     "//base/third_party/dynamic_annotations",
  97     "//net/base/registry_controlled_domains",
  98     "//sdch",
  99     "//third_party/protobuf:protobuf_lite",
 100     "//third_party/zlib",
 101     "//url",
 102   ]
 103
 104   if (use_kerberos) {
 105     defines += [ "USE_KERBEROS" ]
 106     if (is_android) {
 107       include_dirs += [ "/usr/include/kerberosV" ]
 108     }
 109   } else {
 110     sources -= [
 111       "http/http_auth_gssapi_posix.cc",
 112       "http/http_auth_gssapi_posix.h",
 113       "http/http_auth_handler_negotiate.cc",
 114       "http/http_auth_handler_negotiate.h",
 115     ]
 116   }
 117
 118   if (is_posix) {
 119     if (posix_avoid_mmap) {
 120       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 121     } else {
 122       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 123     }
 124   }
 125
 126   if (disable_file_support) {
 127     sources -= [
 128       "base/directory_lister.cc",
 129       "base/directory_lister.h",
 130       "url_request/file_protocol_handler.cc",
 131       "url_request/file_protocol_handler.h",
 132       "url_request/url_request_file_dir_job.cc",
 133       "url_request/url_request_file_dir_job.h",
 134       "url_request/url_request_file_job.cc",
 135       "url_request/url_request_file_job.h",
 136     ]
 137   }
 138
 139   if (disable_ftp_support) {
 140     sources -= [
 141       "ftp/ftp_auth_cache.cc",
 142       "ftp/ftp_auth_cache.h",
 143       "ftp/ftp_ctrl_response_buffer.cc",
 144       "ftp/ftp_ctrl_response_buffer.h",
 145       "ftp/ftp_directory_listing_parser.cc",
 146       "ftp/ftp_directory_listing_parser.h",
 147       "ftp/ftp_directory_listing_parser_ls.cc",
 148       "ftp/ftp_directory_listing_parser_ls.h",
 149       "ftp/ftp_directory_listing_parser_netware.cc",
 150       "ftp/ftp_directory_listing_parser_netware.h",
 151       "ftp/ftp_directory_listing_parser_os2.cc",
 152       "ftp/ftp_directory_listing_parser_os2.h",
 153       "ftp/ftp_directory_listing_parser_vms.cc",
 154       "ftp/ftp_directory_listing_parser_vms.h",
 155       "ftp/ftp_directory_listing_parser_windows.cc",
 156       "ftp/ftp_directory_listing_parser_windows.h",
 157       "ftp/ftp_network_layer.cc",
 158       "ftp/ftp_network_layer.h",
 159       "ftp/ftp_network_session.cc",
 160       "ftp/ftp_network_session.h",
 161       "ftp/ftp_network_transaction.cc",
 162       "ftp/ftp_network_transaction.h",
 163       "ftp/ftp_request_info.h",
 164       "ftp/ftp_response_info.cc",
 165       "ftp/ftp_response_info.h",
 166       "ftp/ftp_server_type_histograms.cc",
 167       "ftp/ftp_server_type_histograms.h",
 168       "ftp/ftp_transaction.h",
 169       "ftp/ftp_transaction_factory.h",
 170       "ftp/ftp_util.cc",
 171       "ftp/ftp_util.h",
 172       "url_request/ftp_protocol_handler.cc",
 173       "url_request/ftp_protocol_handler.h",
 174       "url_request/url_request_ftp_job.cc",
 175       "url_request/url_request_ftp_job.h",
 176     ]
 177   }
 178
 179   if (enable_built_in_dns) {
 180     defines += [ "ENABLE_BUILT_IN_DNS" ]
 181   } else {
 182     sources -= [
 183       "dns/address_sorter_posix.cc",
 184       "dns/address_sorter_posix.h",
 185       "dns/dns_client.cc",
 186     ]
 187   }
 188
 189   if (use_openssl) {
 190     sources -= [
 191       "base/nss_memio.c",
 192       "base/nss_memio.h",
 193       "cert/ct_log_verifier_nss.cc",
 194       "cert/ct_objects_extractor_nss.cc",
 195       "cert/jwk_serializer_nss.cc",
 196       "cert/scoped_nss_types.h",
 197       "cert/x509_util_nss.cc",
 198       "quic/crypto/aead_base_decrypter_nss.cc",
 199       "quic/crypto/aead_base_encrypter_nss.cc",
 200       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 201       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 202       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 203       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 204       "quic/crypto/channel_id_nss.cc",
 205       "quic/crypto/p256_key_exchange_nss.cc",
 206       "socket/nss_ssl_util.cc",
 207       "socket/nss_ssl_util.h",
 208       "socket/ssl_client_socket_nss.cc",
 209       "socket/ssl_client_socket_nss.h",
 210       "socket/ssl_server_socket_nss.cc",
 211       "socket/ssl_server_socket_nss.h",
 212     ]
 213     if (is_ios) {
 214       # Always removed for !ios below.
 215       sources -= [
 216         "cert/cert_verify_proc_nss.cc",
 217         "cert/cert_verify_proc_nss.h",
 218       ]
 219     }
 220     if (is_win) {
 221       sources -= [ "cert/sha256_legacy_support_nss_win.cc" ]
 222     }
 223     if (!use_nss_certs && !is_ios) {
 224       sources -= [ "cert/x509_util_nss.h" ]
 225     }
 226   } else {
 227     sources -= [
 228       "cert/ct_log_verifier_openssl.cc",
 229       "cert/ct_objects_extractor_openssl.cc",
 230       "cert/jwk_serializer_openssl.cc",
 231       "cert/x509_util_openssl.cc",
 232       "cert/x509_util_openssl.h",
 233       "quic/crypto/aead_base_decrypter_openssl.cc",
 234       "quic/crypto/aead_base_encrypter_openssl.cc",
 235       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 236       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 237       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 238       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 239       "quic/crypto/channel_id_openssl.cc",
 240       "quic/crypto/p256_key_exchange_openssl.cc",
 241       "quic/crypto/scoped_evp_aead_ctx.cc",
 242       "quic/crypto/scoped_evp_aead_ctx.h",
 243       "socket/ssl_client_socket_openssl.cc",
 244       "socket/ssl_client_socket_openssl.h",
 245       "socket/ssl_server_socket_openssl.cc",
 246       "socket/ssl_server_socket_openssl.h",
 247       "ssl/openssl_platform_key.h",
 248       "ssl/openssl_platform_key_nss.cc",
 249       "ssl/openssl_ssl_util.cc",
 250       "ssl/openssl_ssl_util.h",
 251       "ssl/ssl_client_session_cache_openssl.cc",
 252       "ssl/ssl_client_session_cache_openssl.h",
 253     ]
 254     if (is_mac) {
 255       sources -= [ "ssl/openssl_platform_key_mac.cc" ]
 256     }
 257     if (is_win) {
 258       sources -= [
 259         "cert/sha256_legacy_support_openssl_win.cc",
 260         "ssl/openssl_platform_key_win.cc",
 261       ]
 262     }
 263   }
 264
 265   if (!use_openssl_certs) {
 266     sources -= [
 267       "base/crypto_module_openssl.cc",
 268       "base/keygen_handler_openssl.cc",
 269       "base/openssl_private_key_store.h",
 270       "base/openssl_private_key_store_memory.cc",
 271       "cert/cert_database_openssl.cc",
 272       "cert/cert_verify_proc_openssl.cc",
 273       "cert/cert_verify_proc_openssl.h",
 274       "cert/test_root_certs_openssl.cc",
 275       "cert/x509_certificate_openssl.cc",
 276       "ssl/openssl_client_key_store.cc",
 277       "ssl/openssl_client_key_store.h",
 278     ]
 279     if (is_android) {
 280       sources -= [ "base/openssl_private_key_store_android.cc" ]
 281     }
 282   } else if (is_android) {
 283     # Android doesn't use these even when using OpenSSL.
 284     sources -= [
 285       "base/openssl_private_key_store_memory.cc",
 286       "cert/cert_database_openssl.cc",
 287       "cert/cert_verify_proc_openssl.cc",
 288       "cert/test_root_certs_openssl.cc",
 289     ]
 290   }
 291
 292   if (use_glib && !is_chromeos) {
 293     configs += [ "//build/config/linux:gconf" ]
 294     deps += [ "//build/config/linux:gio" ]
 295   }
 296
 297   if (is_linux) {
 298     configs += [ "//build/config/linux:libresolv" ]
 299   }
 300
 301   if (!use_nss_certs) {
 302     sources -= [
 303       "base/crypto_module_nss.cc",
 304       "base/keygen_handler_nss.cc",
 305       "cert/cert_database_nss.cc",
 306       "cert/nss_cert_database.cc",
 307       "cert/nss_cert_database.h",
 308       "cert/x509_certificate_nss.cc",
 309       "ssl/client_cert_store_nss.cc",
 310       "ssl/client_cert_store_nss.h",
 311       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 312       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 313       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 314       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 315       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 316       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 317     ]
 318     if (!is_ios) {
 319       # These files are part of the partial implementation of NSS on iOS so
 320       # keep them in that case (even though use_nss_certs is not set).
 321       sources -= [
 322         "cert/cert_verify_proc_nss.cc",
 323         "cert/cert_verify_proc_nss.h",
 324         "cert/test_root_certs_nss.cc",
 325         "cert/x509_util_nss_certs.cc",
 326         "cert_net/nss_ocsp.cc",
 327         "cert_net/nss_ocsp.h",
 328       ]
 329     }
 330     if (is_chromeos) {
 331       # These were already removed on non-ChromeOS.
 332       sources -= [
 333         "cert/nss_cert_database_chromeos.cc",
 334         "cert/nss_cert_database_chromeos.h",
 335         "cert/nss_profile_filter_chromeos.cc",
 336         "cert/nss_profile_filter_chromeos.h",
 337         "ssl/client_cert_store_chromeos.cc",
 338         "ssl/client_cert_store_chromeos.h",
 339       ]
 340     }
 341     if (use_openssl) {
 342       sources -= [ "ssl/openssl_platform_key_nss.cc" ]
 343     }
 344   } else if (use_openssl) {
 345     # client_cert_store_nss.c requires NSS_CmpCertChainWCANames from NSS's
 346     # libssl, but our bundled copy is not built in OpenSSL ports. Pull that file
 347     # in directly.
 348     sources += [ "third_party/nss/ssl/cmpcert.c" ]
 349   }
 350
 351   if (!enable_websockets) {
 352     sources -= [
 353       "websockets/websocket_basic_handshake_stream.cc",
 354       "websockets/websocket_basic_handshake_stream.h",
 355       "websockets/websocket_basic_stream.cc",
 356       "websockets/websocket_basic_stream.h",
 357       "websockets/websocket_channel.cc",
 358       "websockets/websocket_channel.h",
 359       "websockets/websocket_deflate_predictor.h",
 360       "websockets/websocket_deflate_predictor_impl.cc",
 361       "websockets/websocket_deflate_predictor_impl.h",
 362       "websockets/websocket_deflate_stream.cc",
 363       "websockets/websocket_deflate_stream.h",
 364       "websockets/websocket_deflater.cc",
 365       "websockets/websocket_deflater.h",
 366       "websockets/websocket_errors.cc",
 367       "websockets/websocket_errors.h",
 368       "websockets/websocket_extension.cc",
 369       "websockets/websocket_extension.h",
 370       "websockets/websocket_extension_parser.cc",
 371       "websockets/websocket_extension_parser.h",
 372       "websockets/websocket_frame.cc",
 373       "websockets/websocket_frame.h",
 374       "websockets/websocket_frame_parser.cc",
 375       "websockets/websocket_frame_parser.h",
 376       "websockets/websocket_handshake_challenge.cc",
 377       "websockets/websocket_handshake_challenge.h",
 378       "websockets/websocket_handshake_constants.cc",
 379       "websockets/websocket_handshake_constants.h",
 380       "websockets/websocket_handshake_request_info.cc",
 381       "websockets/websocket_handshake_request_info.h",
 382       "websockets/websocket_handshake_response_info.cc",
 383       "websockets/websocket_handshake_response_info.h",
 384       "websockets/websocket_handshake_stream_base.h",
 385       "websockets/websocket_handshake_stream_create_helper.cc",
 386       "websockets/websocket_handshake_stream_create_helper.h",
 387       "websockets/websocket_inflater.cc",
 388       "websockets/websocket_inflater.h",
 389       "websockets/websocket_mux.h",
 390       "websockets/websocket_stream.cc",
 391       "websockets/websocket_stream.h",
 392     ]
 393   }
 394
 395   if (!enable_mdns) {
 396     sources -= [
 397       "dns/mdns_cache.cc",
 398       "dns/mdns_cache.h",
 399       "dns/mdns_client.cc",
 400       "dns/mdns_client.h",
 401       "dns/mdns_client_impl.cc",
 402       "dns/mdns_client_impl.h",
 403       "dns/record_parsed.cc",
 404       "dns/record_parsed.h",
 405       "dns/record_rdata.cc",
 406       "dns/record_rdata.h",
 407     ]
 408   }
 409
 410   if (is_win) {
 411     sources -= [
 412       "http/http_auth_handler_ntlm_portable.cc",
 413       "socket/socket_libevent.cc",
 414       "socket/socket_libevent.h",
 415       "socket/tcp_socket_libevent.cc",
 416       "socket/tcp_socket_libevent.h",
 417       "udp/udp_socket_libevent.cc",
 418       "udp/udp_socket_libevent.h",
 419     ]
 420   } else {  # !is_win
 421     sources -= [
 422       "base/winsock_init.cc",
 423       "base/winsock_init.h",
 424       "base/winsock_util.cc",
 425       "base/winsock_util.h",
 426       "proxy/proxy_resolver_winhttp.cc",
 427       "proxy/proxy_resolver_winhttp.h",
 428     ]
 429   }
 430
 431   if (is_mac) {
 432     libs = [
 433       "Foundation.framework",
 434       "Security.framework",
 435       "SystemConfiguration.framework",
 436       "resolv",
 437     ]
 438   }
 439
 440   if (is_ios) {
 441     # Add back some sources that were otherwise filtered out. iOS needs some Mac
 442     # files.
 443     set_sources_assignment_filter([])
 444     sources += [
 445       "base/net_util_mac.cc",
 446       "base/net_util_mac.h",
 447       "base/network_change_notifier_mac.cc",
 448       "base/network_config_watcher_mac.cc",
 449       "base/platform_mime_util_mac.mm",
 450       "proxy/proxy_resolver_mac.cc",
 451       "proxy/proxy_server_mac.cc",
 452     ]
 453     set_sources_assignment_filter(sources_assignment_filter)
 454
 455     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 456     libs = [
 457       "CFNetwork.framework",
 458       "MobileCoreServices.framework",
 459       "Security.framework",
 460       "SystemConfiguration.framework",
 461       "resolv",
 462     ]
 463   }
 464
 465   if (is_ios || is_mac) {
 466     sources += gypi_values.net_base_mac_ios_sources
 467   }
 468
 469   if (is_android) {
 470     # Add some Linux sources that were excluded by the filter, but which
 471     # are needed.
 472     set_sources_assignment_filter([])
 473     sources += [
 474       "base/address_tracker_linux.cc",
 475       "base/address_tracker_linux.h",
 476       "base/net_util_linux.cc",
 477       "base/net_util_linux.h",
 478       "base/platform_mime_util_linux.cc",
 479     ]
 480     set_sources_assignment_filter(sources_assignment_filter)
 481     deps += [ ":net_jni_headers" ]
 482   }
 483
 484   if (use_icu_alternatives_on_android) {
 485     sources += [
 486       "base/net_string_util_icu_alternatives_android.cc",
 487       "base/net_string_util_icu_alternatives_android.h",
 488     ]
 489   } else {
 490     deps += [
 491       "//base:i18n",
 492       "//third_party/icu",
 493     ]
 494     sources += [
 495       "base/filename_util_icu.cc",
 496       "base/net_string_util_icu.cc",
 497       "base/net_util_icu.cc",
 498     ]
 499   }
 500 }
 501
 502 grit("net_resources") {
 503   source = "base/net_resources.grd"
 504   use_qualified_include = true
 505   outputs = [
 506     "grit/net_resources.h",
 507     "net_resources.pak",
 508     "net_resources.rc",
 509   ]
 510 }
 511
 512 proto_library("net_quic_proto") {
 513   visibility = [ "//net" ]  # Part of the net component.
 514
 515   sources = [
 516     "quic/proto/cached_network_parameters.proto",
 517     "quic/proto/source_address_token.proto",
 518   ]
 519   cc_generator_options = "dllexport_decl=NET_EXPORT_PRIVATE:"
 520   cc_include = "net/base/net_export.h"
 521
 522   defines = [ "NET_IMPLEMENTATION" ]
 523
 524   extra_configs = [ "//build/config/compiler:wexit_time_destructors" ]
 525 }
 526
 527 static_library("extras") {
 528   sources = gypi_values.net_extras_sources
 529   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 530   deps = [
 531     ":net",
 532     "//base",
 533     "//sql:sql",
 534   ]
 535 }
 536
 537 static_library("http_server") {
 538   sources = [
 539     "server/http_connection.cc",
 540     "server/http_connection.h",
 541     "server/http_server.cc",
 542     "server/http_server.h",
 543     "server/http_server_request_info.cc",
 544     "server/http_server_request_info.h",
 545     "server/http_server_response_info.cc",
 546     "server/http_server_response_info.h",
 547     "server/web_socket.cc",
 548     "server/web_socket.h",
 549     "server/web_socket_encoder.cc",
 550     "server/web_socket_encoder.h",
 551   ]
 552   configs += [
 553     "//build/config/compiler:no_size_t_to_int_warning",
 554     "//build/config/compiler:wexit_time_destructors",
 555   ]
 556   deps = [
 557     ":net",
 558     "//base",
 559   ]
 560 }
 561
 562 executable("dump_cache") {
 563   testonly = true
 564   sources = [
 565     "tools/dump_cache/cache_dumper.cc",
 566     "tools/dump_cache/cache_dumper.h",
 567     "tools/dump_cache/dump_cache.cc",
 568     "tools/dump_cache/dump_files.cc",
 569     "tools/dump_cache/dump_files.h",
 570     "tools/dump_cache/simple_cache_dumper.cc",
 571     "tools/dump_cache/simple_cache_dumper.h",
 572     "tools/dump_cache/url_to_filename_encoder.cc",
 573     "tools/dump_cache/url_to_filename_encoder.h",
 574     "tools/dump_cache/url_utilities.cc",
 575     "tools/dump_cache/url_utilities.h",
 576   ]
 577
 578   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 579   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 580
 581   deps = [
 582     "//base",
 583     ":net",
 584     ":test_support",
 585   ]
 586 }
 587
 588 source_set("test_support") {
 589   testonly = true
 590   sources = [
 591     "base/load_timing_info_test_util.cc",
 592     "base/load_timing_info_test_util.h",
 593     "base/mock_file_stream.cc",
 594     "base/mock_file_stream.h",
 595     "base/test_completion_callback.cc",
 596     "base/test_completion_callback.h",
 597     "base/test_data_directory.cc",
 598     "base/test_data_directory.h",
 599     "cert/mock_cert_verifier.cc",
 600     "cert/mock_cert_verifier.h",
 601     "cookies/cookie_monster_store_test.cc",
 602     "cookies/cookie_monster_store_test.h",
 603     "cookies/cookie_store_test_callbacks.cc",
 604     "cookies/cookie_store_test_callbacks.h",
 605     "cookies/cookie_store_test_helpers.cc",
 606     "cookies/cookie_store_test_helpers.h",
 607     "disk_cache/disk_cache_test_base.cc",
 608     "disk_cache/disk_cache_test_base.h",
 609     "disk_cache/disk_cache_test_util.cc",
 610     "disk_cache/disk_cache_test_util.h",
 611     "dns/dns_test_util.cc",
 612     "dns/dns_test_util.h",
 613     "dns/mock_host_resolver.cc",
 614     "dns/mock_host_resolver.h",
 615     "dns/mock_mdns_socket_factory.cc",
 616     "dns/mock_mdns_socket_factory.h",
 617     "http/http_transaction_test_util.cc",
 618     "http/http_transaction_test_util.h",
 619     "log/test_net_log.cc",
 620     "log/test_net_log.h",
 621     "log/test_net_log_entry.cc",
 622     "log/test_net_log_entry.h",
 623     "log/test_net_log_util.cc",
 624     "log/test_net_log_util.h",
 625     "proxy/mock_proxy_resolver.cc",
 626     "proxy/mock_proxy_resolver.h",
 627     "proxy/mock_proxy_script_fetcher.cc",
 628     "proxy/mock_proxy_script_fetcher.h",
 629     "proxy/proxy_config_service_common_unittest.cc",
 630     "proxy/proxy_config_service_common_unittest.h",
 631     "socket/socket_test_util.cc",
 632     "socket/socket_test_util.h",
 633     "test/cert_test_util.cc",
 634     "test/cert_test_util.h",
 635     "test/cert_test_util_nss.cc",
 636     "test/ct_test_util.cc",
 637     "test/ct_test_util.h",
 638     "test/embedded_test_server/embedded_test_server.cc",
 639     "test/embedded_test_server/embedded_test_server.h",
 640     "test/embedded_test_server/http_connection.cc",
 641     "test/embedded_test_server/http_connection.h",
 642     "test/embedded_test_server/http_request.cc",
 643     "test/embedded_test_server/http_request.h",
 644     "test/embedded_test_server/http_response.cc",
 645     "test/embedded_test_server/http_response.h",
 646     "test/event_waiter.h",
 647     "test/net_test_suite.cc",
 648     "test/net_test_suite.h",
 649     "test/python_utils.cc",
 650     "test/python_utils.h",
 651     "test/spawned_test_server/base_test_server.cc",
 652     "test/spawned_test_server/base_test_server.h",
 653     "test/spawned_test_server/local_test_server.cc",
 654     "test/spawned_test_server/local_test_server.h",
 655     "test/spawned_test_server/local_test_server_posix.cc",
 656     "test/spawned_test_server/local_test_server_win.cc",
 657     "test/spawned_test_server/remote_test_server.cc",
 658     "test/spawned_test_server/remote_test_server.h",
 659     "test/spawned_test_server/spawned_test_server.h",
 660     "test/spawned_test_server/spawner_communicator.cc",
 661     "test/spawned_test_server/spawner_communicator.h",
 662     "test/url_request/url_request_failed_job.cc",
 663     "test/url_request/url_request_failed_job.h",
 664     "test/url_request/url_request_mock_data_job.cc",
 665     "test/url_request/url_request_mock_data_job.h",
 666     "test/url_request/url_request_slow_download_job.cc",
 667     "test/url_request/url_request_slow_download_job.h",
 668     "url_request/test_url_fetcher_factory.cc",
 669     "url_request/test_url_fetcher_factory.h",
 670     "url_request/url_request_test_util.cc",
 671     "url_request/url_request_test_util.h",
 672   ]
 673
 674   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 675   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 676
 677   public_deps = [
 678     "//base",
 679     "//base/test:test_support",
 680     "//crypto",
 681     "//net",
 682     "//net/tools/tld_cleanup",
 683     "//testing/gmock",
 684     "//testing/gtest",
 685     "//url",
 686   ]
 687
 688   if (!is_ios) {
 689     public_deps += [ "//third_party/protobuf:py_proto" ]
 690   }
 691
 692   if (!use_openssl && (use_nss_certs || is_ios)) {
 693     public_deps += [ "//crypto:platform" ]
 694   }
 695
 696   if (!is_android) {
 697     sources -= [
 698       "test/spawned_test_server/remote_test_server.cc",
 699       "test/spawned_test_server/remote_test_server.h",
 700       "test/spawned_test_server/spawner_communicator.cc",
 701       "test/spawned_test_server/spawner_communicator.h",
 702     ]
 703   }
 704
 705   if (use_v8_in_net) {
 706     public_deps += [ ":net_with_v8" ]
 707   }
 708
 709   if (!enable_mdns) {
 710     sources -= [
 711       "dns/mock_mdns_socket_factory.cc",
 712       "dns/mock_mdns_socket_factory.h",
 713     ]
 714   }
 715
 716   if (!use_nss_certs) {
 717     sources -= [ "test/cert_test_util_nss.cc" ]
 718   }
 719
 720   if (!disable_file_support) {
 721     sources += [
 722       "test/url_request/url_request_mock_http_job.cc",
 723       "test/url_request/url_request_mock_http_job.h",
 724       "url_request/test_url_request_interceptor.cc",
 725       "url_request/test_url_request_interceptor.h",
 726     ]
 727   }
 728 }
 729
 730 source_set("balsa") {
 731   sources = [
 732     "tools/balsa/balsa_enums.h",
 733     "tools/balsa/balsa_frame.cc",
 734     "tools/balsa/balsa_frame.h",
 735     "tools/balsa/balsa_headers.cc",
 736     "tools/balsa/balsa_headers.h",
 737     "tools/balsa/balsa_headers_token_utils.cc",
 738     "tools/balsa/balsa_headers_token_utils.h",
 739     "tools/balsa/balsa_visitor_interface.h",
 740     "tools/balsa/http_message_constants.cc",
 741     "tools/balsa/http_message_constants.h",
 742     "tools/balsa/noop_balsa_visitor.h",
 743     "tools/balsa/simple_buffer.cc",
 744     "tools/balsa/simple_buffer.h",
 745     "tools/balsa/split.cc",
 746     "tools/balsa/split.h",
 747     "tools/balsa/string_piece_utils.h",
 748     "tools/quic/spdy_balsa_utils.cc",
 749     "tools/quic/spdy_balsa_utils.h",
 750   ]
 751   deps = [
 752     ":net",
 753     "//base",
 754     "//url",
 755   ]
 756 }
 757
 758 if (use_v8_in_net) {
 759   component("net_with_v8") {
 760     sources = [
 761       "proxy/proxy_resolver_v8.cc",
 762       "proxy/proxy_resolver_v8.h",
 763       "proxy/proxy_resolver_v8_tracing.cc",
 764       "proxy/proxy_resolver_v8_tracing.h",
 765       "proxy/proxy_service_v8.cc",
 766       "proxy/proxy_service_v8.h",
 767     ]
 768
 769     defines = [ "NET_IMPLEMENTATION" ]
 770     configs += [
 771       "//build/config/compiler:no_size_t_to_int_warning",
 772       "//build/config/compiler:wexit_time_destructors",
 773     ]
 774
 775     public_deps = [
 776       ":net",
 777     ]
 778     deps = [
 779       "//base",
 780       "//gin",
 781       "//url",
 782       "//v8",
 783     ]
 784   }
 785 }
 786
 787 if (use_v8_in_net && !is_android) {
 788   source_set("net_browser_services") {
 789     sources = [
 790       "dns/mojo_host_resolver_impl.cc",
 791       "dns/mojo_host_resolver_impl.h",
 792       "proxy/in_process_mojo_proxy_resolver_factory.cc",
 793       "proxy/in_process_mojo_proxy_resolver_factory.h",
 794       "proxy/mojo_proxy_resolver_factory.h",
 795       "proxy/proxy_resolver_mojo.cc",
 796       "proxy/proxy_resolver_mojo.h",
 797       "proxy/proxy_service_mojo.cc",
 798       "proxy/proxy_service_mojo.h",
 799     ]
 800
 801     public_deps = [
 802       ":mojo_type_converters",
 803       ":net",
 804       "//base",
 805       "//mojo/common",
 806       "//net/interfaces",
 807       "//third_party/mojo/src/mojo/public/cpp/bindings",
 808
 809       # NOTE(amistry): As long as we support in-process Mojo v8 PAC, we need
 810       # this dependency since in_process_mojo_proxy_resolver_factory creates
 811       # the utility process side Mojo services in the browser process.
 812       # Ultimately, this will go away when we only support out-of-process.
 813       ":net_utility_services",
 814     ]
 815   }
 816
 817   source_set("mojo_type_converters") {
 818     sources = [
 819       "dns/mojo_host_type_converters.cc",
 820       "dns/mojo_host_type_converters.h",
 821       "proxy/mojo_proxy_type_converters.cc",
 822       "proxy/mojo_proxy_type_converters.h",
 823     ]
 824
 825     public_deps = [
 826       ":net",
 827       "//net/interfaces",
 828       "//third_party/mojo/src/mojo/public/cpp/bindings",
 829     ]
 830   }
 831
 832   source_set("net_utility_services") {
 833     sources = [
 834       "dns/host_resolver_mojo.cc",
 835       "dns/host_resolver_mojo.h",
 836       "proxy/load_state_change_coalescer.cc",
 837       "proxy/load_state_change_coalescer.h",
 838       "proxy/mojo_proxy_resolver_factory_impl.cc",
 839       "proxy/mojo_proxy_resolver_factory_impl.h",
 840       "proxy/mojo_proxy_resolver_impl.cc",
 841       "proxy/mojo_proxy_resolver_impl.h",
 842       "proxy/proxy_resolver_error_observer_mojo.cc",
 843       "proxy/proxy_resolver_error_observer_mojo.h",
 844     ]
 845
 846     deps = [
 847       ":net_with_v8",
 848     ]
 849
 850     public_deps = [
 851       ":mojo_type_converters",
 852       ":net",
 853       "//mojo/common",
 854       "//net/interfaces",
 855       "//third_party/mojo/src/mojo/public/cpp/bindings",
 856     ]
 857   }
 858 }
 859
 860 if (!is_ios && !is_android) {
 861   executable("crash_cache") {
 862     testonly = true
 863     sources = [
 864       "tools/crash_cache/crash_cache.cc",
 865     ]
 866
 867     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 868     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 869     deps = [
 870       ":net",
 871       ":test_support",
 872       "//base",
 873     ]
 874   }
 875
 876   executable("crl_set_dump") {
 877     testonly = true
 878     sources = [
 879       "tools/crl_set_dump/crl_set_dump.cc",
 880     ]
 881
 882     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 883     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 884     deps = [
 885       ":net",
 886       "//base",
 887     ]
 888   }
 889
 890   executable("dns_fuzz_stub") {
 891     testonly = true
 892     sources = [
 893       "tools/dns_fuzz_stub/dns_fuzz_stub.cc",
 894     ]
 895
 896     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 897     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 898     deps = [
 899       ":net",
 900       "//base",
 901     ]
 902   }
 903
 904   executable("gdig") {
 905     testonly = true
 906     sources = [
 907       "tools/gdig/file_net_log.cc",
 908       "tools/gdig/gdig.cc",
 909     ]
 910     deps = [
 911       ":net",
 912       "//base",
 913     ]
 914   }
 915
 916   executable("get_server_time") {
 917     testonly = true
 918     sources = [
 919       "tools/get_server_time/get_server_time.cc",
 920     ]
 921
 922     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 923     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 924     deps = [
 925       ":net",
 926       "//base",
 927       "//base:i18n",
 928       "//url",
 929     ]
 930   }
 931
 932   executable("hpack_example_generator") {
 933     testonly = true
 934     sources = [
 935       "spdy/fuzzing/hpack_example_generator.cc",
 936     ]
 937
 938     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 939     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 940     deps = [
 941       "//base",
 942       ":net",
 943     ]
 944   }
 945
 946   executable("hpack_fuzz_mutator") {
 947     testonly = true
 948     sources = [
 949       "spdy/fuzzing/hpack_fuzz_mutator.cc",
 950     ]
 951
 952     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 953     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 954     deps = [
 955       "//base",
 956       ":net",
 957     ]
 958   }
 959
 960   executable("hpack_fuzz_wrapper") {
 961     testonly = true
 962     sources = [
 963       "spdy/fuzzing/hpack_fuzz_wrapper.cc",
 964     ]
 965
 966     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 967     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 968     deps = [
 969       "//base",
 970       ":net",
 971     ]
 972   }
 973
 974   if (use_v8_in_net) {
 975     executable("net_watcher") {
 976       testonly = true
 977       sources = [
 978         "tools/net_watcher/net_watcher.cc",
 979       ]
 980       deps = [
 981         ":net",
 982         ":net_with_v8",
 983         "//base",
 984       ]
 985
 986       if (is_desktop_linux) {
 987         configs += [
 988           "//build/config/linux:gconf",
 989           "//build/config/linux:glib",
 990         ]
 991         deps += [ "//build/config/linux:gio" ]
 992       }
 993     }
 994   }
 995
 996   executable("run_testserver") {
 997     testonly = true
 998     sources = [
 999       "tools/testserver/run_testserver.cc",
1000     ]
1001     deps = [
1002       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
1003                # in the GYP build, and can be removed when the bug is fixed.
1004
1005       ":test_support",
1006       "//base",
1007       "//base/test:test_support",
1008       "//testing/gtest",
1009     ]
1010   }
1011
1012   executable("stress_cache") {
1013     testonly = true
1014     sources = [
1015       "tools/stress_cache/stress_cache.cc",
1016     ]
1017
1018     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1019     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1020     deps = [
1021       ":net",
1022       ":test_support",
1023       "//base",
1024     ]
1025   }
1026
1027   executable("tld_cleanup") {
1028     sources = [
1029       "tools/tld_cleanup/tld_cleanup.cc",
1030     ]
1031
1032     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1033     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1034     deps = [
1035       "//base",
1036       "//base:i18n",
1037       "//net/tools/tld_cleanup",
1038     ]
1039   }
1040 }
1041
1042 if (is_linux) {
1043   static_library("epoll_server") {
1044     sources = [
1045       "tools/epoll_server/epoll_server.cc",
1046       "tools/epoll_server/epoll_server.h",
1047     ]
1048     deps = [
1049       ":net",
1050       "//base",
1051     ]
1052   }
1053
1054   static_library("flip_in_mem_edsm_server_base") {
1055     testonly = true
1056     sources = [
1057       "tools/dump_cache/url_to_filename_encoder.cc",
1058       "tools/dump_cache/url_to_filename_encoder.h",
1059       "tools/dump_cache/url_utilities.cc",
1060       "tools/dump_cache/url_utilities.h",
1061       "tools/flip_server/acceptor_thread.cc",
1062       "tools/flip_server/acceptor_thread.h",
1063       "tools/flip_server/constants.h",
1064       "tools/flip_server/create_listener.cc",
1065       "tools/flip_server/create_listener.h",
1066       "tools/flip_server/flip_config.cc",
1067       "tools/flip_server/flip_config.h",
1068       "tools/flip_server/http_interface.cc",
1069       "tools/flip_server/http_interface.h",
1070       "tools/flip_server/loadtime_measurement.h",
1071       "tools/flip_server/mem_cache.cc",
1072       "tools/flip_server/mem_cache.h",
1073       "tools/flip_server/output_ordering.cc",
1074       "tools/flip_server/output_ordering.h",
1075       "tools/flip_server/ring_buffer.cc",
1076       "tools/flip_server/ring_buffer.h",
1077       "tools/flip_server/sm_connection.cc",
1078       "tools/flip_server/sm_connection.h",
1079       "tools/flip_server/sm_interface.h",
1080       "tools/flip_server/spdy_interface.cc",
1081       "tools/flip_server/spdy_interface.h",
1082       "tools/flip_server/spdy_ssl.cc",
1083       "tools/flip_server/spdy_ssl.h",
1084       "tools/flip_server/spdy_util.cc",
1085       "tools/flip_server/spdy_util.h",
1086       "tools/flip_server/streamer_interface.cc",
1087       "tools/flip_server/streamer_interface.h",
1088     ]
1089     deps = [
1090       ":balsa",
1091       ":epoll_server",
1092       ":net",
1093       "//base",
1094       "//third_party/boringssl",
1095     ]
1096   }
1097
1098   executable("flip_in_mem_edsm_server_unittests") {
1099     testonly = true
1100     sources = [
1101       "tools/flip_server/flip_test_utils.cc",
1102       "tools/flip_server/flip_test_utils.h",
1103       "tools/flip_server/http_interface_test.cc",
1104       "tools/flip_server/mem_cache_test.cc",
1105       "tools/flip_server/run_all_tests.cc",
1106       "tools/flip_server/spdy_interface_test.cc",
1107     ]
1108     deps = [
1109       ":balsa",
1110       ":flip_in_mem_edsm_server_base",
1111       ":net",
1112       ":test_support",
1113       "//testing/gtest",
1114       "//testing/gmock",
1115       "//third_party/boringssl",
1116     ]
1117   }
1118
1119   executable("flip_in_mem_edsm_server") {
1120     testonly = true
1121     sources = [
1122       "tools/flip_server/flip_in_mem_edsm_server.cc",
1123     ]
1124     deps = [
1125       ":balsa",
1126       ":flip_in_mem_edsm_server_base",
1127       ":net",
1128       "//base",
1129     ]
1130   }
1131
1132   source_set("epoll_quic_tools") {
1133     sources = [
1134       "tools/quic/quic_client.cc",
1135       "tools/quic/quic_client.h",
1136       "tools/quic/quic_default_packet_writer.cc",
1137       "tools/quic/quic_default_packet_writer.h",
1138       "tools/quic/quic_epoll_clock.cc",
1139       "tools/quic/quic_epoll_clock.h",
1140       "tools/quic/quic_epoll_connection_helper.cc",
1141       "tools/quic/quic_epoll_connection_helper.h",
1142       "tools/quic/quic_packet_reader.cc",
1143       "tools/quic/quic_packet_reader.h",
1144       "tools/quic/quic_packet_writer_wrapper.cc",
1145       "tools/quic/quic_packet_writer_wrapper.h",
1146       "tools/quic/quic_server.cc",
1147       "tools/quic/quic_server.h",
1148       "tools/quic/quic_socket_utils.cc",
1149       "tools/quic/quic_socket_utils.h",
1150     ]
1151     deps = [
1152       ":balsa",
1153       ":epoll_server",
1154       ":net",
1155       "//base",
1156       "//base/third_party/dynamic_annotations",
1157       "//crypto",
1158       "//third_party/boringssl",
1159       "//url",
1160     ]
1161   }
1162
1163   executable("epoll_quic_client") {
1164     sources = [
1165       "tools/quic/quic_client_bin.cc",
1166     ]
1167     deps = [
1168       ":balsa",
1169       ":epoll_server",
1170       ":epoll_quic_tools",
1171       ":net",
1172       ":simple_quic_tools",
1173       "//base",
1174       "//third_party/boringssl",
1175     ]
1176   }
1177
1178   executable("epoll_quic_server") {
1179     sources = [
1180       "tools/quic/quic_server_bin.cc",
1181     ]
1182     deps = [
1183       ":balsa",
1184       ":epoll_server",
1185       ":epoll_quic_tools",
1186       ":net",
1187       ":simple_quic_tools",
1188       "//base",
1189       "//third_party/boringssl",
1190     ]
1191   }
1192 }
1193
1194 if (is_android) {
1195   generate_jni("net_jni_headers") {
1196     sources = [
1197       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1198       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1199       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1200       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1201       "android/java/src/org/chromium/net/GURLUtils.java",
1202       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1203       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1204       "android/java/src/org/chromium/net/X509Util.java",
1205     ]
1206     jni_package = "net"
1207   }
1208   generate_jni("net_test_jni_headers") {
1209     sources = [
1210       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1211     ]
1212     jni_package = "net"
1213   }
1214 }
1215
1216 if (is_android || is_linux) {
1217   executable("disk_cache_memory_test") {
1218     testonly = true
1219     sources = [
1220       "tools/disk_cache_memory_test/disk_cache_memory_test.cc",
1221     ]
1222     deps = [
1223       ":net",
1224       "//base",
1225     ]
1226   }
1227 }
1228
1229 source_set("simple_quic_tools") {
1230   sources = [
1231     "tools/quic/quic_client_session.cc",
1232     "tools/quic/quic_client_session.h",
1233     "tools/quic/quic_dispatcher.cc",
1234     "tools/quic/quic_dispatcher.h",
1235     "tools/quic/quic_in_memory_cache.cc",
1236     "tools/quic/quic_in_memory_cache.h",
1237     "tools/quic/quic_per_connection_packet_writer.cc",
1238     "tools/quic/quic_per_connection_packet_writer.h",
1239     "tools/quic/quic_server_session.cc",
1240     "tools/quic/quic_server_session.h",
1241     "tools/quic/quic_simple_client.cc",
1242     "tools/quic/quic_simple_client.h",
1243     "tools/quic/quic_simple_per_connection_packet_writer.cc",
1244     "tools/quic/quic_simple_per_connection_packet_writer.h",
1245     "tools/quic/quic_simple_server.cc",
1246     "tools/quic/quic_simple_server.h",
1247     "tools/quic/quic_simple_server_packet_writer.cc",
1248     "tools/quic/quic_simple_server_packet_writer.h",
1249     "tools/quic/quic_spdy_client_stream.cc",
1250     "tools/quic/quic_spdy_client_stream.h",
1251     "tools/quic/quic_spdy_server_stream.cc",
1252     "tools/quic/quic_spdy_server_stream.h",
1253     "tools/quic/quic_time_wait_list_manager.cc",
1254     "tools/quic/quic_time_wait_list_manager.h",
1255     "tools/quic/synchronous_host_resolver.cc",
1256     "tools/quic/synchronous_host_resolver.h",
1257   ]
1258   deps = [
1259     ":net",
1260     "//base",
1261     "//base/third_party/dynamic_annotations",
1262     "//url",
1263   ]
1264 }
1265
1266 executable("quic_client") {
1267   sources = [
1268     "tools/quic/quic_simple_client_bin.cc",
1269   ]
1270   deps = [
1271     ":net",
1272     ":simple_quic_tools",
1273     "//base",
1274     "//url",
1275   ]
1276 }
1277
1278 executable("quic_server") {
1279   sources = [
1280     "tools/quic/quic_simple_server_bin.cc",
1281   ]
1282   deps = [
1283     ":net",
1284     ":simple_quic_tools",
1285     "//base",
1286     "//third_party/boringssl",
1287     "//third_party/protobuf:protobuf_lite",
1288   ]
1289 }
1290
1291 # TODO(GYP) make this compile on Android, we need some native test deps done.
1292 # TODO(GYP) Also doesn't work on Mac, need to figure out why not.
1293 if (!is_android && !is_mac) {
1294   test("net_unittests") {
1295     sources = gypi_values.net_test_sources
1296
1297     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1298     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1299     defines = []
1300
1301     deps = [
1302       ":balsa",
1303       ":extras",
1304       ":http_server",
1305       ":net",
1306       ":simple_quic_tools",
1307       ":test_support",
1308       "//base",
1309       "//base:i18n",
1310       "//base:prefs_test_support",
1311       "//base/allocator",
1312       "//base/third_party/dynamic_annotations",
1313       "//crypto",
1314       "//crypto:platform",
1315       "//crypto:test_support",
1316       "//gin",
1317       "//net/base/registry_controlled_domains",
1318       "//sql",
1319       "//testing/gmock",
1320       "//testing/gtest",
1321       "//third_party/zlib",
1322       "//url",
1323     ]
1324
1325     if (is_desktop_linux) {
1326       deps += [ ":epoll_quic_tools" ]
1327     }
1328     if (is_linux) {
1329       sources += gypi_values.net_linux_test_sources
1330       deps += [
1331         ":balsa",
1332         ":epoll_server",
1333         ":flip_in_mem_edsm_server_base",
1334         ":epoll_quic_tools",
1335       ]
1336     }
1337
1338     if (is_mac || is_ios) {
1339       sources += gypi_values.net_base_test_mac_ios_sources
1340     }
1341
1342     if (is_chromeos) {
1343       sources -= [ "proxy/proxy_config_service_linux_unittest.cc" ]
1344     }
1345
1346     if (is_android) {
1347       sources -= [
1348         # See bug http://crbug.com/344533.
1349         "disk_cache/blockfile/index_table_v3_unittest.cc",
1350
1351         # No res_ninit() et al on Android, so this doesn't make a lot of
1352         # sense.
1353         "dns/dns_config_service_posix_unittest.cc",
1354       ]
1355       deps += [ ":net_test_jni_headers" ]
1356     }
1357
1358     if (v8_use_external_startup_data) {
1359       deps += [ "//gin" ]
1360     }
1361
1362     if (!use_nss_certs) {
1363       sources -= [
1364         "cert/nss_cert_database_unittest.cc",
1365         "ssl/client_cert_store_nss_unittest.cc",
1366       ]
1367       if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1368         sources -= [
1369           "cert/nss_cert_database_chromeos_unittest.cc",
1370           "cert/nss_profile_filter_chromeos_unittest.cc",
1371           "ssl/client_cert_store_chromeos_unittest.cc",
1372         ]
1373       }
1374     }
1375
1376     if (use_openssl) {
1377       # When building for OpenSSL, we need to exclude NSS specific tests
1378       # or functionality not supported by OpenSSL yet.
1379       # TODO(bulach): Add equivalent tests when the underlying
1380       #               functionality is ported to OpenSSL.
1381       sources -= [
1382         "cert/x509_util_nss_unittest.cc",
1383         "quic/test_tools/crypto_test_utils_nss.cc",
1384       ]
1385     } else {
1386       sources -= [
1387         "cert/x509_util_openssl_unittest.cc",
1388         "quic/test_tools/crypto_test_utils_openssl.cc",
1389         "socket/ssl_client_socket_openssl_unittest.cc",
1390         "ssl/ssl_client_session_cache_openssl_unittest.cc",
1391       ]
1392     }
1393
1394     if (use_kerberos) {
1395       defines += [ "USE_KERBEROS" ]
1396     } else {
1397       sources -= [
1398         "http/http_auth_gssapi_posix_unittest.cc",
1399         "http/http_auth_handler_negotiate_unittest.cc",
1400         "http/mock_gssapi_library_posix.cc",
1401         "http/mock_gssapi_library_posix.h",
1402       ]
1403     }
1404
1405     if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1406       # Only include this test when on Posix and using NSS for
1407       # cert verification or on iOS (which also uses NSS for certs).
1408       sources -= [ "cert_net/nss_ocsp_unittest.cc" ]
1409     }
1410
1411     if (!use_openssl_certs) {
1412       sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1413     }
1414
1415     if (!enable_websockets) {
1416       sources -= [
1417         "server/http_connection_unittest.cc",
1418         "server/http_server_response_info_unittest.cc",
1419         "server/http_server_unittest.cc",
1420         "server/web_socket_encoder_unittest.cc",
1421         "websockets/websocket_basic_stream_test.cc",
1422         "websockets/websocket_channel_test.cc",
1423         "websockets/websocket_deflate_predictor_impl_test.cc",
1424         "websockets/websocket_deflate_stream_test.cc",
1425         "websockets/websocket_deflater_test.cc",
1426         "websockets/websocket_end_to_end_test.cc",
1427         "websockets/websocket_errors_test.cc",
1428         "websockets/websocket_extension_parser_test.cc",
1429         "websockets/websocket_frame_parser_test.cc",
1430         "websockets/websocket_frame_test.cc",
1431         "websockets/websocket_handshake_challenge_test.cc",
1432         "websockets/websocket_handshake_stream_create_helper_test.cc",
1433         "websockets/websocket_inflater_test.cc",
1434         "websockets/websocket_stream_test.cc",
1435         "websockets/websocket_test_util.cc",
1436         "websockets/websocket_test_util.h",
1437       ]
1438       deps -= [ ":http_server" ]
1439     }
1440
1441     if (disable_file_support) {
1442       sources -= [
1443         "base/directory_lister_unittest.cc",
1444         "url_request/url_request_file_job_unittest.cc",
1445       ]
1446     }
1447
1448     if (disable_ftp_support) {
1449       sources -= [
1450         "ftp/ftp_auth_cache_unittest.cc",
1451         "ftp/ftp_ctrl_response_buffer_unittest.cc",
1452         "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1453         "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1454         "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1455         "ftp/ftp_directory_listing_parser_unittest.cc",
1456         "ftp/ftp_directory_listing_parser_unittest.h",
1457         "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1458         "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1459         "ftp/ftp_network_transaction_unittest.cc",
1460         "ftp/ftp_util_unittest.cc",
1461         "url_request/url_request_ftp_job_unittest.cc",
1462       ]
1463     }
1464
1465     if (!enable_built_in_dns) {
1466       sources -= [
1467         "dns/address_sorter_posix_unittest.cc",
1468         "dns/address_sorter_unittest.cc",
1469       ]
1470     }
1471
1472     # Always need use_v8_in_net to be 1 to run on Android, so just remove
1473     # net_unittest's dependency on v8 when using icu alternatives instead of
1474     # setting use_v8_in_net to 0.
1475     if (use_v8_in_net && !use_icu_alternatives_on_android) {
1476       deps += [ ":net_with_v8" ]
1477     } else {
1478       sources -= [
1479         "proxy/proxy_resolver_v8_tracing_unittest.cc",
1480         "proxy/proxy_resolver_v8_unittest.cc",
1481       ]
1482     }
1483
1484     if (use_v8_in_net && !is_android) {
1485       deps += [
1486         ":net_browser_services",
1487         ":net_utility_services",
1488         "//mojo/environment:chromium",
1489         "//third_party/mojo/src/mojo/edk/system",
1490       ]
1491     } else {
1492       sources -= [
1493         "dns/host_resolver_mojo_unittest.cc",
1494         "dns/mojo_host_resolver_impl_unittest.cc",
1495         "proxy/load_state_change_coalescer_unittest.cc",
1496         "proxy/mojo_proxy_resolver_factory_impl_unittest.cc",
1497         "proxy/mojo_proxy_resolver_impl_unittest.cc",
1498         "proxy/proxy_resolver_error_observer_mojo_unittest.cc",
1499         "proxy/proxy_resolver_mojo_unittest.cc",
1500         "proxy/proxy_service_mojo_unittest.cc",
1501       ]
1502     }
1503
1504     if (!enable_mdns) {
1505       sources -= [
1506         "dns/mdns_cache_unittest.cc",
1507         "dns/mdns_client_unittest.cc",
1508         "dns/record_parsed_unittest.cc",
1509         "dns/record_rdata_unittest.cc",
1510       ]
1511     }
1512
1513     if (is_ios) {
1514       # TODO(GYP)
1515       #  'actions': [
1516       #    {
1517       #      'action_name': 'copy_test_data',
1518       #      'variables': {
1519       #        'test_data_files': [
1520       #          'data/ssl/certificates/',
1521       #          'data/test.html',
1522       #          'data/url_request_unittest/',
1523       #        ],
1524       #        'test_data_prefix': 'net',
1525       #      },
1526       #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1527       #    },
1528       #  ],
1529       sources -= [
1530         # TODO(droger): The following tests are disabled because the
1531         # implementation is missing or incomplete.
1532         # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1533         "base/keygen_handler_unittest.cc",
1534         "disk_cache/backend_unittest.cc",
1535         "disk_cache/blockfile/block_files_unittest.cc",
1536
1537         # Need to read input data files.
1538         "filter/gzip_filter_unittest.cc",
1539         "socket/ssl_server_socket_unittest.cc",
1540         "spdy/fuzzing/hpack_fuzz_util_test.cc",
1541
1542         # Need TestServer.
1543         "cert_net/cert_net_fetcher_impl_unittest.cc",
1544         "proxy/proxy_script_fetcher_impl_unittest.cc",
1545         "socket/ssl_client_socket_unittest.cc",
1546         "url_request/url_fetcher_impl_unittest.cc",
1547         "url_request/url_request_context_builder_unittest.cc",
1548
1549         # Needs GetAppOutput().
1550         "test/python_utils_unittest.cc",
1551
1552         # The following tests are disabled because they don't apply to
1553         # iOS.
1554         # OS is not "linux" or "freebsd" or "openbsd".
1555         "socket/unix_domain_client_socket_posix_unittest.cc",
1556         "socket/unix_domain_listen_socket_posix_unittest.cc",
1557         "socket/unix_domain_server_socket_posix_unittest.cc",
1558
1559         # See bug http://crbug.com/344533.
1560         "disk_cache/blockfile/index_table_v3_unittest.cc",
1561       ]
1562     }
1563
1564     if (is_android) {
1565       sources -= [ "dns/dns_config_service_posix_unittest.cc" ]
1566
1567       # TODO(GYP)
1568       # # TODO(mmenke):  This depends on test_support_base, which depends on
1569       # #                icu.  Figure out a way to remove that dependency.
1570       # 'dependencies': [
1571       #   '../testing/android/native_test.gyp:native_test_native_code',
1572       # ]
1573
1574       set_sources_assignment_filter([])
1575       sources += [ "base/address_tracker_linux_unittest.cc" ]
1576       set_sources_assignment_filter(sources_assignment_filter)
1577     }
1578
1579     if (use_icu_alternatives_on_android) {
1580       sources -= [
1581         "base/filename_util_unittest.cc",
1582         "base/net_util_icu_unittest.cc",
1583       ]
1584       deps -= [ "//base:i18n" ]
1585     }
1586   }
1587 }  # !is_android && !is_win && !is_mac
1588
1589 executable("net_perftests") {
1590   testonly = true
1591   sources = [
1592     "base/mime_sniffer_perftest.cc",
1593     "cookies/cookie_monster_perftest.cc",
1594     "disk_cache/blockfile/disk_cache_perftest.cc",
1595     "extras/sqlite/sqlite_persistent_cookie_store_perftest.cc",
1596     "proxy/proxy_resolver_perftest.cc",
1597     "udp/udp_socket_perftest.cc",
1598   ]
1599
1600   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1601   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1602   deps = [
1603     "//base",
1604     "//base:i18n",
1605     "//base/test:test_support_perf",
1606     "//testing/gtest",
1607     "//url",
1608     ":extras",
1609     ":net",
1610     ":test_support",
1611   ]
1612
1613   if (enable_websockets) {
1614     sources += [ "websockets/websocket_frame_perftest.cc" ]
1615   }
1616
1617   if (use_v8_in_net) {
1618     deps += [ ":net_with_v8" ]
1619   } else {
1620     sources -= [ "proxy/proxy_resolver_perftest.cc" ]
1621   }
1622
1623   if (is_win && icu_use_data_file) {
1624     # This is needed to trigger the dll copy step on windows.
1625     # TODO(mark): Specifying this here shouldn't be necessary.
1626     deps += [ "//third_party/icu:icudata" ]
1627   }
1628 }