ui/views/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8
   9 gypi_values = exec_script("//build/gypi_to_gn.py",
  10                           [ rebase_path("views.gyp") ],
  11                           "scope",
  12                           [ "views.gyp" ])
  13
  14 component("views") {
  15   sources = gypi_values.views_sources
  16
  17   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  18   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  19
  20   defines = [ "VIEWS_IMPLEMENTATION" ]
  21
  22   deps = [
  23     "//base:i18n",
  24     "//base/third_party/dynamic_annotations",
  25     "//skia",
  26     "//third_party/icu",
  27     "//ui/accessibility",
  28     "//ui/native_theme",
  29     "//ui/resources",
  30     "//ui/strings",
  31     "//url",
  32   ]
  33
  34   public_deps = [
  35     "//base",
  36     "//ui/accessibility:ax_gen",
  37     "//ui/base",
  38     "//ui/base/ime",
  39     "//ui/compositor",
  40     "//ui/events",
  41     "//ui/events:events_base",
  42     "//ui/events/platform",
  43     "//ui/gfx",
  44     "//ui/gfx/geometry",
  45   ]
  46
  47   if (use_x11 && !is_chromeos) {
  48     deps += [ "//ui/display/util" ]
  49   }
  50   if (is_linux && !is_chromeos) {
  51     sources -= [ "window/window_button_order_provider.cc" ]
  52     deps += [ "//ui/shell_dialogs" ]
  53   } else {
  54     sources -= [
  55       "linux_ui/linux_ui.cc",
  56       "linux_ui/linux_ui.h",
  57       "linux_ui/window_button_order_observer.h",
  58       "linux_ui/window_button_order_provider.cc",
  59     ]
  60   }
  61
  62   if (is_chromeos) {
  63     sources -= [
  64       "linux_ui/status_icon_linux.cc",
  65       "linux_ui/status_icon_linux.h",
  66     ]
  67   }
  68
  69   if (is_win) {
  70     sources += gypi_values.views_win_sources
  71     libs = [
  72       "dwmapi.lib",
  73       "imm32.lib",
  74       "oleacc.lib",
  75     ]
  76     ldflags = [ "/DELAYLOAD:user32.dll" ]
  77     deps += [
  78       "//third_party/iaccessible2",
  79       "//third_party/wtl",
  80     ]
  81   }
  82
  83   if (use_ozone) {
  84     deps += [ "//ui/ozone" ]
  85   }
  86   if (use_x11) {
  87     configs += [
  88       "//build/config/linux:x11",
  89       "//build/config/linux:xrandr",
  90     ]
  91     deps += [
  92       "//ui/events/devices",
  93       "//ui/events/platform/x11",
  94       "//ui/gfx/x",
  95     ]
  96   }
  97
  98   if (use_aura) {
  99     sources += gypi_values.views_aura_sources
 100     deps += [
 101       "//ui/aura",
 102       "//ui/touch_selection",
 103       "//ui/wm",
 104     ]
 105     if (!is_chromeos) {
 106       sources += gypi_values.views_desktop_aura_sources
 107       if (use_x11) {
 108         sources += gypi_values.views_desktop_aura_x11_sources
 109         configs += [ "//build/config/linux:atk" ]
 110       } else if (is_win) {
 111         sources += gypi_values.views_desktop_aura_win_sources
 112       } else if (use_ozone) {
 113         sources += gypi_values.views_desktop_aura_ozone_sources
 114       }
 115       if (is_linux) {
 116         sources += gypi_values.views_desktop_aura_linux_sources
 117       }
 118     }
 119   }
 120
 121   if (is_mac) {
 122     deps += [ "//ui/accelerated_widget_mac" ]
 123     libs = [
 124       # Required by bridged_native_widget.mm.
 125       "QuartzCore.framework",
 126     ]
 127   }
 128 }
 129
 130 static_library("test_support") {
 131   testonly = true
 132   sources = gypi_values.views_test_support_sources
 133
 134   public_deps = [
 135     ":views",
 136   ]
 137   deps = [
 138     "//base",
 139     "//ipc:test_support",
 140     "//skia",
 141     "//testing/gtest",
 142     "//ui/base",
 143     "//ui/base/ime",
 144     "//ui/compositor",
 145     "//ui/compositor:test_support",
 146     "//ui/events",
 147     "//ui/events:events_base",
 148     "//ui/events:test_support",
 149     "//ui/events/platform",
 150     "//ui/gfx",
 151     "//ui/gfx/geometry",
 152   ]
 153
 154   if (use_aura) {
 155     sources += gypi_values.views_test_support_aura_sources
 156     deps += [
 157       "//ui/aura",
 158       "//ui/aura:test_support",
 159       "//ui/wm",
 160     ]
 161     if (use_x11 && !is_chromeos) {
 162       sources += gypi_values.views_test_support_desktop_aura_x11_sources
 163     }
 164   }
 165   if (use_x11) {
 166     deps += [ "//ui/gfx/x" ]
 167   }
 168   if (use_ozone || !use_x11) {
 169     sources -= [ "test/x11_property_change_waiter.cc" ]
 170   }
 171 }
 172
 173 test("views_unittests") {
 174   sources = gypi_values.views_unittests_sources
 175
 176   deps = [
 177     ":test_support",
 178     "//base",
 179     "//base:i18n",
 180     "//base/allocator",
 181     "//base/test:test_support",
 182     "//skia",
 183     "//testing/gtest",
 184     "//third_party/icu",
 185     "//ui/accessibility",
 186     "//ui/base",
 187     "//ui/base/ime",
 188     "//ui/base:test_support",
 189     "//ui/compositor:test_support",
 190     "//ui/events:test_support",
 191     "//ui/events:events_base",
 192     "//ui/events/platform",
 193     "//ui/gfx",
 194     "//ui/gfx/geometry",
 195     "//ui/gl",
 196     "//ui/resources",
 197     "//ui/strings",
 198     "//url",
 199   ]
 200
 201   if (is_win) {
 202     deps += [
 203       "//third_party/iaccessible2",
 204       "//third_party/wtl",
 205     ]
 206     libs = [
 207       "imm32.lib",
 208       "oleacc.lib",
 209       "comctl32.lib",
 210     ]
 211
 212     # TOOD(GYP)
 213     #'msvs_settings': {
 214     #  'VCManifestTool': {
 215     #    'AdditionalManifestFiles': [
 216     #      '$(ProjectDir)\\test\\views_unittest.manifest',
 217     #    ],
 218     #  },
 219     #},
 220   }
 221
 222   if (use_x11) {
 223     configs += [
 224       "//build/config/linux:x11",
 225       "//build/config/linux:xext",
 226     ]
 227     deps += [
 228       "//ui/events/devices",
 229       "//ui/events/platform/x11",
 230       "//ui/gfx/x",
 231     ]
 232   }
 233
 234   if (use_aura) {
 235     sources += gypi_values.views_unittests_aura_sources
 236     deps += [
 237       "//ui/aura",
 238       "//ui/aura:test_support",
 239       "//ui/touch_selection",
 240       "//ui/wm",
 241     ]
 242     if (!is_chromeos) {
 243       sources += gypi_values.views_unittests_desktop_aura_sources
 244       if (use_x11) {
 245         sources += gypi_values.views_unittests_desktop_aurax11_sources
 246       }
 247     }
 248   }
 249   if (!is_chromeos) {
 250     sources += gypi_values.views_unittests_desktop_sources
 251   }
 252   if (use_x11) {
 253     deps += [
 254       "//ui/events/platform/x11",
 255       "//ui/gfx/x",
 256     ]
 257   }
 258
 259   if (is_mac) {
 260     # views_unittests not yet compiling on Mac. http://crbug.com/378134
 261     sources -= [
 262       "bubble/bubble_window_targeter_unittest.cc",
 263       "controls/button/custom_button_unittest.cc",
 264       "controls/button/menu_button_unittest.cc",
 265       "controls/menu/menu_controller_unittest.cc",
 266       "controls/native/native_view_host_unittest.cc",
 267       "focus/focus_manager_unittest.cc",
 268       "ime/input_method_bridge_unittest.cc",
 269       "widget/widget_unittest.cc",
 270       "widget/window_reorderer_unittest.cc",
 271     ]
 272   }
 273 }
 274
 275 if (is_mac) {
 276   test("macviews_interactive_ui_tests") {
 277     sources = [
 278       "cocoa/bridged_native_widget_interactive_uitest.mm",
 279       "run_all_unittests.cc",
 280       "widget/native_widget_mac_interactive_uitest.mm",
 281     ]
 282     deps = [
 283       ":test_support",
 284       ":views",
 285       "//base",
 286       "//base/test:test_support",
 287       "//skia",
 288       "//testing/gtest",
 289       "//ui/base:test_support",
 290       "//ui/compositor",
 291       "//ui/resources",
 292       "//ui/resources:ui_test_pak",
 293       "//ui/strings",
 294     ]
 295   }
 296 }