build/android/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/rules.gni")
   6
   7 sun_tools_jar_path = "$root_gen_dir/sun_tools_jar/tools.jar"
   8
   9 action("find_sun_tools_jar") {
  10   script = "//build/android/gyp/find_sun_tools_jar.py"
  11   depfile = "$target_gen_dir/$target_name.d"
  12   outputs = [
  13     depfile,
  14     sun_tools_jar_path,
  15   ]
  16   args = [
  17     "--depfile",
  18     rebase_path(depfile, root_build_dir),
  19     "--output",
  20     rebase_path(sun_tools_jar_path, root_build_dir),
  21   ]
  22 }
  23
  24 java_prebuilt("sun_tools_java") {
  25   jar_path = sun_tools_jar_path
  26   jar_dep = ":find_sun_tools_jar"
  27 }
  28
  29 action("cpplib_stripped") {
  30   _strip_bin = "${android_tool_prefix}strip"
  31   _soname = "libc++_shared.so"
  32   _input_so = "${android_libcpp_root}/libs/${android_app_abi}/${_soname}"
  33   _output_so = "${root_out_dir}/lib.stripped/${_soname}"
  34
  35   script = "//build/gn_run_binary.py"
  36   inputs = [
  37     _strip_bin,
  38   ]
  39   sources = [
  40     _input_so,
  41   ]
  42   outputs = [
  43     _output_so,
  44   ]
  45
  46   _rebased_strip_bin = rebase_path(_strip_bin, root_out_dir)
  47   _rebased_input_so = rebase_path(_input_so, root_out_dir)
  48   _rebased_output_so = rebase_path(_output_so, root_out_dir)
  49   args = [
  50     _rebased_strip_bin,
  51     "--strip-unneeded",
  52     "-o",
  53     _rebased_output_so,
  54     _rebased_input_so,
  55   ]
  56 }