build/config/win/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/sanitizers/sanitizers.gni")
   6 import("//build/config/win/visual_studio_version.gni")
   7
   8 # Compiler setup for the Windows SDK. Applied to all targets.
   9 config("sdk") {
  10   # The include path is the stuff returned by the script.
  11   #include_dirs = msvc_config[0]  TODO(brettw) make this work.
  12
  13   defines = [
  14     "_ATL_NO_OPENGL",
  15     "_WINDOWS",
  16     "CERT_CHAIN_PARA_HAS_EXTRA_FIELDS",
  17     "NTDDI_VERSION=0x06030000",
  18     "PSAPI_VERSION=1",
  19     "WIN32",
  20     "_SECURE_ATL",
  21
  22     # This is required for ATL to use XP-safe versions of its functions.
  23     "_USING_V110_SDK71_",
  24   ]
  25 }
  26
  27 # Sets the default Windows build version. This is separated because some
  28 # targets need to manually override it for their compiles.
  29 config("winver") {
  30   defines = [
  31     "_WIN32_WINNT=0x0603",
  32     "WINVER=0x0603",
  33   ]
  34 }
  35
  36 # Linker flags for Windows SDK setup, this is applied only to EXEs and DLLs.
  37 config("sdk_link") {
  38   if (current_cpu == "x64") {
  39     ldflags = [ "/MACHINE:X64" ]
  40     lib_dirs = [
  41       "$windows_sdk_path\Lib\winv6.3\um\x64",
  42       "$visual_studio_path\VC\lib\amd64",
  43       "$visual_studio_path\VC\atlmfc\lib\amd64",
  44     ]
  45   } else {
  46     ldflags = [
  47       "/MACHINE:X86",
  48       "/SAFESEH",  # Not compatible with x64 so use only for x86.
  49     ]
  50     lib_dirs = [
  51       "$windows_sdk_path\Lib\winv6.3\um\x86",
  52       "$visual_studio_path\VC\lib",
  53       "$visual_studio_path\VC\atlmfc\lib",
  54     ]
  55     if (!is_syzyasan) {
  56       ldflags += [ "/largeaddressaware" ]
  57     }
  58   }
  59 }
  60
  61 # This default linker setup is provided separately from the SDK setup so
  62 # targets who want different library configurations can remove this and specify
  63 # their own.
  64 config("common_linker_setup") {
  65   ldflags = [
  66     "/FIXED:NO",
  67     "/ignore:4199",
  68     "/ignore:4221",
  69     "/NXCOMPAT",
  70
  71     # Suggested by Microsoft Devrel to avoid
  72     #   LINK : fatal error LNK1248: image size (80000000)
  73     #   exceeds maximum allowable size (80000000)
  74     # which started happening more regularly after VS2013 Update 4.
  75     "/maxilksize:2147483647",
  76   ]
  77
  78   # ASLR makes debugging with windbg difficult because Chrome.exe and
  79   # Chrome.dll share the same base name. As result, windbg will name the
  80   # Chrome.dll module like chrome_<base address>, where <base address>
  81   # typically changes with each launch. This in turn means that breakpoints in
  82   # Chrome.dll don't stick from one launch to the next. For this reason, we
  83   # turn ASLR off in debug builds.
  84   if (is_debug) {
  85     ldflags += [ "/DYNAMICBASE:NO" ]
  86   } else {
  87     ldflags += [ "/DYNAMICBASE" ]
  88   }
  89
  90   # Delay loaded DLLs.
  91   ldflags += [
  92     "/DELAYLOAD:dbghelp.dll",
  93     "/DELAYLOAD:dwmapi.dll",
  94     "/DELAYLOAD:shell32.dll",
  95     "/DELAYLOAD:uxtheme.dll",
  96   ]
  97 }
  98
  99 # Subsystem --------------------------------------------------------------------
 100
 101 # This is appended to the subsystem to specify a minimum version.
 102 if (current_cpu == "x64") {
 103   # The number after the comma is the minimum required OS version.
 104   # 5.02 = Windows Server 2003.
 105   subsystem_version_suffix = ",5.02"
 106 } else {
 107   # 5.01 = Windows XP.
 108   subsystem_version_suffix = ",5.01"
 109 }
 110
 111 config("console") {
 112   ldflags = [ "/SUBSYSTEM:CONSOLE$subsystem_version_suffix" ]
 113 }
 114 config("windowed") {
 115   ldflags = [ "/SUBSYSTEM:WINDOWS$subsystem_version_suffix" ]
 116 }
 117
 118 # Incremental linking ----------------------------------------------------------
 119
 120 incremental_linking_on_switch = [ "/INCREMENTAL" ]
 121 incremental_linking_off_switch = [ "/INCREMENTAL:NO" ]
 122 if (is_debug) {
 123   default_incremental_linking_switch = incremental_linking_on_switch
 124 } else {
 125   default_incremental_linking_switch = incremental_linking_off_switch
 126 }
 127
 128 # Applies incremental linking or not depending on the current configuration.
 129 config("default_incremental_linking") {
 130   ldflags = default_incremental_linking_switch
 131 }
 132
 133 # Explicitly on or off incremental linking
 134 config("incremental_linking") {
 135   ldflags = incremental_linking_on_switch
 136 }
 137 config("no_incremental_linking") {
 138   ldflags = incremental_linking_off_switch
 139 }
 140
 141 # Some large modules can't handle incremental linking in some situations. This
 142 # config should be applied to large modules to turn off incremental linking
 143 # when it won't work.
 144 config("default_large_module_incremental_linking") {
 145   if (symbol_level > 0 && (current_cpu == "x86" || !is_component_build)) {
 146     # When symbols are on, things get so large that the tools fail due to the
 147     # size of the .ilk files.
 148     ldflags = incremental_linking_off_switch
 149   } else {
 150     # Otherwise just do the default incremental linking for this build type.
 151     ldflags = default_incremental_linking_switch
 152   }
 153 }
 154
 155 # Character set ----------------------------------------------------------------
 156
 157 # Not including this config means "ansi" (8-bit system codepage).
 158 config("unicode") {
 159   defines = [
 160     "_UNICODE",
 161     "UNICODE",
 162   ]
 163 }
 164
 165 # Lean and mean ----------------------------------------------------------------
 166
 167 # Some third party code might not compile with WIN32_LEAN_AND_MEAN so we have
 168 # to have a separate config for it. Remove this config from your target to
 169 # get the "bloaty and accomodating" version of windows.h.
 170 config("lean_and_mean") {
 171   defines = [ "WIN32_LEAN_AND_MEAN" ]
 172 }
 173
 174 # Nominmax --------------------------------------------------------------------
 175
 176 # Some third party code defines NOMINMAX before including windows.h, which
 177 # then causes warnings when it's been previously defined on the command line.
 178 # For such targets, this config can be removed.
 179
 180 config("nominmax") {
 181   defines = [ "NOMINMAX" ]
 182 }
 183
 184 # Target WinRT ----------------------------------------------------------------
 185
 186 # When targeting Windows Runtime, certain compiler/linker flags are necessary.
 187
 188 config("target_winrt") {
 189   defines = [
 190     "WINRT",
 191     "WINAPI_FAMILY=WINAPI_FAMILY_PC_APP",
 192   ]
 193   cflags_cc = [
 194     "/ZW",
 195     "/EHsc",
 196   ]
 197 }