build/secondary/tools/grit/repack.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This file defines a template to invoke grit repack in a consistent manner.
   6 #
   7 # Parameters:
   8 #   sources  [required]
   9 #       List of pak files that need to be combined.
  10 #
  11 #   output  [required]
  12 #       File name (single string) of the output file.
  13 #
  14 #   repack_options  [optional]
  15 #       List of extra arguments to pass.
  16 #
  17 #   deps  [optional]
  18 #   visibility  [optional]
  19 #       Normal meaning.
  20 template("repack") {
  21   action(target_name) {
  22     assert(defined(invoker.sources), "Need sources for $target_name")
  23     assert(defined(invoker.output), "Need output for $target_name")
  24
  25     if (defined(invoker.visibility)) {
  26       visibility = invoker.visibility
  27     }
  28
  29     script = "//tools/grit/grit/format/repack.py"
  30
  31     inputs = invoker.sources
  32     outputs = [
  33       invoker.output,
  34     ]
  35
  36     args = []
  37     if (defined(invoker.repack_options)) {
  38       args += invoker.repack_options
  39     }
  40     args += [ rebase_path(invoker.output, root_build_dir) ]
  41     args += rebase_path(invoker.sources, root_build_dir)
  42
  43     if (defined(invoker.deps)) {
  44       deps = invoker.deps
  45     }
  46   }
  47 }