build/toolchain/gcc_toolchain.gni

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This value will be inherited in the toolchain below.
   6 concurrent_links = exec_script("get_concurrent_links.py", [], "value")
   7
   8 # This template defines a toolchain for something that works like gcc
   9 # (including clang).
  10 #
  11 # It requires the following variables specifying the executables to run:
  12 #  - cc
  13 #  - cxx
  14 #  - ar
  15 #  - ld
  16 # and the following which is used in the toolchain_args
  17 #  - toolchain_cpu  (What "current_cpu" should be set to when invoking a
  18 #                    build using this toolchain.)
  19 #  - toolchain_os  (What "current_os" should be set to when invoking a
  20 #                   build using this toolchain.)
  21 #
  22 # Optional parameters:
  23 #  - libs_section_prefix
  24 #  - libs_section_postfix
  25 #      The contents of these strings, if specified, will be placed around
  26 #      the libs section of the linker line. It allows one to inject libraries
  27 #      at the beginning and end for all targets in a toolchain.
  28 #  - solink_libs_section_prefix
  29 #  - solink_libs_section_postfix
  30 #      Same as libs_section_{pre,post}fix except used for solink instead of link.
  31 #  - post_solink
  32 #      The content of this string, if specified, will be appended to the solink
  33 #      command.
  34 #  - deps
  35 #      Just forwarded to the toolchain definition.
  36 #  - is_clang
  37 template("gcc_toolchain") {
  38   toolchain(target_name) {
  39     assert(defined(invoker.cc), "gcc_toolchain() must specify a \"cc\" value")
  40     assert(defined(invoker.cxx), "gcc_toolchain() must specify a \"cxx\" value")
  41     assert(defined(invoker.ar), "gcc_toolchain() must specify a \"ar\" value")
  42     assert(defined(invoker.ld), "gcc_toolchain() must specify a \"ld\" value")
  43     assert(defined(invoker.toolchain_cpu),
  44            "gcc_toolchain() must specify a \"toolchain_cpu\"")
  45     assert(defined(invoker.toolchain_os),
  46            "gcc_toolchain() must specify a \"toolchain_os\"")
  47
  48     # We can't do string interpolation ($ in strings) on things with dots in
  49     # them. To allow us to use $cc below, for example, we create copies of
  50     # these values in our scope.
  51     cc = invoker.cc
  52     cxx = invoker.cxx
  53     ar = invoker.ar
  54     ld = invoker.ld
  55     if (defined(invoker.readelf)) {
  56       readelf = invoker.readelf
  57     } else {
  58       readelf = "readelf"
  59     }
  60     if (defined(invoker.nm)) {
  61       nm = invoker.nm
  62     } else {
  63       nm = "nm"
  64     }
  65
  66     # Bring these into our scope for string interpolation with default values.
  67     if (defined(invoker.libs_section_prefix)) {
  68       libs_section_prefix = invoker.libs_section_prefix
  69     } else {
  70       libs_section_prefix = ""
  71     }
  72
  73     if (defined(invoker.libs_section_postfix)) {
  74       libs_section_postfix = invoker.libs_section_postfix
  75     } else {
  76       libs_section_postfix = ""
  77     }
  78
  79     if (defined(invoker.solink_libs_section_prefix)) {
  80       solink_libs_section_prefix = invoker.solink_libs_section_prefix
  81     } else {
  82       solink_libs_section_prefix = ""
  83     }
  84
  85     if (defined(invoker.solink_libs_section_postfix)) {
  86       solink_libs_section_postfix = invoker.solink_libs_section_postfix
  87     } else {
  88       solink_libs_section_postfix = ""
  89     }
  90
  91     # These library switches can apply to all tools below.
  92     lib_switch = "-l"
  93     lib_dir_switch = "-L"
  94
  95     tool("cc") {
  96       depfile = "{{output}}.d"
  97       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
  98       depsformat = "gcc"
  99       description = "CC {{output}}"
 100       outputs = [
 101         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 102       ]
 103     }
 104
 105     tool("cxx") {
 106       depfile = "{{output}}.d"
 107       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
 108       depsformat = "gcc"
 109       description = "CXX {{output}}"
 110       outputs = [
 111         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 112       ]
 113     }
 114
 115     tool("asm") {
 116       # For GCC we can just use the C compiler to compile assembly.
 117       depfile = "{{output}}.d"
 118       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
 119       depsformat = "gcc"
 120       description = "ASM {{output}}"
 121       outputs = [
 122         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 123       ]
 124     }
 125
 126     tool("alink") {
 127       rspfile = "{{output}}.rsp"
 128       command = "rm -f {{output}} && $ar rcs {{output}} @$rspfile"
 129       description = "AR {{output}}"
 130       rspfile_content = "{{inputs}}"
 131       outputs = [
 132         "{{target_out_dir}}/{{target_output_name}}{{output_extension}}",
 133       ]
 134       default_output_extension = ".a"
 135       output_prefix = "lib"
 136     }
 137
 138     tool("solink") {
 139       soname = "{{target_output_name}}{{output_extension}}"  # e.g. "libfoo.so".
 140       sofile = "{{root_out_dir}}/$soname"  # Possibly including toolchain dir.
 141       rspfile = sofile + ".rsp"
 142
 143       # These variables are not built into GN but are helpers that implement
 144       # (1) linking to produce a .so, (2) extracting the symbols from that file
 145       # to a temporary file, (3) if the temporary file has differences from the
 146       # existing .TOC file, overwrite it, otherwise, don't change it.
 147       tocfile = sofile + ".TOC"
 148       temporary_tocname = sofile + ".tmp"
 149       link_command =
 150           "$ld -shared {{ldflags}} -o $sofile -Wl,-soname=$soname @$rspfile"
 151       assert(defined(readelf), "to solink you must have a readelf")
 152       assert(defined(nm), "to solink you must have an nm")
 153       toc_command = "{ $readelf -d $sofile | grep SONAME ; $nm -gD -f p $sofile | cut -f1-2 -d' '; } > $temporary_tocname"
 154       replace_command = "if ! cmp -s $temporary_tocname $tocfile; then mv $temporary_tocname $tocfile; fi"
 155
 156       command = "$link_command && $toc_command && $replace_command"
 157       if (defined(invoker.postsolink)) {
 158         command += " && " + invoker.postsolink
 159       }
 160       rspfile_content = "-Wl,--whole-archive {{inputs}} {{solibs}} -Wl,--no-whole-archive $solink_libs_section_prefix {{libs}} $solink_libs_section_postfix"
 161
 162       description = "SOLINK $sofile"
 163
 164       # Use this for {{output_extension}} expansions unless a target manually
 165       # overrides it (in which case {{output_extension}} will be what the target
 166       # specifies).
 167       default_output_extension = ".so"
 168       if (defined(invoker.default_output_extension)) {
 169         default_output_extension = invoker.default_output_extension
 170       }
 171
 172       output_prefix = "lib"
 173
 174       # Since the above commands only updates the .TOC file when it changes, ask
 175       # Ninja to check if the timestamp actually changed to know if downstream
 176       # dependencies should be recompiled.
 177       restat = true
 178
 179       # Tell GN about the output files. It will link to the sofile but use the
 180       # tocfile for dependency management.
 181       outputs = [
 182         sofile,
 183         tocfile,
 184       ]
 185       if (defined(invoker.solink_outputs)) {
 186         outputs += invoker.solink_outputs
 187       }
 188       link_output = sofile
 189       depend_output = tocfile
 190     }
 191
 192     tool("link") {
 193       outfile = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}"
 194       rspfile = "$outfile.rsp"
 195       command = "$ld {{ldflags}} -o $outfile -Wl,--start-group @$rspfile {{solibs}} -Wl,--end-group $libs_section_prefix {{libs}} $libs_section_postfix"
 196       if (defined(invoker.postlink)) {
 197         command += " && " + invoker.postlink
 198       }
 199       description = "LINK $outfile"
 200       rspfile_content = "{{inputs}}"
 201       outputs = [
 202         outfile,
 203       ]
 204       if (defined(invoker.link_outputs)) {
 205         outputs += invoker.link_outputs
 206       }
 207     }
 208
 209     tool("stamp") {
 210       command = "touch {{output}}"
 211       description = "STAMP {{output}}"
 212     }
 213
 214     tool("copy") {
 215       command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
 216       description = "COPY {{source}} {{output}}"
 217     }
 218
 219     # When invoking this toolchain not as the default one, these args will be
 220     # passed to the build. They are ignored when this is the default toolchain.
 221     toolchain_args() {
 222       current_cpu = invoker.toolchain_cpu
 223       current_os = invoker.toolchain_os
 224
 225       # These values need to be passed through unchanged.
 226       target_os = target_os
 227       target_cpu = target_cpu
 228
 229       if (defined(invoker.is_clang)) {
 230         is_clang = invoker.is_clang
 231       }
 232     }
 233
 234     if (defined(invoker.deps)) {
 235       deps = invoker.deps
 236     }
 237   }
 238 }