chrome/browser/ui/cocoa/single_web_contents_dialog_manager_cocoa.mm

   1 // Copyright 2015 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/single_web_contents_dialog_manager_cocoa.h"
   6
   7 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_sheet.h"
   8 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_mac.h"
   9 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet_controller.h"
  10 #include "components/web_modal/web_contents_modal_dialog_host.h"
  11 #include "components/web_modal/web_contents_modal_dialog_manager.h"
  12 #include "content/public/browser/web_contents.h"
  13
  14 SingleWebContentsDialogManagerCocoa::SingleWebContentsDialogManagerCocoa(
  15     ConstrainedWindowMac* client,
  16     id<ConstrainedWindowSheet> sheet,
  17     web_modal::SingleWebContentsDialogManagerDelegate* delegate)
  18     : client_(client),
  19       sheet_([sheet retain]),
  20       delegate_(delegate),
  21       host_(nullptr),
  22       shown_(false) {
  23   DCHECK(client);
  24   client->set_manager(this);
  25 }
  26
  27 SingleWebContentsDialogManagerCocoa::~SingleWebContentsDialogManagerCocoa() {
  28 }
  29
  30 void SingleWebContentsDialogManagerCocoa::Show() {
  31   if (shown_)
  32     return;
  33
  34   // If a dialog is initially shown on a hidden/background WebContents, the
  35   // |delegate_| will defer the Show() until the WebContents is shown. If the
  36   // defer happens during tab closure or tab dragging, a suspected data race or
  37   // ObserverList ordering may result in |host_| being null here. If the tab is
  38   // closing anyway, it doesn't matter. For tab dragging, avoid a crash, but the
  39   // user may have to switch tabs again to see the dialog. See
  40   // http://crbug.com/514826 for details.
  41   if (!host_)
  42     return;
  43
  44   NSView* parent_view = host_->GetHostView();
  45   // Note that simply [parent_view window] for an inactive tab is nil. However,
  46   // the following should always be non-nil for all WebContents containers.
  47   NSWindow* parent_window =
  48       delegate_->GetWebContents()->GetTopLevelNativeWindow();
  49
  50   shown_ = true;
  51   [[ConstrainedWindowSheetController controllerForParentWindow:parent_window]
  52       showSheet:sheet_ forParentView:parent_view];
  53 }
  54
  55 void SingleWebContentsDialogManagerCocoa::Hide() {
  56 }
  57
  58 void SingleWebContentsDialogManagerCocoa::Close() {
  59   [[ConstrainedWindowSheetController controllerForSheet:sheet_]
  60       closeSheet:sheet_];
  61   client_->set_manager(nullptr);
  62   client_->OnDialogClosing();      // |client_| might delete itself here.
  63   delegate_->WillClose(dialog());  // Deletes |this|.
  64 }
  65
  66 void SingleWebContentsDialogManagerCocoa::Focus() {
  67 }
  68
  69 void SingleWebContentsDialogManagerCocoa::Pulse() {
  70   [[ConstrainedWindowSheetController controllerForSheet:sheet_]
  71       pulseSheet:sheet_];
  72 }
  73
  74 void SingleWebContentsDialogManagerCocoa::HostChanged(
  75     web_modal::WebContentsModalDialogHost* new_host) {
  76   // No need to observe the host. For Cocoa, the constrained window controller
  77   // will reposition the dialog when necessary. The host can also never change.
  78   // Tabs showing a dialog can not be dragged off a Cocoa browser window.
  79   // However, closing a tab with a dialog open will set the host back to null.
  80   DCHECK_NE(!!host_, !!new_host);
  81   host_ = new_host;
  82 }
  83
  84 gfx::NativeWindow SingleWebContentsDialogManagerCocoa::dialog() {
  85   return [sheet_ sheetWindow];
  86 }