chrome/browser/ui/cocoa/wrench_menu/wrench_menu_controller_unittest.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "base/command_line.h"
   6 #include "base/mac/scoped_nsobject.h"
   7 #include "base/run_loop.h"
   8 #include "base/strings/sys_string_conversions.h"
   9 #include "base/strings/utf_string_conversions.h"
  10 #include "chrome/app/chrome_command_ids.h"
  11 #include "chrome/browser/sync/profile_sync_service_factory.h"
  12 #include "chrome/browser/sync/sessions/sessions_sync_manager.h"
  13 #include "chrome/browser/ui/browser_list.h"
  14 #include "chrome/browser/ui/browser_list_observer.h"
  15 #include "chrome/browser/ui/cocoa/cocoa_profile_test.h"
  16 #include "chrome/browser/ui/cocoa/run_loop_testing.h"
  17 #import "chrome/browser/ui/cocoa/toolbar/toolbar_controller.h"
  18 #import "chrome/browser/ui/cocoa/view_resizer_pong.h"
  19 #import "chrome/browser/ui/cocoa/wrench_menu/wrench_menu_controller.h"
  20 #include "chrome/browser/ui/toolbar/recent_tabs_builder_test_helper.h"
  21 #include "chrome/browser/ui/toolbar/recent_tabs_sub_menu_model.h"
  22 #include "chrome/browser/ui/toolbar/wrench_menu_model.h"
  23 #include "chrome/common/chrome_switches.h"
  24 #include "chrome/grit/generated_resources.h"
  25 #include "chrome/test/base/testing_profile.h"
  26 #include "components/sync_driver/local_device_info_provider_mock.h"
  27 #include "grit/theme_resources.h"
  28 #include "sync/api/fake_sync_change_processor.h"
  29 #include "sync/api/sync_error_factory_mock.h"
  30 #include "testing/gmock/include/gmock/gmock.h"
  31 #include "testing/gtest/include/gtest/gtest.h"
  32 #include "testing/gtest_mac.h"
  33 #include "testing/platform_test.h"
  34 #include "ui/base/l10n/l10n_util.h"
  35 #include "ui/base/resource/resource_bundle.h"
  36
  37 namespace {
  38
  39 class MockWrenchMenuModel : public WrenchMenuModel {
  40  public:
  41   MockWrenchMenuModel() : WrenchMenuModel() {}
  42   ~MockWrenchMenuModel() {
  43     // This dirty, ugly hack gets around a bug in the test. In
  44     // ~WrenchMenuModel(), there's a call to TabstripModel::RemoveObserver(this)
  45     // which mysteriously leads to this crash: http://crbug.com/49206 .  It
  46     // seems that the vector of observers is getting hosed somewhere between
  47     // |-[ToolbarController dealloc]| and ~MockWrenchMenuModel(). This line
  48     // short-circuits the parent destructor to avoid this crash.
  49     tab_strip_model_ = NULL;
  50   }
  51   MOCK_METHOD2(ExecuteCommand, void(int command_id, int event_flags));
  52 };
  53
  54 class DummyRouter : public browser_sync::LocalSessionEventRouter {
  55  public:
  56   ~DummyRouter() override {}
  57   void StartRoutingTo(
  58       browser_sync::LocalSessionEventHandler* handler) override {}
  59   void Stop() override {}
  60 };
  61
  62 class WrenchMenuControllerTest
  63     : public CocoaProfileTest {
  64  public:
  65   WrenchMenuControllerTest()
  66       : local_device_(new sync_driver::LocalDeviceInfoProviderMock(
  67             "WrenchMenuControllerTest",
  68             "Test Machine",
  69             "Chromium 10k",
  70             "Chrome 10k",
  71             sync_pb::SyncEnums_DeviceType_TYPE_LINUX,
  72             "device_id")) {
  73   }
  74
  75   void SetUp() override {
  76     CocoaProfileTest::SetUp();
  77     ASSERT_TRUE(browser());
  78
  79     controller_.reset([[WrenchMenuController alloc] initWithBrowser:browser()]);
  80     fake_model_.reset(new MockWrenchMenuModel);
  81
  82     manager_.reset(new browser_sync::SessionsSyncManager(
  83         profile(),
  84         local_device_.get(),
  85         scoped_ptr<browser_sync::LocalSessionEventRouter>(
  86             new DummyRouter())));
  87     manager_->MergeDataAndStartSyncing(
  88         syncer::SESSIONS,
  89         syncer::SyncDataList(),
  90         scoped_ptr<syncer::SyncChangeProcessor>(
  91             new syncer::FakeSyncChangeProcessor),
  92         scoped_ptr<syncer::SyncErrorFactory>(
  93             new syncer::SyncErrorFactoryMock));
  94   }
  95
  96   void RegisterRecentTabs(RecentTabsBuilderTestHelper* helper) {
  97     helper->ExportToSessionsSyncManager(manager_.get());
  98   }
  99
 100   sync_driver::OpenTabsUIDelegate* GetOpenTabsDelegate() {
 101     return manager_.get();
 102   }
 103
 104   void TearDown() override {
 105     fake_model_.reset();
 106     controller_.reset();
 107     manager_.reset();
 108     CocoaProfileTest::TearDown();
 109   }
 110
 111   WrenchMenuController* controller() {
 112     return controller_.get();
 113   }
 114
 115   base::scoped_nsobject<WrenchMenuController> controller_;
 116
 117   scoped_ptr<MockWrenchMenuModel> fake_model_;
 118
 119  private:
 120   scoped_ptr<browser_sync::SessionsSyncManager> manager_;
 121   scoped_ptr<sync_driver::LocalDeviceInfoProviderMock> local_device_;
 122 };
 123
 124 TEST_F(WrenchMenuControllerTest, Initialized) {
 125   EXPECT_TRUE([controller() menu]);
 126   EXPECT_GE([[controller() menu] numberOfItems], 5);
 127 }
 128
 129 TEST_F(WrenchMenuControllerTest, DispatchSimple) {
 130   base::scoped_nsobject<NSButton> button([[NSButton alloc] init]);
 131   [button setTag:IDC_ZOOM_PLUS];
 132
 133   // Set fake model to test dispatching.
 134   EXPECT_CALL(*fake_model_, ExecuteCommand(IDC_ZOOM_PLUS, 0));
 135   [controller() setModel:fake_model_.get()];
 136
 137   [controller() dispatchWrenchMenuCommand:button.get()];
 138   chrome::testing::NSRunLoopRunAllPending();
 139 }
 140
 141 TEST_F(WrenchMenuControllerTest, RecentTabsFavIcon) {
 142   RecentTabsBuilderTestHelper recent_tabs_builder;
 143   recent_tabs_builder.AddSession();
 144   recent_tabs_builder.AddWindow(0);
 145   recent_tabs_builder.AddTab(0, 0);
 146   RegisterRecentTabs(&recent_tabs_builder);
 147
 148   RecentTabsSubMenuModel recent_tabs_sub_menu_model(
 149       NULL, browser(), GetOpenTabsDelegate());
 150   fake_model_->AddSubMenuWithStringId(
 151       IDC_RECENT_TABS_MENU, IDS_RECENT_TABS_MENU,
 152       &recent_tabs_sub_menu_model);
 153
 154   [controller() setModel:fake_model_.get()];
 155   NSMenu* menu = [controller() menu];
 156   [controller() updateRecentTabsSubmenu];
 157
 158   NSString* title = l10n_util::GetNSStringWithFixup(IDS_RECENT_TABS_MENU);
 159   NSMenu* recent_tabs_menu = [[menu itemWithTitle:title] submenu];
 160   EXPECT_TRUE(recent_tabs_menu);
 161   EXPECT_EQ(6, [recent_tabs_menu numberOfItems]);
 162
 163   // Send a icon changed event and verify that the icon is updated.
 164   gfx::Image icon(ResourceBundle::GetSharedInstance().GetNativeImageNamed(
 165       IDR_BOOKMARKS_FAVICON));
 166   recent_tabs_sub_menu_model.SetIcon(3, icon);
 167   EXPECT_NSNE(icon.ToNSImage(), [[recent_tabs_menu itemAtIndex:3] image]);
 168   recent_tabs_sub_menu_model.GetMenuModelDelegate()->OnIconChanged(3);
 169   EXPECT_TRUE([[recent_tabs_menu itemAtIndex:3] image]);
 170   EXPECT_NSEQ(icon.ToNSImage(), [[recent_tabs_menu itemAtIndex:3] image]);
 171
 172   controller_.reset();
 173   fake_model_.reset();
 174 }
 175
 176 TEST_F(WrenchMenuControllerTest, RecentTabsElideTitle) {
 177   // Add 1 session with 1 window and 2 tabs.
 178   RecentTabsBuilderTestHelper recent_tabs_builder;
 179   recent_tabs_builder.AddSession();
 180   recent_tabs_builder.AddWindow(0);
 181   base::string16 tab1_short_title = base::ASCIIToUTF16("Short");
 182   recent_tabs_builder.AddTabWithInfo(0, 0, base::Time::Now(), tab1_short_title);
 183   base::string16 tab2_long_title = base::ASCIIToUTF16(
 184       "Very very very very very very very very very very very very long");
 185   recent_tabs_builder.AddTabWithInfo(0, 0,
 186       base::Time::Now() - base::TimeDelta::FromMinutes(10), tab2_long_title);
 187   RegisterRecentTabs(&recent_tabs_builder);
 188
 189   RecentTabsSubMenuModel recent_tabs_sub_menu_model(
 190       NULL, browser(), GetOpenTabsDelegate());
 191   fake_model_->AddSubMenuWithStringId(
 192       IDC_RECENT_TABS_MENU, IDS_RECENT_TABS_MENU,
 193       &recent_tabs_sub_menu_model);
 194
 195   [controller() setModel:fake_model_.get()];
 196   NSMenu* menu = [controller() menu];
 197   [controller() updateRecentTabsSubmenu];
 198
 199   NSString* title = l10n_util::GetNSStringWithFixup(IDS_RECENT_TABS_MENU);
 200   NSMenu* recent_tabs_menu = [[menu itemWithTitle:title] submenu];
 201   EXPECT_TRUE(recent_tabs_menu);
 202   EXPECT_EQ(7, [recent_tabs_menu numberOfItems]);
 203
 204   // Item 1: separator.
 205   EXPECT_TRUE([[recent_tabs_menu itemAtIndex:1] isSeparatorItem]);
 206
 207   // Index 2: restore tabs menu item.
 208   NSString* restore_tab_label = l10n_util::FixUpWindowsStyleLabel(
 209       recent_tabs_sub_menu_model.GetLabelAt(2));
 210   EXPECT_NSEQ(restore_tab_label, [[recent_tabs_menu itemAtIndex:2] title]);
 211
 212   // Item 3: separator.
 213   EXPECT_TRUE([[recent_tabs_menu itemAtIndex:3] isSeparatorItem]);
 214
 215   // Item 4: window title.
 216   EXPECT_NSEQ(
 217       base::SysUTF16ToNSString(recent_tabs_sub_menu_model.GetLabelAt(4)),
 218       [[recent_tabs_menu itemAtIndex:4] title]);
 219
 220   // Item 5: short tab title.
 221   EXPECT_NSEQ(base::SysUTF16ToNSString(tab1_short_title),
 222               [[recent_tabs_menu itemAtIndex:5] title]);
 223
 224   // Item 6: long tab title.
 225   NSString* tab2_actual_title = [[recent_tabs_menu itemAtIndex:6] title];
 226   NSUInteger title_length = [tab2_actual_title length];
 227   EXPECT_GT(tab2_long_title.size(), title_length);
 228   NSString* actual_substring =
 229       [tab2_actual_title substringToIndex:title_length - 1];
 230   NSString* expected_substring = [base::SysUTF16ToNSString(tab2_long_title)
 231       substringToIndex:title_length - 1];
 232   EXPECT_NSEQ(expected_substring, actual_substring);
 233
 234   controller_.reset();
 235   fake_model_.reset();
 236 }
 237
 238 // Verify that |RecentTabsMenuModelDelegate| is deleted before the model
 239 // it's observing.
 240 TEST_F(WrenchMenuControllerTest, RecentTabDeleteOrder) {
 241   [controller_ menuNeedsUpdate:[controller_ menu]];
 242   // If the delete order is wrong then the test will crash on exit.
 243 }
 244
 245 class BrowserRemovedObserver : public chrome::BrowserListObserver {
 246  public:
 247   BrowserRemovedObserver() { BrowserList::AddObserver(this); }
 248   ~BrowserRemovedObserver() override { BrowserList::RemoveObserver(this); }
 249   void WaitUntilBrowserRemoved() { run_loop_.Run(); }
 250   void OnBrowserRemoved(Browser* browser) override { run_loop_.Quit(); }
 251
 252  private:
 253   base::RunLoop run_loop_;
 254
 255   DISALLOW_COPY_AND_ASSIGN(BrowserRemovedObserver);
 256 };
 257
 258 // Test that WrenchMenuController can be destroyed after the Browser.
 259 // This can happen because the WrenchMenuController's owner (ToolbarController)
 260 // can outlive the Browser.
 261 TEST_F(WrenchMenuControllerTest, DestroyedAfterBrowser) {
 262   BrowserRemovedObserver observer;
 263   // This is normally called by ToolbarController, but since |controller_| is
 264   // not owned by one, call it here.
 265   [controller_ browserWillBeDestroyed];
 266   CloseBrowserWindow();
 267   observer.WaitUntilBrowserRemoved();
 268   // |controller_| is released in TearDown().
 269 }
 270
 271 }  // namespace