chrome/common/mac/launchd.mm

   1 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "chrome/common/mac/launchd.h"
   6
   7 #import <Foundation/Foundation.h>
   8 #include <launch.h>
   9
  10 #include "base/mac/foundation_util.h"
  11 #include "base/mac/scoped_cftyperef.h"
  12 #include "base/mac/scoped_nsautorelease_pool.h"
  13 #include "base/process/launch.h"
  14 #include "base/strings/stringprintf.h"
  15 #include "base/strings/sys_string_conversions.h"
  16 #include "third_party/google_toolbox_for_mac/src/Foundation/GTMServiceManagement.h"
  17
  18 namespace {
  19
  20 NSString* SanitizeShellArgument(NSString* arg) {
  21   if (!arg) {
  22     return nil;
  23   }
  24   NSString *sanitize = [arg stringByReplacingOccurrencesOfString:@"'"
  25                                                       withString:@"'\''"];
  26   return [NSString stringWithFormat:@"'%@'", sanitize];
  27 }
  28
  29 NSURL* GetPlistURL(Launchd::Domain domain,
  30                    Launchd::Type type,
  31                    CFStringRef name) {
  32   NSArray* library_paths =
  33       NSSearchPathForDirectoriesInDomains(NSLibraryDirectory, domain, YES);
  34   DCHECK_EQ([library_paths count], 1U);
  35   NSString* library_path = [library_paths objectAtIndex:0];
  36
  37   NSString *launch_dir_name = (type == Launchd::Daemon) ? @"LaunchDaemons"
  38                                                         : @"LaunchAgents";
  39   NSString* launch_dir =
  40       [library_path stringByAppendingPathComponent:launch_dir_name];
  41
  42   NSError* err;
  43   if (![[NSFileManager defaultManager] createDirectoryAtPath:launch_dir
  44                                  withIntermediateDirectories:YES
  45                                                   attributes:nil
  46                                                        error:&err]) {
  47     DLOG(ERROR) << "GetPlistURL " << base::mac::NSToCFCast(err);
  48     return nil;
  49   }
  50
  51   NSString* plist_file_path =
  52       [launch_dir stringByAppendingPathComponent:base::mac::CFToNSCast(name)];
  53   plist_file_path = [plist_file_path stringByAppendingPathExtension:@"plist"];
  54   return [NSURL fileURLWithPath:plist_file_path isDirectory:NO];
  55 }
  56
  57 }  // namespace
  58
  59 static_assert(static_cast<int>(Launchd::User) ==
  60               static_cast<int>(NSUserDomainMask),
  61               "NSUserDomainMask value changed");
  62 static_assert(static_cast<int>(Launchd::Local) ==
  63               static_cast<int>(NSLocalDomainMask),
  64               "NSLocalDomainMask value changed");
  65 static_assert(static_cast<int>(Launchd::Network) ==
  66               static_cast<int>(NSNetworkDomainMask),
  67               "NSNetworkDomainMask value changed");
  68 static_assert(static_cast<int>(Launchd::System) ==
  69               static_cast<int>(NSSystemDomainMask),
  70               "NSSystemDomainMask value changed");
  71
  72 Launchd* Launchd::g_instance_ = NULL;
  73
  74 Launchd* Launchd::GetInstance() {
  75   if (!g_instance_) {
  76     g_instance_ = Singleton<Launchd>::get();
  77   }
  78   return g_instance_;
  79 }
  80
  81 void Launchd::SetInstance(Launchd* instance) {
  82   if (instance) {
  83     CHECK(!g_instance_);
  84   }
  85   g_instance_ = instance;
  86 }
  87
  88 Launchd::~Launchd() { }
  89
  90 CFDictionaryRef Launchd::CopyJobDictionary(CFStringRef label) {
  91   return GTMSMJobCopyDictionary(label);
  92 }
  93
  94 CFDictionaryRef Launchd::CopyDictionaryByCheckingIn(CFErrorRef* error) {
  95   return GTMSMCopyJobCheckInDictionary(error);
  96 }
  97
  98 bool Launchd::RemoveJob(CFStringRef label, CFErrorRef* error) {
  99   return GTMSMJobRemove(label, error);
 100 }
 101
 102 bool Launchd::RestartJob(Domain domain,
 103                          Type type,
 104                          CFStringRef name,
 105                          CFStringRef cf_session_type) {
 106   base::mac::ScopedNSAutoreleasePool pool;
 107   NSURL* url = GetPlistURL(domain, type, name);
 108   NSString* ns_path = [url path];
 109   ns_path = SanitizeShellArgument(ns_path);
 110   const char* file_path = [ns_path fileSystemRepresentation];
 111
 112   NSString* ns_session_type =
 113       SanitizeShellArgument(base::mac::CFToNSCast(cf_session_type));
 114   if (!file_path || !ns_session_type) {
 115     return false;
 116   }
 117
 118   std::vector<std::string> argv;
 119   argv.push_back("/bin/bash");
 120   argv.push_back("--noprofile");
 121   argv.push_back("-c");
 122   std::string command = base::StringPrintf(
 123       "/bin/launchctl unload -S %s %s;"
 124       "/bin/launchctl load -S %s %s;",
 125       [ns_session_type UTF8String], file_path,
 126       [ns_session_type UTF8String], file_path);
 127   argv.push_back(command);
 128
 129   base::LaunchOptions options;
 130   options.new_process_group = true;
 131   return base::LaunchProcess(argv, options).IsValid();
 132 }
 133
 134 CFMutableDictionaryRef Launchd::CreatePlistFromFile(Domain domain,
 135                                                     Type type,
 136                                                     CFStringRef name) {
 137   base::mac::ScopedNSAutoreleasePool pool;
 138   NSURL* ns_url = GetPlistURL(domain, type, name);
 139   NSMutableDictionary* plist =
 140       [[NSMutableDictionary alloc] initWithContentsOfURL:ns_url];
 141   return base::mac::NSToCFCast(plist);
 142 }
 143
 144 bool Launchd::WritePlistToFile(Domain domain,
 145                                Type type,
 146                                CFStringRef name,
 147                                CFDictionaryRef dict) {
 148   base::mac::ScopedNSAutoreleasePool pool;
 149   NSURL* ns_url = GetPlistURL(domain, type, name);
 150   return [base::mac::CFToNSCast(dict) writeToURL:ns_url atomically:YES];
 151 }
 152
 153 bool Launchd::DeletePlist(Domain domain, Type type, CFStringRef name) {
 154   base::mac::ScopedNSAutoreleasePool pool;
 155   NSURL* ns_url = GetPlistURL(domain, type, name);
 156   NSError* err = nil;
 157   if (![[NSFileManager defaultManager] removeItemAtPath:[ns_url path]
 158                                                   error:&err]) {
 159     if ([err code] != NSFileNoSuchFileError) {
 160       DLOG(ERROR) << "DeletePlist: " << base::mac::NSToCFCast(err);
 161     }
 162     return false;
 163   }
 164   return true;
 165 }