chrome/utility/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7
   8 gypi_values = exec_script("//build/gypi_to_gn.py",
   9                           [ rebase_path("../chrome_utility.gypi") ],
  10                           "scope",
  11                           [ "../chrome_utility.gypi" ])
  12
  13 static_library("utility") {
  14   sources = rebase_path(gypi_values.chrome_utility_sources, ".", "..")
  15   defines = []
  16   configs += [ "//build/config:precompiled_headers" ]
  17
  18   public_deps = []
  19   deps = [
  20     "//base",
  21     "//components/safe_json:safe_json_parser_message_filter",
  22     "//components/search_engines",
  23     "//components/strings",
  24     "//components/url_fixer",
  25     "//content/public/common",
  26     "//content/public/utility",
  27     "//media",
  28     "//skia",
  29     "//third_party/libxml",
  30     "//chrome:resources",
  31     "//chrome:strings",
  32     "//chrome/common",
  33   ]
  34
  35   if (!is_android) {
  36     deps += [
  37       "//chrome/common:mojo_bindings",
  38       "//net:net_utility_services",
  39     ]
  40     sources +=
  41         rebase_path(gypi_values.chrome_utility_importer_sources, ".", "..")
  42   }
  43
  44   if (enable_extensions) {
  45     deps += [
  46       "//chrome/common/extensions/api",
  47       "//extensions/utility",
  48     ]
  49
  50     public_deps += [ "//chrome/common/extensions/api" ]
  51
  52     sources +=
  53         rebase_path(gypi_values.chrome_utility_extensions_sources, ".", "..")
  54     sources +=
  55         rebase_path(gypi_values.chrome_utility_shared_media_sources, ".", "..")
  56
  57     # Prevent wininet from loading in the renderer. http://crbug.com/460679
  58     if (is_win) {
  59       ldflags = [ "/DELAYLOAD:wininet.dll" ]
  60     }
  61
  62     if (is_win || is_mac) {
  63       sources +=
  64           rebase_path(gypi_values.chrome_utility_win_mac_media_gallery_sources,
  65                       ".",
  66                       "..")
  67       deps += [ "//components/wifi" ]
  68     } else {
  69       sources += [ "image_writer/image_writer_stub.cc" ]
  70     }
  71
  72     if (is_mac) {
  73       sources +=
  74           rebase_path(gypi_values.chrome_utility_mac_media_gallery_sources,
  75                       ".",
  76                       "..")
  77     }
  78
  79     # Linux should use system libexif
  80     if (!is_linux) {
  81       # TODO(thestig): Properly support building on Linux and ChromeOS.
  82       deps += [ "//third_party/libexif" ]
  83     }
  84   }
  85
  86   if (use_nss_certs) {
  87     sources += [
  88       "importer/nss_decryptor_system_nss.cc",
  89       "importer/nss_decryptor_system_nss.h",
  90     ]
  91     deps += [
  92       "//crypto",
  93       "//crypto:platform",
  94     ]
  95   }
  96
  97   if (!enable_print_preview) {
  98     sources -= [
  99       "printing_handler.cc",
 100       "printing_handler.h",
 101     ]
 102   }
 103
 104   if (!enable_mdns) {
 105     sources -= [
 106       "local_discovery/service_discovery_message_handler.cc",
 107       "local_discovery/service_discovery_message_handler.h",
 108     ]
 109   }
 110 }