content/test/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/crypto.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/ui.gni")
   9 import("//build/module_args/v8.gni")
  10 import("//testing/test.gni")
  11 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
  12
  13 content_tests_gypi_values =
  14     exec_script("//build/gypi_to_gn.py",
  15                 [
  16                   rebase_path("../content_tests.gypi"),
  17                   "--replace=<(SHARED_INTERMEDIATE_DIR)=$root_gen_dir",
  18                 ],
  19                 "scope",
  20                 [ "../content_tests.gypi" ])
  21
  22 # GYP version //content/content_tests.gypi:test_support_content
  23 source_set("test_support") {
  24   testonly = true
  25   configs += [ "//build/config:precompiled_headers" ]
  26   public_deps = [
  27     "//content/public/app:both",
  28     "//content/public/browser",
  29     "//content/public/common",
  30   ]
  31   deps = [
  32     "//cc/blink",
  33     "//net:test_support",
  34     "//skia",
  35     "//storage/common",
  36     "//testing/gmock",
  37     "//testing/gtest",
  38     "//ui/accessibility:ax_gen",
  39     "//ui/base",
  40     "//ui/base/ime",
  41     "//ui/base:test_support",
  42     "//ui/events:dom_keycode_converter",
  43     "//ui/events:events_base",
  44     "//ui/events:test_support",
  45     "//ui/events:gesture_detection",
  46     "//ui/gfx:test_support",
  47     "//ui/gl",
  48     "//ui/gl:test_support",
  49     "//ui/resources",
  50     "//url",
  51   ]
  52
  53   if (!is_ios) {
  54     sources =
  55         rebase_path(content_tests_gypi_values.test_support_content_sources,
  56                     ".",
  57                     "//content")
  58
  59     public_deps += [ "//third_party/WebKit/public:blink" ]
  60     deps += [
  61       ":content_test_mojo_bindings",
  62       "//components/scheduler:scheduler",
  63       "//components/scheduler:test_support",
  64       "//content/browser/speech/proto",
  65       "//content/public/child",
  66       "//content/gpu",
  67       "//content/public/plugin",
  68       "//content/public/renderer",
  69       "//content/public/utility",
  70       "//content/shell:pak",
  71       "//cc",
  72       "//cc:test_support",
  73       "//ipc/mojo",
  74       "//media",
  75       "//mojo/application/public/cpp:cpp_for_chromium",
  76       "//mojo/environment:chromium",
  77       "//ppapi/host",
  78       "//ppapi/proxy",
  79       "//ppapi/proxy:test_support",
  80       "//ppapi/shared_impl",
  81       "//ppapi/shared_impl:test_support",
  82       "//storage/browser",
  83       "//storage/common",
  84       "//ui/surface",
  85       "//v8",
  86     ]
  87
  88     if (enable_plugins) {
  89       deps += [ "//content/ppapi_plugin" ]
  90     }
  91
  92     if (enable_webrtc) {
  93       sources += [
  94         "../renderer/media/mock_data_channel_impl.cc",
  95         "../renderer/media/mock_data_channel_impl.h",
  96         "../renderer/media/mock_media_stream_dispatcher.cc",
  97         "../renderer/media/mock_media_stream_dispatcher.h",
  98         "../renderer/media/mock_peer_connection_impl.cc",
  99         "../renderer/media/mock_peer_connection_impl.h",
 100         "../renderer/media/mock_web_rtc_peer_connection_handler_client.cc",
 101         "../renderer/media/mock_web_rtc_peer_connection_handler_client.h",
 102         "../renderer/media/webrtc/mock_peer_connection_dependency_factory.cc",
 103         "../renderer/media/webrtc/mock_peer_connection_dependency_factory.h",
 104       ]
 105
 106       deps += [
 107         "//third_party/libjingle:libjingle_webrtc",
 108         "//third_party/libjingle:libpeerconnection",
 109         "//third_party/webrtc/modules/video_capture",
 110       ]
 111     }
 112     if (!enable_plugins) {
 113       sources -= [ "ppapi_unittest.cc" ]
 114     }
 115
 116     if (use_glib) {
 117       configs += [ "//build/config/linux:glib" ]
 118     }
 119
 120     if (use_aura) {
 121       deps += [
 122         "//ui/aura:test_support",
 123         "//ui/resources:ui_test_pak",
 124         "//ui/wm",
 125       ]
 126     }
 127
 128     if (use_aura || is_mac) {
 129       deps += [ "//ui/compositor" ]
 130     }
 131
 132     if (use_ozone) {
 133       deps += [ "//ui/ozone" ]
 134     }
 135
 136     if (is_win) {
 137       deps += [
 138         "//content:startup_helper_win",
 139         "//third_party/iaccessible2",
 140       ]
 141     }
 142
 143     if (!is_android && !is_ios) {
 144       sources += [
 145         "../browser/compositor/test/no_transport_image_transport_factory.cc",
 146         "../browser/compositor/test/no_transport_image_transport_factory.h",
 147       ]
 148       deps += [
 149         "//ui/compositor",
 150         "//third_party/libvpx",
 151       ]
 152     }
 153
 154     if (is_android) {
 155       deps += [
 156         "//content/shell/android:copy_content_shell_assets",
 157         "//ui/android",
 158         "//ui/shell_dialogs",
 159       ]
 160     }
 161
 162     if (is_win) {
 163       deps += [ "//sandbox" ]
 164     }
 165   } else {  # is_ios
 166     sources = [
 167       "public/test/content_test_suite_base.cc",
 168       "public/test/mock_notification_observer.cc",
 169       "public/test/mock_resource_context.cc",
 170       "public/test/test_browser_thread.cc",
 171       "public/test/test_content_client_initializer.cc",
 172       "public/test/test_notification_tracker.cc",
 173       "public/test/test_utils.cc",
 174       "public/test/unittest_test_suite.cc",
 175       "test/content_test_suite.cc",
 176       "test/test_content_browser_client.cc",
 177       "test/test_content_client.cc",
 178     ]
 179   }
 180   if (v8_use_external_startup_data) {
 181     deps += [ "//gin:gin" ]
 182   }
 183 }
 184
 185 source_set("browsertest_support") {
 186   testonly = true
 187
 188   sources = [
 189     "../public/test/content_browser_test.cc",
 190     "../public/test/content_browser_test.h",
 191     "../public/test/content_browser_test_utils.cc",
 192     "../public/test/content_browser_test_utils.h",
 193     "../public/test/content_browser_test_utils_mac.mm",
 194     "content_browser_test_utils_internal.cc",
 195     "content_browser_test_utils_internal.h",
 196     "content_test_launcher.cc",
 197   ]
 198
 199   deps = [
 200     "//content/shell:content_shell_lib",
 201     "//skia",
 202     "//testing/gtest",
 203     "//ui/accessibility:ax_gen",
 204   ]
 205
 206   if (is_android) {
 207     deps += [ "//content/public/app:both" ]
 208   } else {
 209     deps += [ "//content/public/browser" ]
 210   }
 211 }
 212
 213 mojom("content_test_mojo_bindings") {
 214   sources = [
 215     "../public/test/test_mojo_service.mojom",
 216   ]
 217 }
 218
 219 mojom("web_ui_test_mojo_bindings") {
 220   sources = [
 221     "data/web_ui_test_mojo_bindings.mojom",
 222   ]
 223 }
 224
 225 if (!is_ios) {
 226   # GYP version //content/content_tests.gypi:layouttest_support_content
 227   static_library("layouttest_support") {
 228     testonly = true
 229     sources = rebase_path(
 230             content_tests_gypi_values.layouttest_support_content_sources,
 231             ".",
 232             "//content")
 233
 234     deps = [
 235       ":test_support",
 236       "//cc",
 237       "//cc/blink",
 238       "//components/test_runner:test_runner",
 239       "//content/public/common",
 240       "//skia",
 241       "//v8",
 242       "//ui/accessibility:ax_gen",
 243     ]
 244
 245     if (is_android) {
 246       deps += [ ":jni" ]
 247     }
 248   }
 249
 250   if (is_android) {
 251     import("//build/config/android/rules.gni")
 252
 253     generate_jni("jni") {
 254       sources = [
 255         "../public/test/android/javatests/src/org/chromium/content/browser/test/NestedSystemMessageHandler.java",
 256       ]
 257       jni_package = "content/public/test"
 258     }
 259   }
 260 }  # !is_ios
 261
 262 # TODO(GYP) enable content_browsertests on Mac when it links.
 263 if (!is_mac) {
 264   # TODO(GYP): Delete this after we've converted everything to GN.
 265   # The _run targets exist only for compatibility w/ GYP.
 266   group("content_browsertests_run") {
 267     testonly = true
 268     deps = [
 269       ":content_browsertests",
 270     ]
 271   }
 272
 273   test("content_browsertests") {
 274     sources =
 275         rebase_path(content_tests_gypi_values.content_browsertests_sources,
 276                     ".",
 277                     "//content")
 278
 279     if (is_android || is_linux || is_mac || is_win) {
 280       data = [
 281         "data/",
 282         "//net/data/",
 283         "//media/test/data/",
 284       ]
 285
 286       if (is_android) {
 287         data += [ "$root_out_dir/content_shell_assets/content_shell.pak" ]
 288       } else {
 289         data += [
 290           "$root_out_dir/content_shell.pak",
 291           "//net/tools/testserver/",
 292           "//ppapi/tests/test_case.html",
 293           "//ppapi/tests/test_page.css",
 294           "//third_party/pyftpdlib/",
 295           "//third_party/pywebsocket/",
 296           "//third_party/tlslite/",
 297         ]
 298
 299         if (is_mac) {
 300           data += [
 301             "$root_out_dir/Content Shell.app/",
 302             "$root_out_dir/plugins/test_netscape_plugin.plugin/",
 303           ]
 304         }
 305         if (is_win) {
 306           data += [ "$root_out_dir/plugins/np_test_netscape_plugin.dll" ]
 307         }
 308       }
 309     }
 310
 311     defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
 312
 313     configs += [
 314       "//build/config:precompiled_headers",
 315       "//build/config/compiler:no_size_t_to_int_warning",
 316     ]
 317
 318     deps = [
 319       ":browsertest_support",
 320       ":web_ui_test_mojo_bindings",
 321       "//base/allocator",
 322       "//base/test:test_support",
 323       "//content/browser/background_sync:background_sync_proto",
 324       "//content/common:mojo_bindings",
 325       "//content/gpu",
 326       "//content/public/common",
 327       "//content/public/plugin",
 328       "//content/public/renderer",
 329       "//content:resources",
 330       "//content/shell:content_shell_lib",
 331       "//content/shell:pak",
 332       "//content/test:test_support",
 333       "//device/battery",
 334       "//device/battery:mojo_bindings",
 335       "//gin",
 336       "//gpu",
 337       "//ipc:test_support",
 338       "//media:test_support",
 339       "//media/audio:test_support",
 340       "//media/base:test_support",
 341       "//media:shared_memory_support",
 342       "//mojo/application/public/cpp:cpp_for_chromium",
 343       "//mojo/environment:chromium",
 344       "//mojo/test:test_support",
 345       "//net:test_support",
 346       "//ppapi/host",
 347       "//ppapi/proxy",
 348       "//ppapi/proxy:ipc",
 349       "//ppapi/shared_impl",
 350       "//third_party/mojo/src/mojo/edk/system",
 351       "//third_party/mojo/src/mojo/edk/test:test_support",
 352       "//third_party/mojo/src/mojo/public/cpp/bindings",
 353       "//third_party/mojo/src/mojo/public/js",
 354       "//testing/gmock",
 355       "//testing/gtest",
 356       "//third_party/WebKit/public:blink",
 357       "//third_party/leveldatabase",
 358       "//third_party/mesa:osmesa",
 359       "//third_party/zlib",
 360       "//ui/accessibility",
 361       "//ui/accessibility:ax_gen",
 362       "//ui/base",
 363       "//ui/base/ime",
 364       "//ui/gfx",
 365       "//ui/gfx/geometry",
 366       "//ui/gl",
 367       "//ui/gl:test_support",
 368       "//ui/resources",
 369       "//ui/shell_dialogs",
 370       "//ui/snapshot",
 371     ]
 372
 373     data_deps = [
 374       "//ppapi:ppapi_tests",
 375       "//third_party/mesa:osmesa",
 376     ]
 377
 378     if (!is_chromeos) {
 379       sources -=
 380           [ "../browser/web_contents/touch_editable_impl_aura_browsertest.cc" ]
 381     }
 382
 383     if (is_win) {
 384       sources += rebase_path(
 385               content_tests_gypi_values.content_browsertests_win_sources,
 386               ".",
 387               "//content")
 388
 389       deps += [
 390         "//content/app/strings",
 391         "//net:net_resources",
 392         "//third_party/WebKit/public:resources",
 393         "//third_party/iaccessible2",
 394         "//third_party/isimpledom",
 395       ]
 396
 397       libs = [ "oleacc.lib" ]
 398     }
 399
 400     if (is_linux) {
 401       sources -=
 402           [ "../browser/accessibility/dump_accessibility_tree_browsertest.cc" ]
 403     }
 404
 405     if (is_android) {
 406       sources += rebase_path(
 407               content_tests_gypi_values.content_browsertests_android_sources,
 408               ".",
 409               "//content")
 410       sources -=
 411           [ "../browser/battery_status/battery_monitor_impl_browsertest.cc" ]
 412       deps += [
 413         "//content/shell/android:content_shell_jni_headers",
 414         "//content/shell:content_shell_lib",
 415         "//testing/android/native_test:native_test_support",
 416       ]
 417
 418       use_launcher = false
 419     }
 420
 421     if (is_mac) {
 422       sources += [ "../renderer/external_popup_menu_browsertest.cc" ]
 423       deps += [
 424         # Needed for Content Shell.app's Helper.
 425         #"//content/shell:content_shell",  #TODO(GYP) enable for mac
 426       ]
 427     }
 428
 429     if (use_aura && !is_win) {
 430       deps += [ "//ui/events:test_support" ]
 431     }
 432
 433     if (!use_aura && !is_mac) {
 434       sources -=
 435           [ "../browser/compositor/image_transport_factory_browsertest.cc" ]
 436     }
 437
 438     if (enable_webrtc) {
 439       sources += rebase_path(
 440               content_tests_gypi_values.content_browsertests_webrtc_sources,
 441               ".",
 442               "//content")
 443       deps += [ "//testing/perf" ]
 444     }
 445
 446     if (enable_plugins) {
 447       sources += rebase_path(
 448               content_tests_gypi_values.content_browsertests_plugins_sources,
 449               ".",
 450               "//content")
 451       data_deps += [ "//ppapi:ppapi_tests" ]
 452     }
 453
 454     if (enable_web_speech) {
 455       sources += rebase_path(
 456               content_tests_gypi_values.content_browsertests_speech_sources,
 457               ".",
 458               "//content")
 459     }
 460
 461     if (!is_chrome_branded) {
 462       sources += rebase_path(
 463               content_tests_gypi_values.content_browsertests_unofficial_build_sources,
 464               ".",
 465               "//content")
 466     }
 467
 468     if (!use_aura) {
 469       sources -=
 470           [ "../browser/web_contents/web_contents_view_aura_browsertest.cc" ]
 471     }
 472   }
 473 }
 474
 475 # TODO(GYP): Delete this after we've converted everything to GN.
 476 # The _run targets exist only for compatibility w/ GYP.
 477 group("content_unittests_run") {
 478   testonly = true
 479   deps = [
 480     ":content_unittests",
 481   ]
 482 }
 483
 484 test("content_unittests") {
 485   sources = rebase_path(content_tests_gypi_values.content_unittests_sources,
 486                         ".",
 487                         "//content")
 488
 489   if (is_android || is_linux || is_mac || is_win) {
 490     data = [
 491       "data/",
 492       "//net/data/ssl/certificates/",
 493       "//media/test/data/",
 494     ]
 495
 496     if (is_android) {
 497       data += [ "$root_out_dir/content_shell_assets/content_shell.pak" ]
 498     } else {
 499       data += [ "$root_out_dir/content_shell.pak" ]
 500     }
 501   }
 502
 503   configs += [ "//build/config:precompiled_headers" ]
 504
 505   deps = [
 506     ":test_support",
 507     "//base/allocator",
 508     "//base/test:test_support",
 509     "//content/browser/background_sync:background_sync_proto",
 510     "//content/browser/notifications:notification_proto",
 511     "//content/browser/service_worker:service_worker_proto",
 512     "//content/browser/speech/proto",
 513     "//content/common:mojo_bindings",
 514     "//content/public/browser",
 515     "//content/public/common",
 516     "//content/public/common:mojo_bindings",
 517     "//crypto",
 518     "//device/battery",
 519     "//device/battery:mojo_bindings",
 520     "//mojo/environment:chromium",
 521     "//net:extras",
 522     "//net:test_support",
 523     "//skia",
 524     "//sql",
 525     "//sql:test_support",
 526     "//testing/gmock",
 527     "//testing/gtest",
 528     "//third_party/mojo/src/mojo/edk/test:test_support",
 529     "//third_party/mojo/src/mojo/public/cpp/bindings",
 530     "//third_party/re2",
 531     "//ui/accessibility",
 532     "//ui/base",
 533     "//ui/events/blink",
 534     "//ui/gfx",
 535     "//ui/gfx/geometry",
 536     "//ui/gfx/ipc",
 537   ]
 538
 539   if (!is_ios) {
 540     deps += [
 541       "//base/third_party/dynamic_annotations",
 542       "//cc",
 543       "//cc:test_support",
 544       "//cc/surfaces",
 545       "//content:resources",
 546       "//content/gpu",
 547       "//content/public/browser",
 548       "//content/public/child",
 549       "//content/public/plugin",
 550       "//content/public/renderer",
 551       "//gin",
 552       "//gpu",
 553       "//gpu:test_support",
 554       "//ipc:test_support",
 555       "//media:test_support",
 556       "//media:shared_memory_support",
 557       "//media/audio:test_support",
 558       "//media/base:test_support",
 559       "//media/midi:midi",
 560       "//storage/browser",
 561       "//storage/common",
 562       "//third_party/WebKit/public:blink",
 563       "//third_party/icu",
 564       "//third_party/leveldatabase",
 565       "//third_party/libjingle",
 566       "//ui/compositor:test_support",
 567       "//ui/gl",
 568       "//ui/gl:test_support",
 569     ]
 570   }
 571
 572   data_deps = [ "//third_party/mesa:osmesa" ]
 573
 574   if (!is_win) {
 575     sources += [ "../browser/file_descriptor_info_impl_unittest.cc" ]
 576   }
 577
 578   if (enable_plugins) {
 579     sources +=
 580         rebase_path(content_tests_gypi_values.content_unittests_plugins_sources,
 581                     ".",
 582                     "//content")
 583   }
 584
 585   if (enable_webrtc) {
 586     sources +=
 587         rebase_path(content_tests_gypi_values.content_unittests_webrtc_sources,
 588                     ".",
 589                     "//content")
 590     deps += [
 591       "//third_party/libjingle:libjingle_webrtc",
 592       "//third_party/libjingle:libpeerconnection",
 593       "//third_party/webrtc/modules/video_capture",
 594     ]
 595
 596     if (is_linux || is_mac || is_win) {
 597       sources +=
 598           [ "../browser/media/capture/desktop_capture_device_unittest.cc" ]
 599       deps += [ "//third_party/webrtc/modules/desktop_capture" ]
 600     }
 601
 602     if (is_chromeos) {
 603       sources +=
 604           [ "../browser/media/capture/desktop_capture_device_aura_unittest.cc" ]
 605     }
 606   } else {
 607     if (enable_plugins) {
 608       # This file is added only when plugins are enabled, but we don't want it
 609       # unless webrtc is also enabled.
 610       sources -=
 611           [ "../renderer/media/webrtc/video_destination_handler_unittest.cc" ]
 612     }
 613   }
 614
 615   if (enable_web_speech) {
 616     sources +=
 617         rebase_path(content_tests_gypi_values.content_unittests_speech_sources,
 618                     ".",
 619                     "//content")
 620   }
 621
 622   if (is_linux) {
 623     if (use_dbus) {
 624       deps += [ "//dbus:test_support" ]
 625     } else {
 626       sources -=
 627           [ "../browser/geolocation/wifi_data_provider_linux_unittest.cc" ]
 628     }
 629   }
 630   if (is_win) {
 631     deps += [ "//third_party/iaccessible2" ]
 632   }
 633   if (is_mac) {
 634     # These flags are needed to run the test on Mac.
 635     # Search for comments about "xcode_settings" in chrome_tests.gypi.
 636     ldflags = [ "-Wl,-ObjC" ]
 637
 638     deps += [ "//third_party/ocmock" ]
 639   }
 640   if (is_chromeos) {
 641     sources -= [ "../browser/geolocation/wifi_data_provider_linux_unittest.cc" ]
 642     deps += [ "//chromeos" ]
 643   }
 644   if (is_android) {
 645     sources +=
 646         rebase_path(content_tests_gypi_values.content_unittests_android_sources,
 647                     ".",
 648                     "//content")
 649     sources -= [
 650       "../browser/geolocation/network_location_provider_unittest.cc",
 651       "../browser/geolocation/wifi_data_provider_common_unittest.cc",
 652       "../browser/renderer_host/begin_frame_observer_proxy_unittest.cc",
 653       "../browser/webui/url_data_manager_backend_unittest.cc",
 654     ]
 655     deps += [ "//testing/android/native_test:native_test_native_code" ]
 656   }
 657   if (!is_android && !is_ios) {
 658     deps += [ "//third_party/libvpx" ]
 659   }
 660
 661   if (use_aura) {
 662     deps += [
 663       "//ui/aura",
 664       "//ui/aura_extra",
 665       "//ui/wm",
 666     ]
 667   } else {
 668     sources -= [
 669       "../browser/renderer_host/render_widget_host_view_aura_unittest.cc",
 670       "../browser/renderer_host/web_input_event_aura_unittest.cc",
 671       "../browser/web_contents/aura/overscroll_navigation_overlay_unittest.cc",
 672       "../browser/web_contents/aura/overscroll_window_animation_unittest.cc",
 673       "../browser/web_contents/aura/overscroll_window_delegate_unittest.cc",
 674       "../browser/web_contents/web_contents_view_aura_unittest.cc",
 675     ]
 676   }
 677   if (use_aura || toolkit_views) {
 678     deps += [ "//ui/events:test_support" ]
 679   }
 680   if (!use_aura && !is_mac) {
 681     sources -= [
 682       "../browser/compositor/buffer_queue_unittest.cc",
 683       "../browser/compositor/reflector_impl_unittest.cc",
 684       "../browser/compositor/software_browser_compositor_output_surface_unittest.cc",
 685     ]
 686   }
 687
 688   if (!is_win && !is_mac) {
 689     sources -= [ "../common/plugin_list_unittest.cc" ]
 690   }
 691
 692   if (use_ozone) {
 693     deps += [
 694       "//ui/ozone",
 695       "//ui/ozone:ozone_base",
 696     ]
 697   } else {
 698     sources -=
 699         [ "../browser/compositor/software_output_device_ozone_unittest.cc" ]
 700   }
 701
 702   if (is_mac && use_openssl) {
 703     deps += [ "//third_party/boringssl" ]
 704   }
 705 }
 706
 707 if (!is_mac) {  # TODO(GYP) enable on Mac once it links.
 708   test("content_perftests") {
 709     sources = [
 710       "../browser/renderer_host/input/input_router_impl_perftest.cc",
 711       "../common/cc_messages_perftest.cc",
 712       "../test/run_all_perftests.cc",
 713     ]
 714     deps = [
 715       "//base/allocator",
 716       "//base/test:test_support",
 717       "//content/public/browser",
 718       "//content/public/common",
 719       "//content/test:test_support",
 720       "//cc",
 721       "//skia",
 722       "//testing/gtest",
 723       "//testing/perf",
 724       "//ui/gfx",
 725       "//ui/gfx/geometry",
 726     ]
 727
 728     if (is_android) {
 729       deps += [ "//testing/android/native_test:native_test_native_code" ]
 730     }
 731   }
 732
 733   test("content_gl_tests") {
 734     sources = [
 735       "../common/gpu/client/gl_helper_unittest.cc",
 736       "../common/gpu/client/gpu_in_process_context_tests.cc",
 737     ]
 738
 739     deps = [
 740       ":test_support",
 741       "//base/allocator",
 742       "//base/test:test_support",
 743       "//content/public/common",
 744       "//gpu/blink",
 745       "//gpu/command_buffer/common",
 746       "//testing/gtest",
 747       "//third_party/WebKit/public:blink",
 748       "//ui/base",
 749       "//ui/gfx",
 750       "//ui/gfx:test_support",
 751       "//ui/gfx/geometry",
 752       "//ui/gl",
 753       "//ui/gl:test_support",
 754       "//v8",
 755     ]
 756
 757     if (is_android) {
 758       deps += [ "//testing/android/native_test:native_test_native_code" ]
 759     } else {
 760       data_deps = [
 761         "//third_party/ffmpeg",
 762         "//third_party/mesa:osmesa",
 763       ]
 764     }
 765   }
 766
 767   test("content_gl_benchmark") {
 768     sources = [
 769       "../common/gpu/client/gl_helper_benchmark.cc",
 770     ]
 771
 772     deps = [
 773       ":test_support",
 774       "//base/allocator",
 775       "//base/test:test_support",
 776       "//content/public/common",
 777       "//gpu/blink",
 778       "//testing/gtest",
 779       "//third_party/WebKit/public:blink",
 780       "//ui/base",
 781       "//ui/gfx",
 782       "//ui/gfx/geometry",
 783       "//ui/gl",
 784       "//ui/gl:test_support",
 785     ]
 786   }
 787 }