device/usb/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(!is_android && !is_ios)
   6
   7 source_ids = "//third_party/usb_ids/usb.ids"
   8 generated_ids = "$target_gen_dir/usb_ids_gen.cc"
   9
  10 source_set("usb") {
  11   sources = [
  12     "usb_context.cc",
  13     "usb_context.h",
  14     "usb_descriptors.cc",
  15     "usb_descriptors.h",
  16     "usb_device.cc",
  17     "usb_device.h",
  18     "usb_device_filter.cc",
  19     "usb_device_filter.h",
  20     "usb_device_handle.h",
  21     "usb_device_handle_impl.cc",
  22     "usb_device_handle_impl.h",
  23     "usb_device_impl.cc",
  24     "usb_device_impl.h",
  25     "usb_error.cc",
  26     "usb_error.h",
  27     "usb_ids.cc",
  28     "usb_ids.h",
  29     "usb_service.cc",
  30     "usb_service.h",
  31     "usb_service_impl.cc",
  32     "usb_service_impl.h",
  33     "webusb_descriptors.cc",
  34     "webusb_descriptors.h",
  35     generated_ids,
  36   ]
  37
  38   deps = [
  39     ":usb_device_ids",
  40     "//base",
  41     "//base/third_party/dynamic_annotations",
  42     "//components/device_event_log",
  43     "//device/core",
  44     "//net",
  45     "//third_party/libusb",
  46   ]
  47
  48   if (is_linux) {
  49     deps += [ "//device/udev_linux" ]
  50   }
  51   if (is_chromeos) {
  52     deps += [
  53       "//chromeos",
  54       "//dbus",
  55     ]
  56   }
  57 }
  58
  59 source_set("mocks") {
  60   testonly = true
  61
  62   sources = [
  63     "mock_usb_device.cc",
  64     "mock_usb_device.h",
  65     "mock_usb_device_handle.cc",
  66     "mock_usb_device_handle.h",
  67     "mock_usb_service.cc",
  68     "mock_usb_service.h",
  69   ]
  70
  71   deps = [
  72     "//base",
  73     "//testing/gmock",
  74     ":usb",
  75   ]
  76 }
  77
  78 action("usb_device_ids") {
  79   script = "//device/usb/tools/usb_ids.py"
  80   inputs = [
  81     source_ids,
  82   ]
  83   outputs = [
  84     generated_ids,
  85   ]
  86   args = [
  87     "-i",
  88     rebase_path(source_ids, root_build_dir),
  89     "-o",
  90     rebase_path(generated_ids, root_build_dir),
  91   ]
  92
  93   # Only the device_usb target can depend on us.
  94   visibility = [ ":usb" ]
  95 }