base/test/test_support_ios.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import <UIKit/UIKit.h>
   6
   7 #include "base/debug/debugger.h"
   8 #include "base/logging.h"
   9 #include "base/mac/scoped_nsautorelease_pool.h"
  10 #include "base/mac/scoped_nsobject.h"
  11 #include "base/message_loop/message_loop.h"
  12 #include "base/message_loop/message_pump_default.h"
  13 #include "base/test/test_suite.h"
  14
  15 // Springboard will kill any iOS app that fails to check in after launch within
  16 // a given time. Starting a UIApplication before invoking TestSuite::Run
  17 // prevents this from happening.
  18
  19 // InitIOSRunHook saves the TestSuite and argc/argv, then invoking
  20 // RunTestsFromIOSApp calls UIApplicationMain(), providing an application
  21 // delegate class: ChromeUnitTestDelegate. The delegate implements
  22 // application:didFinishLaunchingWithOptions: to invoke the TestSuite's Run
  23 // method.
  24
  25 // Since the executable isn't likely to be a real iOS UI, the delegate puts up a
  26 // window displaying the app name. If a bunch of apps using MainHook are being
  27 // run in a row, this provides an indication of which one is currently running.
  28
  29 static base::TestSuite* g_test_suite = NULL;
  30 static int g_argc;
  31 static char** g_argv;
  32
  33 @interface UIApplication (Testing)
  34 - (void) _terminateWithStatus:(int)status;
  35 @end
  36
  37 #if TARGET_IPHONE_SIMULATOR
  38 // Xcode 6 introduced behavior in the iOS Simulator where the software
  39 // keyboard does not appear if a hardware keyboard is connected. The following
  40 // declaration allows this behavior to be overriden when the app starts up.
  41 @interface UIKeyboardImpl
  42 + (instancetype)sharedInstance;
  43 - (void)setAutomaticMinimizationEnabled:(BOOL)enabled;
  44 - (void)setSoftwareKeyboardShownByTouch:(BOOL)enabled;
  45 @end
  46 #endif  // TARGET_IPHONE_SIMULATOR
  47
  48 @interface ChromeUnitTestDelegate : NSObject {
  49  @private
  50   base::scoped_nsobject<UIWindow> window_;
  51 }
  52 - (void)runTests;
  53 @end
  54
  55 @implementation ChromeUnitTestDelegate
  56
  57 - (BOOL)application:(UIApplication *)application
  58     didFinishLaunchingWithOptions:(NSDictionary *)launchOptions {
  59
  60 #if TARGET_IPHONE_SIMULATOR
  61   // Xcode 6 introduced behavior in the iOS Simulator where the software
  62   // keyboard does not appear if a hardware keyboard is connected. The following
  63   // calls override this behavior by ensuring that the software keyboard is
  64   // always shown.
  65   [[UIKeyboardImpl sharedInstance] setAutomaticMinimizationEnabled:NO];
  66   [[UIKeyboardImpl sharedInstance] setSoftwareKeyboardShownByTouch:YES];
  67 #endif  // TARGET_IPHONE_SIMULATOR
  68
  69   CGRect bounds = [[UIScreen mainScreen] bounds];
  70
  71   // Yes, this is leaked, it's just to make what's running visible.
  72   window_.reset([[UIWindow alloc] initWithFrame:bounds]);
  73   [window_ setBackgroundColor:[UIColor whiteColor]];
  74   [window_ makeKeyAndVisible];
  75
  76   // Add a label with the app name.
  77   UILabel* label = [[[UILabel alloc] initWithFrame:bounds] autorelease];
  78   label.text = [[NSProcessInfo processInfo] processName];
  79   label.textAlignment = NSTextAlignmentCenter;
  80   [window_ addSubview:label];
  81
  82   if ([self shouldRedirectOutputToFile])
  83     [self redirectOutput];
  84
  85   // Queue up the test run.
  86   [self performSelector:@selector(runTests)
  87              withObject:nil
  88              afterDelay:0.1];
  89   return YES;
  90 }
  91
  92 // Returns true if the gtest output should be redirected to a file, then sent
  93 // to NSLog when compleete. This redirection is used because gtest only writes
  94 // output to stdout, but results must be written to NSLog in order to show up in
  95 // the device log that is retrieved from the device by the host.
  96 - (BOOL)shouldRedirectOutputToFile {
  97 #if !TARGET_IPHONE_SIMULATOR
  98   return !base::debug::BeingDebugged();
  99 #endif  // TARGET_IPHONE_SIMULATOR
 100   return NO;
 101 }
 102
 103 // Returns the path to the directory to store gtest output files.
 104 - (NSString*)outputPath {
 105   NSArray* searchPath =
 106       NSSearchPathForDirectoriesInDomains(NSDocumentDirectory,
 107                                           NSUserDomainMask,
 108                                           YES);
 109   CHECK([searchPath count] > 0) << "Failed to get the Documents folder";
 110   return [searchPath objectAtIndex:0];
 111 }
 112
 113 // Returns the path to file that stdout is redirected to.
 114 - (NSString*)stdoutPath {
 115   return [[self outputPath] stringByAppendingPathComponent:@"stdout.log"];
 116 }
 117
 118 // Returns the path to file that stderr is redirected to.
 119 - (NSString*)stderrPath {
 120   return [[self outputPath] stringByAppendingPathComponent:@"stderr.log"];
 121 }
 122
 123 // Redirects stdout and stderr to files in the Documents folder in the app's
 124 // sandbox.
 125 - (void)redirectOutput {
 126   freopen([[self stdoutPath] UTF8String], "w+", stdout);
 127   freopen([[self stderrPath] UTF8String], "w+", stderr);
 128 }
 129
 130 // Reads the redirected gtest output from a file and writes it to NSLog.
 131 - (void)writeOutputToNSLog {
 132   // Close the redirected stdout and stderr files so that the content written to
 133   // NSLog doesn't end up in these files.
 134   fclose(stdout);
 135   fclose(stderr);
 136   for (NSString* path in @[ [self stdoutPath], [self stderrPath]]) {
 137     NSString* content = [NSString stringWithContentsOfFile:path
 138                                                   encoding:NSUTF8StringEncoding
 139                                                      error:NULL];
 140     NSArray* lines = [content componentsSeparatedByCharactersInSet:
 141         [NSCharacterSet newlineCharacterSet]];
 142
 143     NSLog(@"Writing contents of %@ to NSLog", path);
 144     for (NSString* line in lines) {
 145       NSLog(@"%@", line);
 146     }
 147   }
 148 }
 149
 150 - (void)runTests {
 151   int exitStatus = g_test_suite->Run();
 152
 153   if ([self shouldRedirectOutputToFile])
 154     [self writeOutputToNSLog];
 155
 156   // If a test app is too fast, it will exit before Instruments has has a
 157   // a chance to initialize and no test results will be seen.
 158   // TODO(ios): crbug.com/137010 Figure out how much time is actually needed,
 159   // and sleep only to make sure that much time has elapsed since launch.
 160   [NSThread sleepUntilDate:[NSDate dateWithTimeIntervalSinceNow:2.0]];
 161   window_.reset();
 162
 163   // Use the hidden selector to try and cleanly take down the app (otherwise
 164   // things can think the app crashed even on a zero exit status).
 165   UIApplication* application = [UIApplication sharedApplication];
 166   [application _terminateWithStatus:exitStatus];
 167
 168   exit(exitStatus);
 169 }
 170
 171 @end
 172
 173 namespace {
 174
 175 scoped_ptr<base::MessagePump> CreateMessagePumpForUIForTests() {
 176   // A default MessagePump will do quite nicely in tests.
 177   return scoped_ptr<base::MessagePump>(new base::MessagePumpDefault());
 178 }
 179
 180 }  // namespace
 181
 182 namespace base {
 183
 184 void InitIOSTestMessageLoop() {
 185   MessageLoop::InitMessagePumpForUIFactory(&CreateMessagePumpForUIForTests);
 186 }
 187
 188 void InitIOSRunHook(TestSuite* suite, int argc, char* argv[]) {
 189   g_test_suite = suite;
 190   g_argc = argc;
 191   g_argv = argv;
 192 }
 193
 194 void RunTestsFromIOSApp() {
 195   // When TestSuite::Run is invoked it calls RunTestsFromIOSApp(). On the first
 196   // invocation, this method fires up an iOS app via UIApplicationMain. Since
 197   // UIApplicationMain does not return until the app exits, control does not
 198   // return to the initial TestSuite::Run invocation, so the app invokes
 199   // TestSuite::Run a second time and since |ran_hook| is true at this point,
 200   // this method is a no-op and control returns to TestSuite:Run so that test
 201   // are executed. Once the app exits, RunTestsFromIOSApp calls exit() so that
 202   // control is not returned to the initial invocation of TestSuite::Run.
 203   static bool ran_hook = false;
 204   if (!ran_hook) {
 205     ran_hook = true;
 206     mac::ScopedNSAutoreleasePool pool;
 207     int exit_status = UIApplicationMain(g_argc, g_argv, nil,
 208                                         @"ChromeUnitTestDelegate");
 209     exit(exit_status);
 210   }
 211 }
 212
 213 }  // namespace base