chrome/browser/renderer_host/chrome_render_widget_host_view_mac_delegate.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/renderer_host/chrome_render_widget_host_view_mac_delegate.h"
   6
   7 #include <cmath>
   8
   9 #include "base/prefs/pref_service.h"
  10 #include "base/strings/sys_string_conversions.h"
  11 #include "chrome/browser/devtools/devtools_window.h"
  12 #include "chrome/browser/profiles/profile.h"
  13 #import "chrome/browser/renderer_host/chrome_render_widget_host_view_mac_history_swiper.h"
  14 #include "chrome/browser/spellchecker/spellcheck_platform_mac.h"
  15 #include "chrome/browser/ui/browser.h"
  16 #include "chrome/browser/ui/browser_commands.h"
  17 #include "chrome/browser/ui/browser_finder.h"
  18 #import "chrome/browser/ui/cocoa/browser_window_controller.h"
  19 #import "chrome/browser/ui/cocoa/view_id_util.h"
  20 #include "chrome/common/pref_names.h"
  21 #include "chrome/common/spellcheck_messages.h"
  22 #include "chrome/common/url_constants.h"
  23 #include "content/public/browser/render_process_host.h"
  24 #include "content/public/browser/render_view_host.h"
  25 #include "content/public/browser/render_widget_host.h"
  26 #include "content/public/browser/render_widget_host_view.h"
  27 #include "content/public/browser/web_contents.h"
  28 #include "content/public/browser/web_contents_observer.h"
  29
  30 using content::RenderViewHost;
  31
  32 @interface ChromeRenderWidgetHostViewMacDelegate () <HistorySwiperDelegate>
  33 - (void)spellCheckEnabled:(BOOL)enabled checked:(BOOL)checked;
  34 @end
  35
  36 namespace ChromeRenderWidgetHostViewMacDelegateInternal {
  37
  38 // Filters the message sent by the renderer to know if spellchecking is enabled
  39 // or not for the currently focused element.
  40 class SpellCheckObserver : public content::WebContentsObserver {
  41  public:
  42   SpellCheckObserver(
  43       RenderViewHost* host,
  44       ChromeRenderWidgetHostViewMacDelegate* view_delegate)
  45       : content::WebContentsObserver(
  46             content::WebContents::FromRenderViewHost(host)),
  47         view_delegate_(view_delegate) {
  48   }
  49
  50   virtual ~SpellCheckObserver() {
  51   }
  52
  53  private:
  54   virtual bool OnMessageReceived(const IPC::Message& message) OVERRIDE {
  55     bool handled = true;
  56     IPC_BEGIN_MESSAGE_MAP(SpellCheckObserver, message)
  57       IPC_MESSAGE_HANDLER(SpellCheckHostMsg_ToggleSpellCheck,
  58                           OnToggleSpellCheck)
  59       IPC_MESSAGE_UNHANDLED(handled = false)
  60     IPC_END_MESSAGE_MAP()
  61     return handled;
  62   }
  63
  64   void OnToggleSpellCheck(bool enabled, bool checked) {
  65     [view_delegate_ spellCheckEnabled:enabled checked:checked];
  66   }
  67
  68   ChromeRenderWidgetHostViewMacDelegate* view_delegate_;
  69 };
  70
  71 }  // namespace ChromeRenderWidgetHostViewMacDelegateInternal
  72
  73 @implementation ChromeRenderWidgetHostViewMacDelegate
  74
  75 - (id)initWithRenderWidgetHost:(content::RenderWidgetHost*)renderWidgetHost {
  76   self = [super init];
  77   if (self) {
  78     renderWidgetHost_ = renderWidgetHost;
  79     NSView* nativeView = renderWidgetHost_->GetView()->GetNativeView();
  80     view_id_util::SetID(nativeView, VIEW_ID_TAB_CONTAINER);
  81
  82     if (renderWidgetHost_->IsRenderView()) {
  83       spellingObserver_.reset(
  84           new ChromeRenderWidgetHostViewMacDelegateInternal::SpellCheckObserver(
  85               RenderViewHost::From(renderWidgetHost_), self));
  86     }
  87
  88     historySwiper_.reset([[HistorySwiper alloc] initWithDelegate:self]);
  89   }
  90   return self;
  91 }
  92
  93 - (void)dealloc {
  94   [historySwiper_ setDelegate:nil];
  95   [super dealloc];
  96 }
  97
  98 - (void)viewGone:(NSView*)view {
  99   view_id_util::UnsetID(view);
 100 }
 101
 102 // Handle an event. All incoming key and mouse events flow through this
 103 // delegate method if implemented. Return YES if the event is fully handled, or
 104 // NO if normal processing should take place.
 105 - (BOOL)handleEvent:(NSEvent*)event {
 106   return [historySwiper_ handleEvent:event];
 107 }
 108
 109 // Notification that a wheel event was unhandled.
 110 - (void)gotUnhandledWheelEvent {
 111   [historySwiper_ gotUnhandledWheelEvent];
 112 }
 113
 114 // Notification of scroll offset pinning.
 115 - (void)scrollOffsetPinnedToLeft:(BOOL)left toRight:(BOOL)right {
 116   [historySwiper_ scrollOffsetPinnedToLeft:left toRight:right];
 117 }
 118
 119 // Notification of whether the view has a horizontal scrollbar.
 120 - (void)setHasHorizontalScrollbar:(BOOL)has_horizontal_scrollbar {
 121   [historySwiper_ setHasHorizontalScrollbar:has_horizontal_scrollbar];
 122 }
 123
 124 // NSWindow events.
 125
 126 - (void)beginGestureWithEvent:(NSEvent*)event {
 127   [historySwiper_ beginGestureWithEvent:event];
 128 }
 129
 130 - (void)endGestureWithEvent:(NSEvent*)event {
 131   [historySwiper_ endGestureWithEvent:event];
 132 }
 133
 134 // This is a low level API which provides touches associated with an event.
 135 // It is used in conjunction with gestures to determine finger placement
 136 // on the trackpad.
 137 - (void)touchesMovedWithEvent:(NSEvent*)event {
 138   [historySwiper_ touchesMovedWithEvent:event];
 139 }
 140
 141 - (void)touchesBeganWithEvent:(NSEvent*)event {
 142   [historySwiper_ touchesBeganWithEvent:event];
 143 }
 144
 145 - (void)touchesCancelledWithEvent:(NSEvent*)event {
 146   [historySwiper_ touchesCancelledWithEvent:event];
 147 }
 148
 149 - (void)touchesEndedWithEvent:(NSEvent*)event {
 150   [historySwiper_ touchesEndedWithEvent:event];
 151 }
 152
 153 // HistorySwiperDelegate methods
 154
 155 - (BOOL)shouldAllowHistorySwiping {
 156   if (!renderWidgetHost_ || !renderWidgetHost_->IsRenderView())
 157     return NO;
 158   if (DevToolsWindow::IsDevToolsWindow(
 159       RenderViewHost::From(renderWidgetHost_))) {
 160     return NO;
 161   }
 162
 163   return YES;
 164 }
 165
 166 - (NSView*)viewThatWantsHistoryOverlay {
 167   return renderWidgetHost_->GetView()->GetNativeView();
 168 }
 169
 170 - (BOOL)validateUserInterfaceItem:(id<NSValidatedUserInterfaceItem>)item
 171                       isValidItem:(BOOL*)valid {
 172   SEL action = [item action];
 173
 174   // For now, this action is always enabled for render view;
 175   // this is sub-optimal.
 176   // TODO(suzhe): Plumb the "can*" methods up from WebCore.
 177   if (action == @selector(checkSpelling:)) {
 178     *valid = renderWidgetHost_->IsRenderView();
 179     return YES;
 180   }
 181
 182   // TODO(groby): Clarify who sends this and if toggleContinuousSpellChecking:
 183   // is still necessary.
 184   if (action == @selector(toggleContinuousSpellChecking:)) {
 185     if ([(id)item respondsToSelector:@selector(setState:)]) {
 186       content::RenderProcessHost* host = renderWidgetHost_->GetProcess();
 187       Profile* profile = Profile::FromBrowserContext(host->GetBrowserContext());
 188       DCHECK(profile);
 189       spellcheckChecked_ =
 190           profile->GetPrefs()->GetBoolean(prefs::kEnableContinuousSpellcheck);
 191       NSCellStateValue checkedState =
 192           spellcheckChecked_ ? NSOnState : NSOffState;
 193       [(id)item setState:checkedState];
 194     }
 195     *valid = spellcheckEnabled_;
 196     return YES;
 197   }
 198
 199   return NO;
 200 }
 201
 202 // Spellchecking methods
 203 // The next five methods are implemented here since this class is the first
 204 // responder for anything in the browser.
 205
 206 // This message is sent whenever the user specifies that a word should be
 207 // changed from the spellChecker.
 208 - (void)changeSpelling:(id)sender {
 209   // Grab the currently selected word from the spell panel, as this is the word
 210   // that we want to replace the selected word in the text with.
 211   NSString* newWord = [[sender selectedCell] stringValue];
 212   if (newWord != nil) {
 213     renderWidgetHost_->Replace(base::SysNSStringToUTF16(newWord));
 214   }
 215 }
 216
 217 // This message is sent by NSSpellChecker whenever the next word should be
 218 // advanced to, either after a correction or clicking the "Find Next" button.
 219 // This isn't documented anywhere useful, like in NSSpellProtocol.h with the
 220 // other spelling panel methods. This is probably because Apple assumes that the
 221 // the spelling panel will be used with an NSText, which will automatically
 222 // catch this and advance to the next word for you. Thanks Apple.
 223 // This is also called from the Edit -> Spelling -> Check Spelling menu item.
 224 - (void)checkSpelling:(id)sender {
 225   renderWidgetHost_->Send(new SpellCheckMsg_AdvanceToNextMisspelling(
 226       renderWidgetHost_->GetRoutingID()));
 227 }
 228
 229 // This message is sent by the spelling panel whenever a word is ignored.
 230 - (void)ignoreSpelling:(id)sender {
 231   // Ideally, we would ask the current RenderView for its tag, but that would
 232   // mean making a blocking IPC call from the browser. Instead,
 233   // spellcheck_mac::CheckSpelling remembers the last tag and
 234   // spellcheck_mac::IgnoreWord assumes that is the correct tag.
 235   NSString* wordToIgnore = [sender stringValue];
 236   if (wordToIgnore != nil)
 237     spellcheck_mac::IgnoreWord(base::SysNSStringToUTF16(wordToIgnore));
 238 }
 239
 240 - (void)showGuessPanel:(id)sender {
 241   renderWidgetHost_->Send(new SpellCheckMsg_ToggleSpellPanel(
 242       renderWidgetHost_->GetRoutingID(),
 243       spellcheck_mac::SpellingPanelVisible()));
 244 }
 245
 246 - (void)toggleContinuousSpellChecking:(id)sender {
 247   content::RenderProcessHost* host = renderWidgetHost_->GetProcess();
 248   Profile* profile = Profile::FromBrowserContext(host->GetBrowserContext());
 249   DCHECK(profile);
 250   PrefService* pref = profile->GetPrefs();
 251   pref->SetBoolean(prefs::kEnableContinuousSpellcheck,
 252                    !pref->GetBoolean(prefs::kEnableContinuousSpellcheck));
 253 }
 254
 255 - (void)spellCheckEnabled:(BOOL)enabled checked:(BOOL)checked {
 256   spellcheckEnabled_ = enabled;
 257   spellcheckChecked_ = checked;
 258 }
 259
 260 // END Spellchecking methods
 261
 262 @end