ui/views/cocoa/bridged_content_view.mm

   1 // Copyright 2014 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "ui/views/cocoa/bridged_content_view.h"
   6
   7 #include "base/logging.h"
   8 #include "base/strings/sys_string_conversions.h"
   9 #include "grit/ui_strings.h"
  10 #include "ui/base/ime/text_input_client.h"
  11 #include "ui/gfx/canvas_paint_mac.h"
  12 #include "ui/gfx/geometry/rect.h"
  13 #include "ui/views/view.h"
  14
  15 @interface BridgedContentView ()
  16
  17 // Execute a command on the currently focused TextInputClient.
  18 // |commandId| should be a resource ID from ui_strings.grd.
  19 - (void)doCommandByID:(int)commandId;
  20
  21 @end
  22
  23 @implementation BridgedContentView
  24
  25 @synthesize hostedView = hostedView_;
  26 @synthesize textInputClient = textInputClient_;
  27
  28 - (id)initWithView:(views::View*)viewToHost {
  29   DCHECK(viewToHost);
  30   gfx::Rect bounds = viewToHost->bounds();
  31   // To keep things simple, assume the origin is (0, 0) until there exists a use
  32   // case for something other than that.
  33   DCHECK(bounds.origin().IsOrigin());
  34   NSRect initialFrame = NSMakeRect(0, 0, bounds.width(), bounds.height());
  35   if ((self = [super initWithFrame:initialFrame]))
  36     hostedView_ = viewToHost;
  37
  38   return self;
  39 }
  40
  41 - (void)clearView {
  42   hostedView_ = NULL;
  43 }
  44
  45 // BridgedContentView private implementation.
  46
  47 - (void)doCommandByID:(int)commandId {
  48   if (textInputClient_ && textInputClient_->IsEditingCommandEnabled(commandId))
  49     textInputClient_->ExecuteEditingCommand(commandId);
  50 }
  51
  52 // NSView implementation.
  53
  54 - (void)setFrameSize:(NSSize)newSize {
  55   [super setFrameSize:newSize];
  56   if (!hostedView_)
  57     return;
  58
  59   hostedView_->SetSize(gfx::Size(newSize.width, newSize.height));
  60 }
  61
  62 - (void)drawRect:(NSRect)dirtyRect {
  63   if (!hostedView_)
  64     return;
  65
  66   gfx::CanvasSkiaPaint canvas(dirtyRect, false /* opaque */);
  67   hostedView_->Paint(&canvas, views::CullSet());
  68 }
  69
  70 - (void)keyDown:(NSEvent*)theEvent {
  71   if (textInputClient_)
  72     [self interpretKeyEvents:@[ theEvent ]];
  73   else
  74     [super keyDown:theEvent];
  75 }
  76
  77 - (void)deleteBackward:(id)sender {
  78   [self doCommandByID:IDS_DELETE_BACKWARD];
  79 }
  80
  81 - (void)deleteForward:(id)sender {
  82   [self doCommandByID:IDS_DELETE_FORWARD];
  83 }
  84
  85 - (void)moveLeft:(id)sender {
  86   [self doCommandByID:IDS_MOVE_LEFT];
  87 }
  88
  89 - (void)moveRight:(id)sender {
  90   [self doCommandByID:IDS_MOVE_RIGHT];
  91 }
  92
  93 // NSTextInputClient protocol implementation.
  94
  95 - (NSAttributedString*)
  96     attributedSubstringForProposedRange:(NSRange)range
  97                             actualRange:(NSRangePointer)actualRange {
  98   base::string16 substring;
  99   if (textInputClient_) {
 100     gfx::Range textRange;
 101     textInputClient_->GetTextRange(&textRange);
 102     gfx::Range subrange = textRange.Intersect(gfx::Range(range));
 103     textInputClient_->GetTextFromRange(subrange, &substring);
 104     if (actualRange)
 105       *actualRange = subrange.ToNSRange();
 106   }
 107   return [[[NSAttributedString alloc]
 108       initWithString:base::SysUTF16ToNSString(substring)] autorelease];
 109 }
 110
 111 - (NSUInteger)characterIndexForPoint:(NSPoint)aPoint {
 112   NOTIMPLEMENTED();
 113   return 0;
 114 }
 115
 116 - (void)doCommandBySelector:(SEL)selector {
 117   if ([self respondsToSelector:selector])
 118     [self performSelector:selector withObject:nil];
 119   else
 120     [[self nextResponder] doCommandBySelector:selector];
 121 }
 122
 123 - (NSRect)firstRectForCharacterRange:(NSRange)range
 124                          actualRange:(NSRangePointer)actualRange {
 125   NOTIMPLEMENTED();
 126   return NSZeroRect;
 127 }
 128
 129 - (BOOL)hasMarkedText {
 130   return textInputClient_ && textInputClient_->HasCompositionText();
 131 }
 132
 133 - (void)insertText:(id)text replacementRange:(NSRange)replacementRange {
 134   if (!textInputClient_)
 135     return;
 136
 137   if ([text isKindOfClass:[NSAttributedString class]])
 138     text = [text string];
 139   textInputClient_->DeleteRange(gfx::Range(replacementRange));
 140   textInputClient_->InsertText(base::SysNSStringToUTF16(text));
 141 }
 142
 143 - (NSRange)markedRange {
 144   if (!textInputClient_)
 145     return NSMakeRange(NSNotFound, 0);
 146
 147   gfx::Range range;
 148   textInputClient_->GetCompositionTextRange(&range);
 149   return range.ToNSRange();
 150 }
 151
 152 - (NSRange)selectedRange {
 153   if (!textInputClient_)
 154     return NSMakeRange(NSNotFound, 0);
 155
 156   gfx::Range range;
 157   textInputClient_->GetSelectionRange(&range);
 158   return range.ToNSRange();
 159 }
 160
 161 - (void)setMarkedText:(id)text
 162         selectedRange:(NSRange)selectedRange
 163      replacementRange:(NSRange)replacementRange {
 164   if (!textInputClient_)
 165     return;
 166
 167   if ([text isKindOfClass:[NSAttributedString class]])
 168     text = [text string];
 169   ui::CompositionText composition;
 170   composition.text = base::SysNSStringToUTF16(text);
 171   composition.selection = gfx::Range(selectedRange);
 172   textInputClient_->SetCompositionText(composition);
 173 }
 174
 175 - (void)unmarkText {
 176   if (textInputClient_)
 177     textInputClient_->ConfirmCompositionText();
 178 }
 179
 180 - (NSArray*)validAttributesForMarkedText {
 181   return @[];
 182 }
 183
 184 @end