chrome/app_shim/chrome_main_app_mode_mac.mm

   1 // Copyright 2013 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 // On Mac, one can't make shortcuts with command-line arguments. Instead, we
   6 // produce small app bundles which locate the Chromium framework and load it,
   7 // passing the appropriate data. This is the entry point into the framework for
   8 // those app bundles.
   9
  10 #import <Cocoa/Cocoa.h>
  11 #include <vector>
  12
  13 #include "base/at_exit.h"
  14 #include "base/command_line.h"
  15 #include "base/files/file_path.h"
  16 #include "base/files/file_util.h"
  17 #include "base/logging.h"
  18 #include "base/mac/bundle_locations.h"
  19 #include "base/mac/foundation_util.h"
  20 #include "base/mac/launch_services_util.h"
  21 #include "base/mac/mac_logging.h"
  22 #include "base/mac/mac_util.h"
  23 #include "base/mac/scoped_nsautorelease_pool.h"
  24 #include "base/mac/scoped_nsobject.h"
  25 #include "base/mac/sdk_forward_declarations.h"
  26 #include "base/message_loop/message_loop.h"
  27 #include "base/strings/string_number_conversions.h"
  28 #include "base/strings/sys_string_conversions.h"
  29 #include "base/threading/thread.h"
  30 #include "chrome/common/chrome_constants.h"
  31 #include "chrome/common/chrome_paths.h"
  32 #include "chrome/common/chrome_switches.h"
  33 #include "chrome/common/mac/app_mode_common.h"
  34 #include "chrome/common/mac/app_shim_messages.h"
  35 #include "chrome/grit/generated_resources.h"
  36 #include "ipc/ipc_channel_proxy.h"
  37 #include "ipc/ipc_listener.h"
  38 #include "ipc/ipc_message.h"
  39 #include "ui/base/l10n/l10n_util.h"
  40 #include "ui/base/resource/resource_bundle.h"
  41
  42 namespace {
  43
  44 // Timeout in seconds to wait for a reply for the initial Apple Event. Note that
  45 // kAEDefaultTimeout on Mac is "about one minute" according to Apple's
  46 // documentation, but is no longer supported for asynchronous Apple Events.
  47 const int kPingChromeTimeoutSeconds = 60;
  48
  49 const app_mode::ChromeAppModeInfo* g_info;
  50 base::Thread* g_io_thread = NULL;
  51
  52 }  // namespace
  53
  54 class AppShimController;
  55
  56 // An application delegate to catch user interactions and send the appropriate
  57 // IPC messages to Chrome.
  58 @interface AppShimDelegate : NSObject<NSApplicationDelegate> {
  59  @private
  60   AppShimController* appShimController_;  // Weak, initially NULL.
  61   BOOL terminateNow_;
  62   BOOL terminateRequested_;
  63   std::vector<base::FilePath> filesToOpenAtStartup_;
  64 }
  65
  66 // The controller is initially NULL. Setting it indicates to the delegate that
  67 // the controller has finished initialization.
  68 - (void)setController:(AppShimController*)controller;
  69
  70 // Gets files that were queued because the controller was not ready.
  71 // Returns whether any FilePaths were added to |out|.
  72 - (BOOL)getFilesToOpenAtStartup:(std::vector<base::FilePath>*)out;
  73
  74 // If the controller is ready, this sends a FocusApp with the files to open.
  75 // Otherwise, this adds the files to |filesToOpenAtStartup_|.
  76 // Takes an array of NSString*.
  77 - (void)openFiles:(NSArray*)filename;
  78
  79 // Terminate immediately. This is necessary as we override terminate: to send
  80 // a QuitApp message.
  81 - (void)terminateNow;
  82
  83 @end
  84
  85 // The AppShimController is responsible for communication with the main Chrome
  86 // process, and generally controls the lifetime of the app shim process.
  87 class AppShimController : public IPC::Listener {
  88  public:
  89   AppShimController();
  90   ~AppShimController() override;
  91
  92   // Called when the main Chrome process responds to the Apple Event ping that
  93   // was sent, or when the ping fails (if |success| is false).
  94   void OnPingChromeReply(bool success);
  95
  96   // Called |kPingChromeTimeoutSeconds| after startup, to allow a timeout on the
  97   // ping event to be detected.
  98   void OnPingChromeTimeout();
  99
 100   // Connects to Chrome and sends a LaunchApp message.
 101   void Init();
 102
 103   // Create a channel from |socket_path| and send a LaunchApp message.
 104   void CreateChannelAndSendLaunchApp(const base::FilePath& socket_path);
 105
 106   // Builds main menu bar items.
 107   void SetUpMenu();
 108
 109   void SendSetAppHidden(bool hidden);
 110
 111   void SendQuitApp();
 112
 113   // Called when the app is activated, e.g. by clicking on it in the dock, by
 114   // dropping a file on the dock icon, or by Cmd+Tabbing to it.
 115   // Returns whether the message was sent.
 116   bool SendFocusApp(apps::AppShimFocusType focus_type,
 117                     const std::vector<base::FilePath>& files);
 118
 119  private:
 120   // IPC::Listener implemetation.
 121   bool OnMessageReceived(const IPC::Message& message) override;
 122   void OnChannelError() override;
 123
 124   // If Chrome failed to launch the app, |success| will be false and the app
 125   // shim process should die.
 126   void OnLaunchAppDone(apps::AppShimLaunchResult result);
 127
 128   // Hide this app.
 129   void OnHide();
 130
 131   // Set this app to the unhidden state. Happens when an app window shows
 132   // itself.
 133   void OnUnhideWithoutActivation();
 134
 135   // Requests user attention.
 136   void OnRequestUserAttention();
 137   void OnSetUserAttention(apps::AppShimAttentionType attention_type);
 138
 139   // Terminates the app shim process.
 140   void Close();
 141
 142   base::FilePath user_data_dir_;
 143   scoped_ptr<IPC::ChannelProxy> channel_;
 144   base::scoped_nsobject<AppShimDelegate> delegate_;
 145   bool launch_app_done_;
 146   bool ping_chrome_reply_received_;
 147   NSInteger attention_request_id_;
 148
 149   DISALLOW_COPY_AND_ASSIGN(AppShimController);
 150 };
 151
 152 AppShimController::AppShimController()
 153     : delegate_([[AppShimDelegate alloc] init]),
 154       launch_app_done_(false),
 155       ping_chrome_reply_received_(false),
 156       attention_request_id_(0) {
 157   // Since AppShimController is created before the main message loop starts,
 158   // NSApp will not be set, so use sharedApplication.
 159   [[NSApplication sharedApplication] setDelegate:delegate_];
 160 }
 161
 162 AppShimController::~AppShimController() {
 163   // Un-set the delegate since NSApplication does not retain it.
 164   [[NSApplication sharedApplication] setDelegate:nil];
 165 }
 166
 167 void AppShimController::OnPingChromeReply(bool success) {
 168   ping_chrome_reply_received_ = true;
 169   if (!success) {
 170     [NSApp terminate:nil];
 171     return;
 172   }
 173
 174   Init();
 175 }
 176
 177 void AppShimController::OnPingChromeTimeout() {
 178   if (!ping_chrome_reply_received_)
 179     [NSApp terminate:nil];
 180 }
 181
 182 void AppShimController::Init() {
 183   DCHECK(g_io_thread);
 184
 185   SetUpMenu();
 186
 187   // Chrome will relaunch shims when relaunching apps.
 188   if (base::mac::IsOSLionOrLater())
 189     [NSApp disableRelaunchOnLogin];
 190
 191   // The user_data_dir for shims actually contains the app_data_path.
 192   // I.e. <user_data_dir>/<profile_dir>/Web Applications/_crx_extensionid/
 193   user_data_dir_ = g_info->user_data_dir.DirName().DirName().DirName();
 194   CHECK(!user_data_dir_.empty());
 195
 196   base::FilePath symlink_path =
 197       user_data_dir_.Append(app_mode::kAppShimSocketSymlinkName);
 198
 199   base::FilePath socket_path;
 200   if (!base::ReadSymbolicLink(symlink_path, &socket_path)) {
 201     // The path in the user data dir is not a symlink, try connecting directly.
 202     CreateChannelAndSendLaunchApp(symlink_path);
 203     return;
 204   }
 205
 206   app_mode::VerifySocketPermissions(socket_path);
 207
 208   CreateChannelAndSendLaunchApp(socket_path);
 209 }
 210
 211 void AppShimController::CreateChannelAndSendLaunchApp(
 212     const base::FilePath& socket_path) {
 213   IPC::ChannelHandle handle(socket_path.value());
 214   channel_ = IPC::ChannelProxy::Create(handle, IPC::Channel::MODE_NAMED_CLIENT,
 215                                        this, g_io_thread->task_runner().get());
 216
 217   bool launched_by_chrome = base::CommandLine::ForCurrentProcess()->HasSwitch(
 218       app_mode::kLaunchedByChromeProcessId);
 219   apps::AppShimLaunchType launch_type = launched_by_chrome ?
 220           apps::APP_SHIM_LAUNCH_REGISTER_ONLY : apps::APP_SHIM_LAUNCH_NORMAL;
 221
 222   [delegate_ setController:this];
 223
 224   std::vector<base::FilePath> files;
 225   [delegate_ getFilesToOpenAtStartup:&files];
 226
 227   channel_->Send(new AppShimHostMsg_LaunchApp(
 228       g_info->profile_dir, g_info->app_mode_id, launch_type, files));
 229 }
 230
 231 void AppShimController::SetUpMenu() {
 232   NSString* title = base::SysUTF16ToNSString(g_info->app_mode_name);
 233
 234   // Create a main menu since [NSApp mainMenu] is nil.
 235   base::scoped_nsobject<NSMenu> main_menu([[NSMenu alloc] initWithTitle:title]);
 236
 237   // The title of the first item is replaced by OSX with the name of the app and
 238   // bold styling. Create a dummy item for this and make it hidden.
 239   NSMenuItem* dummy_item = [main_menu addItemWithTitle:title
 240                                                 action:nil
 241                                          keyEquivalent:@""];
 242   base::scoped_nsobject<NSMenu> dummy_submenu(
 243       [[NSMenu alloc] initWithTitle:title]);
 244   [dummy_item setSubmenu:dummy_submenu];
 245   [dummy_item setHidden:YES];
 246
 247   // Construct an unbolded app menu, to match how it appears in the Chrome menu
 248   // bar when the app is focused.
 249   NSMenuItem* item = [main_menu addItemWithTitle:title
 250                                           action:nil
 251                                    keyEquivalent:@""];
 252   base::scoped_nsobject<NSMenu> submenu([[NSMenu alloc] initWithTitle:title]);
 253   [item setSubmenu:submenu];
 254
 255   // Add a quit entry.
 256   NSString* quit_localized_string =
 257       l10n_util::GetNSStringF(IDS_EXIT_MAC, g_info->app_mode_name);
 258   [submenu addItemWithTitle:quit_localized_string
 259                      action:@selector(terminate:)
 260               keyEquivalent:@"q"];
 261
 262   // Add File, Edit, and Window menus. These are just here to make the
 263   // transition smoother, i.e. from another application to the shim then to
 264   // Chrome.
 265   [main_menu addItemWithTitle:l10n_util::GetNSString(IDS_FILE_MENU_MAC)
 266                        action:nil
 267                 keyEquivalent:@""];
 268   [main_menu addItemWithTitle:l10n_util::GetNSString(IDS_EDIT_MENU_MAC)
 269                        action:nil
 270                 keyEquivalent:@""];
 271   [main_menu addItemWithTitle:l10n_util::GetNSString(IDS_WINDOW_MENU_MAC)
 272                        action:nil
 273                 keyEquivalent:@""];
 274
 275   [NSApp setMainMenu:main_menu];
 276 }
 277
 278 void AppShimController::SendQuitApp() {
 279   channel_->Send(new AppShimHostMsg_QuitApp);
 280 }
 281
 282 bool AppShimController::OnMessageReceived(const IPC::Message& message) {
 283   bool handled = true;
 284   IPC_BEGIN_MESSAGE_MAP(AppShimController, message)
 285     IPC_MESSAGE_HANDLER(AppShimMsg_LaunchApp_Done, OnLaunchAppDone)
 286     IPC_MESSAGE_HANDLER(AppShimMsg_Hide, OnHide)
 287     IPC_MESSAGE_HANDLER(AppShimMsg_UnhideWithoutActivation,
 288                         OnUnhideWithoutActivation)
 289     IPC_MESSAGE_HANDLER(AppShimMsg_RequestUserAttention, OnRequestUserAttention)
 290     IPC_MESSAGE_HANDLER(AppShimMsg_SetUserAttention, OnSetUserAttention)
 291     IPC_MESSAGE_UNHANDLED(handled = false)
 292   IPC_END_MESSAGE_MAP()
 293
 294   return handled;
 295 }
 296
 297 void AppShimController::OnChannelError() {
 298   Close();
 299 }
 300
 301 void AppShimController::OnLaunchAppDone(apps::AppShimLaunchResult result) {
 302   if (result != apps::APP_SHIM_LAUNCH_SUCCESS) {
 303     Close();
 304     return;
 305   }
 306
 307   std::vector<base::FilePath> files;
 308   if ([delegate_ getFilesToOpenAtStartup:&files])
 309     SendFocusApp(apps::APP_SHIM_FOCUS_OPEN_FILES, files);
 310
 311   launch_app_done_ = true;
 312 }
 313
 314 void AppShimController::OnHide() {
 315   [NSApp hide:nil];
 316 }
 317
 318 void AppShimController::OnUnhideWithoutActivation() {
 319   [NSApp unhideWithoutActivation];
 320 }
 321
 322 void AppShimController::OnRequestUserAttention() {
 323   OnSetUserAttention(apps::APP_SHIM_ATTENTION_INFORMATIONAL);
 324 }
 325
 326 void AppShimController::OnSetUserAttention(
 327     apps::AppShimAttentionType attention_type) {
 328   switch (attention_type) {
 329     case apps::APP_SHIM_ATTENTION_CANCEL:
 330       [NSApp cancelUserAttentionRequest:attention_request_id_];
 331       attention_request_id_ = 0;
 332       break;
 333     case apps::APP_SHIM_ATTENTION_CRITICAL:
 334       attention_request_id_ = [NSApp requestUserAttention:NSCriticalRequest];
 335       break;
 336     case apps::APP_SHIM_ATTENTION_INFORMATIONAL:
 337       attention_request_id_ =
 338           [NSApp requestUserAttention:NSInformationalRequest];
 339       break;
 340     case apps::APP_SHIM_ATTENTION_NUM_TYPES:
 341       NOTREACHED();
 342   }
 343 }
 344
 345 void AppShimController::Close() {
 346   [delegate_ terminateNow];
 347 }
 348
 349 bool AppShimController::SendFocusApp(apps::AppShimFocusType focus_type,
 350                                      const std::vector<base::FilePath>& files) {
 351   if (launch_app_done_) {
 352     channel_->Send(new AppShimHostMsg_FocusApp(focus_type, files));
 353     return true;
 354   }
 355
 356   return false;
 357 }
 358
 359 void AppShimController::SendSetAppHidden(bool hidden) {
 360   channel_->Send(new AppShimHostMsg_SetAppHidden(hidden));
 361 }
 362
 363 @implementation AppShimDelegate
 364
 365 - (BOOL)getFilesToOpenAtStartup:(std::vector<base::FilePath>*)out {
 366   if (filesToOpenAtStartup_.empty())
 367     return NO;
 368
 369   out->insert(out->end(),
 370               filesToOpenAtStartup_.begin(),
 371               filesToOpenAtStartup_.end());
 372   filesToOpenAtStartup_.clear();
 373   return YES;
 374 }
 375
 376 - (void)setController:(AppShimController*)controller {
 377   appShimController_ = controller;
 378 }
 379
 380 - (void)openFiles:(NSArray*)filenames {
 381   std::vector<base::FilePath> filePaths;
 382   for (NSString* filename in filenames)
 383     filePaths.push_back(base::mac::NSStringToFilePath(filename));
 384
 385   // If the AppShimController is ready, try to send a FocusApp. If that fails,
 386   // (e.g. if launching has not finished), enqueue the files.
 387   if (appShimController_ &&
 388       appShimController_->SendFocusApp(apps::APP_SHIM_FOCUS_OPEN_FILES,
 389                                        filePaths)) {
 390     return;
 391   }
 392
 393   filesToOpenAtStartup_.insert(filesToOpenAtStartup_.end(),
 394                                filePaths.begin(),
 395                                filePaths.end());
 396 }
 397
 398 - (BOOL)application:(NSApplication*)app
 399            openFile:(NSString*)filename {
 400   [self openFiles:@[filename]];
 401   return YES;
 402 }
 403
 404 - (void)application:(NSApplication*)app
 405           openFiles:(NSArray*)filenames {
 406   [self openFiles:filenames];
 407   [app replyToOpenOrPrint:NSApplicationDelegateReplySuccess];
 408 }
 409
 410 - (BOOL)applicationOpenUntitledFile:(NSApplication*)app {
 411   if (appShimController_) {
 412     return appShimController_->SendFocusApp(apps::APP_SHIM_FOCUS_REOPEN,
 413                                             std::vector<base::FilePath>());
 414   }
 415
 416   return NO;
 417 }
 418
 419 - (void)applicationWillBecomeActive:(NSNotification*)notification {
 420   if (appShimController_) {
 421     appShimController_->SendFocusApp(apps::APP_SHIM_FOCUS_NORMAL,
 422                                      std::vector<base::FilePath>());
 423   }
 424 }
 425
 426 - (NSApplicationTerminateReply)
 427     applicationShouldTerminate:(NSApplication*)sender {
 428   if (terminateNow_ || !appShimController_)
 429     return NSTerminateNow;
 430
 431   appShimController_->SendQuitApp();
 432   // Wait for the channel to close before terminating.
 433   terminateRequested_ = YES;
 434   return NSTerminateLater;
 435 }
 436
 437 - (void)applicationWillHide:(NSNotification*)notification {
 438   if (appShimController_)
 439     appShimController_->SendSetAppHidden(true);
 440 }
 441
 442 - (void)applicationWillUnhide:(NSNotification*)notification {
 443   if (appShimController_)
 444     appShimController_->SendSetAppHidden(false);
 445 }
 446
 447 - (void)terminateNow {
 448   if (terminateRequested_) {
 449     [NSApp replyToApplicationShouldTerminate:NSTerminateNow];
 450     return;
 451   }
 452
 453   terminateNow_ = YES;
 454   [NSApp terminate:nil];
 455 }
 456
 457 @end
 458
 459 //-----------------------------------------------------------------------------
 460
 461 // A ReplyEventHandler is a helper class to send an Apple Event to a process
 462 // and call a callback when the reply returns.
 463 //
 464 // This is used to 'ping' the main Chrome process -- once Chrome has sent back
 465 // an Apple Event reply, it's guaranteed that it has opened the IPC channel
 466 // that the app shim will connect to.
 467 @interface ReplyEventHandler : NSObject {
 468   base::Callback<void(bool)> onReply_;
 469   AEDesc replyEvent_;
 470 }
 471 // Sends an Apple Event to the process identified by |psn|, and calls |replyFn|
 472 // when the reply is received. Internally this creates a ReplyEventHandler,
 473 // which will delete itself once the reply event has been received.
 474 + (void)pingProcess:(const ProcessSerialNumber&)psn
 475             andCall:(base::Callback<void(bool)>)replyFn;
 476 @end
 477
 478 @interface ReplyEventHandler (PrivateMethods)
 479 // Initialise the reply event handler. Doesn't register any handlers until
 480 // |-pingProcess:| is called. |replyFn| is the function to be called when the
 481 // Apple Event reply arrives.
 482 - (id)initWithCallback:(base::Callback<void(bool)>)replyFn;
 483
 484 // Sends an Apple Event ping to the process identified by |psn| and registers
 485 // to listen for a reply.
 486 - (void)pingProcess:(const ProcessSerialNumber&)psn;
 487
 488 // Called when a response is received from the target process for the ping sent
 489 // by |-pingProcess:|.
 490 - (void)message:(NSAppleEventDescriptor*)event
 491       withReply:(NSAppleEventDescriptor*)reply;
 492
 493 // Calls |onReply_|, passing it |success| to specify whether the ping was
 494 // successful.
 495 - (void)closeWithSuccess:(bool)success;
 496 @end
 497
 498 @implementation ReplyEventHandler
 499 + (void)pingProcess:(const ProcessSerialNumber&)psn
 500             andCall:(base::Callback<void(bool)>)replyFn {
 501   // The object will release itself when the reply arrives, or possibly earlier
 502   // if an unrecoverable error occurs.
 503   ReplyEventHandler* handler =
 504       [[ReplyEventHandler alloc] initWithCallback:replyFn];
 505   [handler pingProcess:psn];
 506 }
 507 @end
 508
 509 @implementation ReplyEventHandler (PrivateMethods)
 510 - (id)initWithCallback:(base::Callback<void(bool)>)replyFn {
 511   if ((self = [super init])) {
 512     onReply_ = replyFn;
 513   }
 514   return self;
 515 }
 516
 517 - (void)pingProcess:(const ProcessSerialNumber&)psn {
 518   // Register the reply listener.
 519   NSAppleEventManager* em = [NSAppleEventManager sharedAppleEventManager];
 520   [em setEventHandler:self
 521           andSelector:@selector(message:withReply:)
 522         forEventClass:'aevt'
 523            andEventID:'ansr'];
 524   // Craft the Apple Event to send.
 525   NSAppleEventDescriptor* target = [NSAppleEventDescriptor
 526       descriptorWithDescriptorType:typeProcessSerialNumber
 527                              bytes:&psn
 528                             length:sizeof(psn)];
 529   NSAppleEventDescriptor* initial_event =
 530       [NSAppleEventDescriptor
 531           appleEventWithEventClass:app_mode::kAEChromeAppClass
 532                            eventID:app_mode::kAEChromeAppPing
 533                   targetDescriptor:target
 534                           returnID:kAutoGenerateReturnID
 535                      transactionID:kAnyTransactionID];
 536
 537   // Note that AESendMessage effectively ignores kAEDefaultTimeout, because this
 538   // call does not pass kAEWantReceipt (which is deprecated and unsupported on
 539   // Mac). Instead, rely on OnPingChromeTimeout().
 540   OSStatus status = AESendMessage(
 541       [initial_event aeDesc], &replyEvent_, kAEQueueReply, kAEDefaultTimeout);
 542   if (status != noErr) {
 543     OSSTATUS_LOG(ERROR, status) << "AESendMessage";
 544     [self closeWithSuccess:false];
 545   }
 546 }
 547
 548 - (void)message:(NSAppleEventDescriptor*)event
 549       withReply:(NSAppleEventDescriptor*)reply {
 550   [self closeWithSuccess:true];
 551 }
 552
 553 - (void)closeWithSuccess:(bool)success {
 554   onReply_.Run(success);
 555   NSAppleEventManager* em = [NSAppleEventManager sharedAppleEventManager];
 556   [em removeEventHandlerForEventClass:'aevt' andEventID:'ansr'];
 557   [self release];
 558 }
 559 @end
 560
 561 //-----------------------------------------------------------------------------
 562
 563 extern "C" {
 564
 565 // |ChromeAppModeStart()| is the point of entry into the framework from the app
 566 // mode loader.
 567 __attribute__((visibility("default")))
 568 int ChromeAppModeStart(const app_mode::ChromeAppModeInfo* info);
 569
 570 }  // extern "C"
 571
 572 int ChromeAppModeStart(const app_mode::ChromeAppModeInfo* info) {
 573   base::CommandLine::Init(info->argc, info->argv);
 574
 575   base::mac::ScopedNSAutoreleasePool scoped_pool;
 576   base::AtExitManager exit_manager;
 577   chrome::RegisterPathProvider();
 578
 579   if (info->major_version < app_mode::kCurrentChromeAppModeInfoMajorVersion) {
 580     RAW_LOG(ERROR, "App Mode Loader too old.");
 581     return 1;
 582   }
 583   if (info->major_version > app_mode::kCurrentChromeAppModeInfoMajorVersion) {
 584     RAW_LOG(ERROR, "Browser Framework too old to load App Shortcut.");
 585     return 1;
 586   }
 587
 588   g_info = info;
 589
 590   // Set bundle paths. This loads the bundles.
 591   base::mac::SetOverrideOuterBundlePath(g_info->chrome_outer_bundle_path);
 592   base::mac::SetOverrideFrameworkBundlePath(
 593       g_info->chrome_versioned_path.Append(chrome::kFrameworkName));
 594
 595   // Calculate the preferred locale used by Chrome.
 596   // We can't use l10n_util::OverrideLocaleWithCocoaLocale() because it calls
 597   // [base::mac::OuterBundle() preferredLocalizations] which gets localizations
 598   // from the bundle of the running app (i.e. it is equivalent to
 599   // [[NSBundle mainBundle] preferredLocalizations]) instead of the target
 600   // bundle.
 601   NSArray* preferred_languages = [NSLocale preferredLanguages];
 602   NSArray* supported_languages = [base::mac::OuterBundle() localizations];
 603   std::string preferred_localization;
 604   for (NSString* language in preferred_languages) {
 605     if ([supported_languages containsObject:language]) {
 606       preferred_localization = base::SysNSStringToUTF8(language);
 607       break;
 608     }
 609   }
 610   std::string locale = l10n_util::NormalizeLocale(
 611       l10n_util::GetApplicationLocale(preferred_localization));
 612
 613   // Load localized strings.
 614   ui::ResourceBundle::InitSharedInstanceWithLocale(
 615       locale, NULL, ui::ResourceBundle::DO_NOT_LOAD_COMMON_RESOURCES);
 616
 617   // Launch the IO thread.
 618   base::Thread::Options io_thread_options;
 619   io_thread_options.message_loop_type = base::MessageLoop::TYPE_IO;
 620   base::Thread *io_thread = new base::Thread("CrAppShimIO");
 621   io_thread->StartWithOptions(io_thread_options);
 622   g_io_thread = io_thread;
 623
 624   // Find already running instances of Chrome.
 625   pid_t pid = -1;
 626   std::string chrome_process_id =
 627       base::CommandLine::ForCurrentProcess()->GetSwitchValueASCII(
 628           app_mode::kLaunchedByChromeProcessId);
 629   if (!chrome_process_id.empty()) {
 630     if (!base::StringToInt(chrome_process_id, &pid))
 631       LOG(FATAL) << "Invalid PID: " << chrome_process_id;
 632   } else {
 633     NSString* chrome_bundle_id = [base::mac::OuterBundle() bundleIdentifier];
 634     NSArray* existing_chrome = [NSRunningApplication
 635         runningApplicationsWithBundleIdentifier:chrome_bundle_id];
 636     if ([existing_chrome count] > 0)
 637       pid = [[existing_chrome objectAtIndex:0] processIdentifier];
 638   }
 639
 640   AppShimController controller;
 641   base::MessageLoopForUI main_message_loop;
 642   main_message_loop.set_thread_name("MainThread");
 643   base::PlatformThread::SetName("CrAppShimMain");
 644
 645   // In tests, launching Chrome does nothing, and we won't get a ping response,
 646   // so just assume the socket exists.
 647   if (pid == -1 &&
 648       !base::CommandLine::ForCurrentProcess()->HasSwitch(
 649           app_mode::kLaunchedForTest)) {
 650     // Launch Chrome if it isn't already running.
 651     ProcessSerialNumber psn;
 652     base::CommandLine command_line(base::CommandLine::NO_PROGRAM);
 653     command_line.AppendSwitch(switches::kSilentLaunch);
 654
 655     // If the shim is the app launcher, pass --show-app-list when starting a new
 656     // Chrome process to inform startup codepaths and load the correct profile.
 657     if (info->app_mode_id == app_mode::kAppListModeId) {
 658       command_line.AppendSwitch(switches::kShowAppList);
 659     } else {
 660       command_line.AppendSwitchPath(switches::kProfileDirectory,
 661                                     info->profile_dir);
 662     }
 663
 664     bool success =
 665         base::mac::OpenApplicationWithPath(base::mac::OuterBundlePath(),
 666                                            command_line,
 667                                            kLSLaunchDefaults,
 668                                            &psn);
 669     if (!success)
 670       return 1;
 671
 672     base::Callback<void(bool)> on_ping_chrome_reply =
 673         base::Bind(&AppShimController::OnPingChromeReply,
 674                    base::Unretained(&controller));
 675
 676     // This code abuses the fact that Apple Events sent before the process is
 677     // fully initialized don't receive a reply until its run loop starts. Once
 678     // the reply is received, Chrome will have opened its IPC port, guaranteed.
 679     [ReplyEventHandler pingProcess:psn
 680                            andCall:on_ping_chrome_reply];
 681
 682     main_message_loop.PostDelayedTask(
 683         FROM_HERE,
 684         base::Bind(&AppShimController::OnPingChromeTimeout,
 685                    base::Unretained(&controller)),
 686         base::TimeDelta::FromSeconds(kPingChromeTimeoutSeconds));
 687   } else {
 688     // Chrome already running. Proceed to init. This could still fail if Chrome
 689     // is still starting up or shutting down, but the process will exit quickly,
 690     // which is preferable to waiting for the Apple Event to timeout after one
 691     // minute.
 692     main_message_loop.PostTask(
 693         FROM_HERE,
 694         base::Bind(&AppShimController::Init,
 695                    base::Unretained(&controller)));
 696   }
 697
 698   main_message_loop.Run();
 699   return 0;
 700 }