chrome/browser/ui/cocoa/web_contents_modal_dialog_manager_views_mac.mm

   1 // Copyright 2015 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/web_contents_modal_dialog_manager_views_mac.h"
   6
   7 #import <Cocoa/Cocoa.h>
   8
   9 #import "base/mac/foundation_util.h"
  10 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet.h"
  11 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet_controller.h"
  12 #include "content/public/browser/web_contents.h"
  13 #include "components/web_modal/web_contents_modal_dialog_host.h"
  14 #import "ui/base/cocoa/constrained_window/constrained_window_animation.h"
  15 #include "ui/views/widget/widget.h"
  16
  17 // A wrapper for a views::Widget dialog to interact with a Cocoa browser's
  18 // ContrainedWindowSheetController. Similar to CustomConstrainedWindowSheet, but
  19 // since Widgets of dialog type animate themselves, and also manage their own
  20 // parenting, there's not much to do except position properly.
  21 @interface WrappedConstrainedWindowSheet : NSObject<ConstrainedWindowSheet> {
  22  @private
  23   base::scoped_nsobject<NSWindow> customWindow_;
  24 }
  25 - (id)initWithCustomWindow:(NSWindow*)customWindow;
  26 @end
  27
  28 @implementation WrappedConstrainedWindowSheet
  29
  30 - (id)initWithCustomWindow:(NSWindow*)customWindow {
  31   if ((self = [super init])) {
  32     customWindow_.reset([customWindow retain]);
  33   }
  34   return self;
  35 }
  36
  37 // ConstrainedWindowSheet implementation.
  38
  39 - (void)showSheetForWindow:(NSWindow*)window {
  40   // This is only called for the initial show, then calls go to unhideSheet.
  41   // Since Widget::Show() will be called, just update the position.
  42   [self updateSheetPosition];
  43 }
  44
  45 - (void)closeSheetWithAnimation:(BOOL)withAnimation {
  46   // Nothing to do here. Either SingleWebContentsDialogManagerViewsMac::Close()
  47   // was called or Widget::Close(). Both cases ending up in OnWidgetClosing() to
  48   // call [ConstrainedWindowSheetController closeSheet:], which calls this.
  49   // However, the Widget is already closing in those cases.
  50
  51   // OnWidgetClosing() is also the _only_ trigger. The exception would be
  52   // -[ConstrainedWindowSheetController onParentWindowWillClose:] which also
  53   // calls closeSheetWithAnimation:, but a Widget never gets there because
  54   // WebContentsModalDialogManager::CloseAllDialogs() is triggered from
  55   // -[BrowserWindowController windowShouldClose:], but the notification that
  56   // calls onParentWindowWillClose always happens once that has returned YES.
  57
  58   // So, since onParentWindowWillClose never calls this, we can assert that
  59   // withAnimation is YES, otherwise there's some code path that might not be
  60   // catered for.
  61   DCHECK(withAnimation);
  62 }
  63
  64 - (void)hideSheet {
  65   // Hide the sheet window by setting the alpha to 0. This technique is used
  66   // instead of -orderOut: because that may cause a Spaces change or window
  67   // ordering change.
  68   [customWindow_ setAlphaValue:0.0];
  69   // TODO(tapted): Support child windows.
  70   DCHECK_EQ(0u, [[customWindow_ childWindows] count]);
  71 }
  72
  73 - (void)unhideSheet {
  74   [customWindow_ setAlphaValue:1.0];
  75   DCHECK_EQ(0u, [[customWindow_ childWindows] count]);
  76 }
  77
  78 - (void)pulseSheet {
  79   base::scoped_nsobject<NSAnimation> animation(
  80       [[ConstrainedWindowAnimationPulse alloc] initWithWindow:customWindow_]);
  81   [animation startAnimation];
  82 }
  83
  84 - (void)makeSheetKeyAndOrderFront {
  85   [customWindow_ makeKeyAndOrderFront:nil];
  86 }
  87
  88 - (void)updateSheetPosition {
  89   ConstrainedWindowSheetController* controller =
  90       [ConstrainedWindowSheetController controllerForSheet:self];
  91   NSPoint origin = [controller originForSheet:self
  92                                withWindowSize:[customWindow_ frame].size];
  93   [customWindow_ setFrameOrigin:origin];
  94 }
  95
  96 - (NSWindow*)sheetWindow {
  97   return customWindow_;
  98 }
  99
 100 @end
 101
 102 SingleWebContentsDialogManagerViewsMac::SingleWebContentsDialogManagerViewsMac(
 103     NSWindow* dialog,
 104     web_modal::SingleWebContentsDialogManagerDelegate* delegate)
 105     : delegate_(delegate), host_(nullptr) {
 106   sheet_.reset(
 107       [[WrappedConstrainedWindowSheet alloc] initWithCustomWindow:dialog]);
 108   widget_ = views::Widget::GetWidgetForNativeWindow(dialog);
 109   DCHECK(widget_);
 110   widget_->AddObserver(this);
 111 }
 112
 113 SingleWebContentsDialogManagerViewsMac::
 114     ~SingleWebContentsDialogManagerViewsMac() {
 115   DCHECK(!widget_->HasObserver(this));
 116 }
 117
 118 void SingleWebContentsDialogManagerViewsMac::Show() {
 119   DCHECK(host_);
 120
 121   NSView* parent_view = host_->GetHostView();
 122   // Note that simply [parent_view window] for an inactive tab is nil. However,
 123   // the following should always be non-nil for all WebContents containers.
 124   NSWindow* parent_window =
 125       delegate_->GetWebContents()->GetTopLevelNativeWindow();
 126   // Register with the ConstrainedWindowSheetController. This ensures that, e.g.
 127   // the NSView that overlays the Cocoa WebContents to intercept clicks is
 128   // installed and managed.
 129   [[ConstrainedWindowSheetController controllerForParentWindow:parent_window]
 130           showSheet:sheet_
 131       forParentView:parent_view];
 132 }
 133
 134 void SingleWebContentsDialogManagerViewsMac::Hide() {
 135   NSWindow* parent_window =
 136       delegate_->GetWebContents()->GetTopLevelNativeWindow();
 137   [[ConstrainedWindowSheetController controllerForParentWindow:parent_window]
 138       hideSheet];
 139 }
 140
 141 void SingleWebContentsDialogManagerViewsMac::Close() {
 142   // When the WebContents is destroyed, WebContentsModalDialogManager
 143   // ::CloseAllDialogs will call this. Close the Widget in the same manner as
 144   // the dialogs so that codepaths are consistent.
 145   widget_->Close();  // Note: Synchronously calls OnWidgetClosing() below.
 146 }
 147
 148 void SingleWebContentsDialogManagerViewsMac::Focus() {
 149   // Handled by ConstrainedWindowSheetController.
 150 }
 151 void SingleWebContentsDialogManagerViewsMac::Pulse() {
 152   // Handled by ConstrainedWindowSheetController.
 153 }
 154
 155 void SingleWebContentsDialogManagerViewsMac::HostChanged(
 156     web_modal::WebContentsModalDialogHost* new_host) {
 157   // No need to observe the host. For Cocoa, the constrained window controller
 158   // will reposition the dialog when necessary. The host can also never change.
 159   // Tabs showing a dialog can not be dragged off a Cocoa browser window.
 160   // However, closing a tab with a dialog open will set the host back to null.
 161   DCHECK_NE(!!host_, !!new_host);
 162   host_ = new_host;
 163 }
 164
 165 gfx::NativeWindow SingleWebContentsDialogManagerViewsMac::dialog() {
 166   return [sheet_ sheetWindow];
 167 }
 168
 169 // views::WidgetObserver:
 170 void SingleWebContentsDialogManagerViewsMac::OnWidgetClosing(
 171     views::Widget* widget) {
 172   DCHECK_EQ(widget, widget_);
 173   widget->RemoveObserver(this);
 174   [[ConstrainedWindowSheetController controllerForSheet:sheet_]
 175       closeSheet:sheet_];
 176   delegate_->WillClose(dialog());  // Deletes |this|.
 177 }
 178
 179 void SingleWebContentsDialogManagerViewsMac::OnWidgetDestroying(
 180     views::Widget* widget) {
 181   // On Mac, this would only be reached if something called -[NSWindow close]
 182   // on the dialog without going through Widget::Close or CloseNow(). Since
 183   // dialogs have no titlebar, it won't come from the system. If something
 184   // internally calls -[NSWindow close] it might break lifetime assumptions
 185   // made by DialogDelegate.
 186   NOTREACHED();
 187 }