base/allocator/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/allocator.gni")
   6
   7 declare_args() {
   8   # Provide a way to force disable debugallocation in Debug builds,
   9   # e.g. for profiling (it's more rare to profile Debug builds,
  10   # but people sometimes need to do that).
  11   enable_debugallocation = is_debug
  12 }
  13
  14 # Only executables and not libraries should depend on the allocator target;
  15 # only the application (the final executable) knows what allocator makes sense.
  16 # This "allocator" meta-target will forward to the default allocator according
  17 # to the build settings.
  18 group("allocator") {
  19   public_deps = []
  20   if (use_allocator == "tcmalloc") {
  21     public_deps += [ ":tcmalloc" ]
  22   }
  23
  24   # This condition expresses the win_use_allocator_shim in the GYP build.
  25   if (is_win && !is_component_build) {
  26     public_deps += [ ":allocator_shim" ]
  27   }
  28 }
  29
  30 # This config defines ALLOCATOR_SHIM in the same conditions that the allocator
  31 # shim will be used by the allocator target.
  32 #
  33 # TODO(brettw) this is only used in one place and is kind of mess, because it
  34 # assumes that the library using it will eventually be linked with
  35 # //base/allocator in the default way. Clean this up and delete this.
  36 config("allocator_shim_define") {
  37   if (is_win && !is_component_build) {
  38     defines = [ "ALLOCATOR_SHIM" ]
  39   }
  40 }
  41
  42 config("tcmalloc_flags") {
  43   if (enable_debugallocation) {
  44     defines = [
  45       # Use debugallocation for Debug builds to catch problems early
  46       # and cleanly, http://crbug.com/30715 .
  47       "TCMALLOC_FOR_DEBUGALLOCATION",
  48     ]
  49   }
  50 }
  51
  52 # This config and libc modification are only used on Windows.
  53 if (is_win) {
  54   import("//build/config/win/visual_studio_version.gni")
  55
  56   config("nocmt") {
  57     ldflags = [
  58       "/NODEFAULTLIB:libcmt",
  59       "/NODEFAULTLIB:libcmtd",
  60     ]
  61     libs = [ rebase_path("$target_gen_dir/allocator/libcmt.lib") ]
  62   }
  63
  64   action("prep_libc") {
  65     script = "prep_libc.py"
  66     outputs = [
  67       "$target_gen_dir/allocator/libcmt.lib",
  68     ]
  69     args = [
  70       visual_studio_path + "/vc/lib",
  71       rebase_path("$target_gen_dir/allocator"),
  72       current_cpu,
  73     ]
  74   }
  75
  76   source_set("allocator_shim") {
  77     sources = [
  78       "allocator_shim_win.cc",
  79     ]
  80     configs -= [ "//build/config/compiler:chromium_code" ]
  81     configs += [ "//build/config/compiler:no_chromium_code" ]
  82
  83     public_configs = [ ":nocmt" ]
  84     deps = [
  85       ":prep_libc",
  86     ]
  87   }
  88 }
  89
  90 if (use_allocator == "tcmalloc") {
  91   # tcmalloc currently won't compile on Android.
  92   source_set("tcmalloc") {
  93     tcmalloc_dir = "//third_party/tcmalloc/chromium"
  94
  95     # Don't check tcmalloc's includes. These files include various files like
  96     # base/foo.h and they actually refer to tcmalloc's forked copy of base
  97     # rather than the regular one, which confuses the header checker.
  98     check_includes = false
  99
 100     sources = [
 101       # Generated for our configuration from tcmalloc"s build
 102       # and checked in.
 103       "$tcmalloc_dir/src/config.h",
 104       "$tcmalloc_dir/src/config_android.h",
 105       "$tcmalloc_dir/src/config_linux.h",
 106       "$tcmalloc_dir/src/config_win.h",
 107
 108       # tcmalloc native and forked files.
 109       "$tcmalloc_dir/src/base/abort.cc",
 110       "$tcmalloc_dir/src/base/abort.h",
 111       "$tcmalloc_dir/src/base/arm_instruction_set_select.h",
 112       "$tcmalloc_dir/src/base/atomicops-internals-arm-generic.h",
 113       "$tcmalloc_dir/src/base/atomicops-internals-arm-v6plus.h",
 114       "$tcmalloc_dir/src/base/atomicops-internals-linuxppc.h",
 115       "$tcmalloc_dir/src/base/atomicops-internals-macosx.h",
 116       "$tcmalloc_dir/src/base/atomicops-internals-windows.h",
 117       "$tcmalloc_dir/src/base/atomicops-internals-x86.cc",
 118       "$tcmalloc_dir/src/base/atomicops-internals-x86.h",
 119       "$tcmalloc_dir/src/base/atomicops.h",
 120       "$tcmalloc_dir/src/base/basictypes.h",
 121       "$tcmalloc_dir/src/base/commandlineflags.h",
 122       "$tcmalloc_dir/src/base/cycleclock.h",
 123
 124       # We don't list dynamic_annotations.c since its copy is already
 125       # present in the dynamic_annotations target.
 126       "$tcmalloc_dir/src/base/elf_mem_image.cc",
 127       "$tcmalloc_dir/src/base/elf_mem_image.h",
 128       "$tcmalloc_dir/src/base/linuxthreads.cc",
 129       "$tcmalloc_dir/src/base/linuxthreads.h",
 130       "$tcmalloc_dir/src/base/logging.cc",
 131       "$tcmalloc_dir/src/base/logging.h",
 132       "$tcmalloc_dir/src/base/low_level_alloc.cc",
 133       "$tcmalloc_dir/src/base/low_level_alloc.h",
 134       "$tcmalloc_dir/src/base/spinlock.cc",
 135       "$tcmalloc_dir/src/base/spinlock.h",
 136       "$tcmalloc_dir/src/base/spinlock_internal.cc",
 137       "$tcmalloc_dir/src/base/spinlock_internal.h",
 138       "$tcmalloc_dir/src/base/synchronization_profiling.h",
 139       "$tcmalloc_dir/src/base/sysinfo.cc",
 140       "$tcmalloc_dir/src/base/sysinfo.h",
 141       "$tcmalloc_dir/src/base/thread_lister.c",
 142       "$tcmalloc_dir/src/base/thread_lister.h",
 143       "$tcmalloc_dir/src/base/vdso_support.cc",
 144       "$tcmalloc_dir/src/base/vdso_support.h",
 145       "$tcmalloc_dir/src/central_freelist.cc",
 146       "$tcmalloc_dir/src/central_freelist.h",
 147       "$tcmalloc_dir/src/common.cc",
 148       "$tcmalloc_dir/src/common.h",
 149
 150       # #included by debugallocation_shim.cc
 151       #"$tcmalloc_dir/src/debugallocation.cc",
 152       "$tcmalloc_dir/src/deep-heap-profile.cc",
 153       "$tcmalloc_dir/src/deep-heap-profile.h",
 154       "$tcmalloc_dir/src/free_list.cc",
 155       "$tcmalloc_dir/src/free_list.h",
 156       "$tcmalloc_dir/src/heap-profile-table.cc",
 157       "$tcmalloc_dir/src/heap-profile-table.h",
 158       "$tcmalloc_dir/src/heap-profiler.cc",
 159       "$tcmalloc_dir/src/internal_logging.cc",
 160       "$tcmalloc_dir/src/internal_logging.h",
 161       "$tcmalloc_dir/src/linked_list.h",
 162       "$tcmalloc_dir/src/malloc_extension.cc",
 163       "$tcmalloc_dir/src/malloc_hook-inl.h",
 164       "$tcmalloc_dir/src/malloc_hook.cc",
 165       "$tcmalloc_dir/src/maybe_threads.cc",
 166       "$tcmalloc_dir/src/maybe_threads.h",
 167       "$tcmalloc_dir/src/memory_region_map.cc",
 168       "$tcmalloc_dir/src/memory_region_map.h",
 169       "$tcmalloc_dir/src/page_heap.cc",
 170       "$tcmalloc_dir/src/page_heap.h",
 171       "$tcmalloc_dir/src/profile-handler.cc",
 172       "$tcmalloc_dir/src/profile-handler.h",
 173       "$tcmalloc_dir/src/profiledata.cc",
 174       "$tcmalloc_dir/src/profiledata.h",
 175       "$tcmalloc_dir/src/profiler.cc",
 176       "$tcmalloc_dir/src/raw_printer.cc",
 177       "$tcmalloc_dir/src/raw_printer.h",
 178       "$tcmalloc_dir/src/sampler.cc",
 179       "$tcmalloc_dir/src/sampler.h",
 180       "$tcmalloc_dir/src/span.cc",
 181       "$tcmalloc_dir/src/span.h",
 182       "$tcmalloc_dir/src/stack_trace_table.cc",
 183       "$tcmalloc_dir/src/stack_trace_table.h",
 184       "$tcmalloc_dir/src/stacktrace.cc",
 185       "$tcmalloc_dir/src/static_vars.cc",
 186       "$tcmalloc_dir/src/static_vars.h",
 187       "$tcmalloc_dir/src/symbolize.cc",
 188       "$tcmalloc_dir/src/symbolize.h",
 189       "$tcmalloc_dir/src/system-alloc.cc",
 190       "$tcmalloc_dir/src/system-alloc.h",
 191
 192       # #included by debugallocation_shim.cc
 193       #"$tcmalloc_dir/src/tcmalloc.cc",
 194       "$tcmalloc_dir/src/thread_cache.cc",
 195       "$tcmalloc_dir/src/thread_cache.h",
 196       "$tcmalloc_dir/src/windows/port.cc",
 197       "$tcmalloc_dir/src/windows/port.h",
 198       "debugallocation_shim.cc",
 199
 200       # These are both #included by allocator_shim for maximal linking.
 201       #"generic_allocators.cc",
 202       #"win_allocator.cc",
 203     ]
 204
 205     # Disable the heap checker in tcmalloc.
 206     defines = [ "NO_HEAP_CHECK" ]
 207
 208     include_dirs = [
 209       ".",
 210       "$tcmalloc_dir/src/base",
 211       "$tcmalloc_dir/src",
 212     ]
 213
 214     configs -= [ "//build/config/compiler:chromium_code" ]
 215     configs += [
 216       "//build/config/compiler:no_chromium_code",
 217       ":tcmalloc_flags",
 218     ]
 219
 220     deps = []
 221
 222     if (is_win) {
 223       sources -= [
 224         "$tcmalloc_dir/src/base/elf_mem_image.cc",
 225         "$tcmalloc_dir/src/base/elf_mem_image.h",
 226         "$tcmalloc_dir/src/base/linuxthreads.cc",
 227         "$tcmalloc_dir/src/base/linuxthreads.h",
 228         "$tcmalloc_dir/src/base/vdso_support.cc",
 229         "$tcmalloc_dir/src/base/vdso_support.h",
 230         "$tcmalloc_dir/src/maybe_threads.cc",
 231         "$tcmalloc_dir/src/maybe_threads.h",
 232         "$tcmalloc_dir/src/symbolize.h",
 233         "$tcmalloc_dir/src/system-alloc.cc",
 234         "$tcmalloc_dir/src/system-alloc.h",
 235
 236         # cpuprofiler
 237         "$tcmalloc_dir/src/base/thread_lister.c",
 238         "$tcmalloc_dir/src/base/thread_lister.h",
 239         "$tcmalloc_dir/src/profile-handler.cc",
 240         "$tcmalloc_dir/src/profile-handler.h",
 241         "$tcmalloc_dir/src/profiledata.cc",
 242         "$tcmalloc_dir/src/profiledata.h",
 243         "$tcmalloc_dir/src/profiler.cc",
 244       ]
 245       defines += [ "PERFTOOLS_DLL_DECL=" ]
 246
 247       configs -= [
 248         # Tcmalloc defines this itself, and we don't want duplicate definition
 249         # warnings.
 250         "//build/config/win:nominmax",
 251       ]
 252
 253       public_configs = [ ":nocmt" ]
 254
 255       deps += [ ":prep_libc" ]
 256     }
 257
 258     if (is_linux || is_android) {
 259       sources -= [
 260         "$tcmalloc_dir/src/system-alloc.h",
 261         "$tcmalloc_dir/src/windows/port.cc",
 262         "$tcmalloc_dir/src/windows/port.h",
 263       ]
 264
 265       # We enable all warnings by default, but upstream disables a few.
 266       # Keep "-Wno-*" flags in sync with upstream by comparing against:
 267       # http://code.google.com/p/google-perftools/source/browse/trunk/Makefile.am
 268       cflags = [
 269         "-Wno-sign-compare",
 270         "-Wno-unused-result",
 271       ]
 272
 273       configs -= [ "//build/config/gcc:symbol_visibility_hidden" ]
 274
 275       ldflags = [
 276         # Don't let linker rip this symbol out, otherwise the heap&cpu
 277         # profilers will not initialize properly on startup.
 278         "-Wl,-uIsHeapProfilerRunning,-uProfilerStart",
 279
 280         # Do the same for heap leak checker.
 281         "-Wl,-u_Z21InitialMallocHook_NewPKvj,-u_Z22InitialMallocHook_MMapPKvS0_jiiix,-u_Z22InitialMallocHook_SbrkPKvi",
 282         "-Wl,-u_Z21InitialMallocHook_NewPKvm,-u_Z22InitialMallocHook_MMapPKvS0_miiil,-u_Z22InitialMallocHook_SbrkPKvl",
 283         "-Wl,-u_ZN15HeapLeakChecker12IgnoreObjectEPKv,-u_ZN15HeapLeakChecker14UnIgnoreObjectEPKv",
 284       ]
 285     }
 286
 287     # Make sure the allocation library is optimized as much as possible when
 288     # we"re in release mode.
 289     if (!is_debug) {
 290       configs -= [ "//build/config/compiler:optimize" ]
 291       configs += [ "//build/config/compiler:optimize_max" ]
 292     }
 293
 294     deps += [ "//base/third_party/dynamic_annotations" ]
 295
 296     if (is_win) {
 297       ldflags = [ "/ignore:4006:4221" ]
 298     }
 299   }
 300 }  # !is_android
 301
 302 source_set("allocator_extension_thunks") {
 303   visibility = [ "//base/*" ]
 304   sources = [
 305     "allocator_extension_thunks.cc",
 306     "allocator_extension_thunks.h",
 307   ]
 308   if (is_android && !is_debug) {
 309     configs -= [ "//build/config/compiler:optimize" ]
 310     configs += [ "//build/config/compiler:optimize_max" ]
 311   }
 312 }