chrome/common/net/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6
   7 # GYP version: chrome/chrome_common.gypi:common_net
   8 static_library("net") {
   9   sources = [
  10     "net_resource_provider.cc",
  11     "net_resource_provider.h",
  12     "x509_certificate_model.cc",
  13     "x509_certificate_model.h",
  14     "x509_certificate_model_nss.cc",
  15     "x509_certificate_model_openssl.cc",
  16   ]
  17
  18   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  19
  20   deps = [
  21     "//base",
  22     "//chrome:resources",
  23     "//chrome:strings",
  24     "//components/url_formatter",
  25     "//crypto",
  26     "//net",
  27     "//net:net_resources",
  28     "//third_party/icu",
  29     "//ui/base",
  30   ]
  31
  32   if (is_ios) {
  33     sources -= [ "net_resource_provider.cc" ]
  34   }
  35
  36   if (is_android || is_ios) {
  37     sources -= [ "x509_certificate_model.cc" ]
  38   }
  39
  40   if (use_openssl_certs && !is_android) {
  41     deps += [ "//third_party/boringssl" ]
  42   } else {
  43     sources -= [ "x509_certificate_model_openssl.cc" ]
  44   }
  45
  46   if (use_nss_certs) {
  47     deps += [ "//crypto:platform" ]
  48   } else {
  49     sources -= [ "x509_certificate_model_nss.cc" ]
  50   }
  51 }