components/version_info/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//chrome/version.gni")
   6
   7 if (is_ios) {
   8   declare_args() {
   9     # Path to the file used to override the version PATH level on iOS.
  10     # Default to ios/build/util/VERSION.
  11     ios_extra_version_path = "//ios/build/util/VERSION"
  12   }
  13 }
  14
  15 source_set("version_info") {
  16   sources = [
  17     "version_info.cc",
  18     "version_info.h",
  19   ]
  20
  21   deps = [
  22     "//base",
  23     "//components/strings",
  24     "//ui/base",
  25     ":generate_version_info",
  26   ]
  27 }
  28
  29 process_version("generate_version_info") {
  30   visibility = [ ":version_info" ]
  31   template_file = "version_info_values.h.version"
  32   output = "$target_gen_dir/version_info_values.h"
  33
  34   if (is_ios) {
  35     # iOS overrides PATCH level of the version with the value from the file
  36     # named by ios_version_path, however, this needs to be the last argument
  37     # to the version.py script, so it cannot be added to the sources variable
  38     # and instead need to be managed manually.
  39
  40     inputs += [ ios_extra_version_path ]
  41     extra_args = [
  42       "-f",
  43       rebase_path(ios_extra_version_path, root_build_dir),
  44     ]
  45   }
  46 }