media/cdm/ppapi/cdm_adapter.gni

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This template defines a CDM adapter target. Just use this as you would a
   6 # normal target and everything should work correctly. If GYP, you would instead
   7 # depend on media/media_cdm_adapter.gyp:cdmadapter which would in turn modify
   8 # your target with direct_dependent_settings.
   9 template("cdm_adapter") {
  10   # TODO(GYP) On Mac/Linux this should be a loadable_module.
  11   shared_library(target_name) {
  12     # Don't filter sources list again.
  13     set_sources_assignment_filter([])
  14     cflags = []
  15     sources = []
  16     ldflags = []
  17     libs = []
  18     forward_variables_from(invoker, "*")
  19
  20     sources += [
  21       "//media/cdm/ppapi/api/content_decryption_module.h",
  22       "//media/cdm/ppapi/cdm_adapter.cc",
  23       "//media/cdm/ppapi/cdm_adapter.h",
  24       "//media/cdm/ppapi/cdm_file_io_impl.cc",
  25       "//media/cdm/ppapi/cdm_file_io_impl.h",
  26       "//media/cdm/ppapi/cdm_helpers.cc",
  27       "//media/cdm/ppapi/cdm_helpers.h",
  28       "//media/cdm/ppapi/cdm_logging.cc",
  29       "//media/cdm/ppapi/cdm_logging.h",
  30       "//media/cdm/ppapi/cdm_wrapper.h",
  31       "//media/cdm/ppapi/linked_ptr.h",
  32       "//media/cdm/ppapi/supported_cdm_versions.h",
  33     ]
  34     if (is_mac) {
  35       ldflags += [
  36         # Not to strip important symbols by -Wl,-dead_strip.
  37         "-Wl,-exported_symbol,_PPP_GetInterface",
  38         "-Wl,-exported_symbol,_PPP_InitializeModule",
  39         "-Wl,-exported_symbol,_PPP_ShutdownModule",
  40       ]
  41       #TODO(GYP) Mac: 'DYLIB_INSTALL_NAME_BASE': '@loader_path',
  42     } else if (is_posix) {
  43       cflags += [ "-fvisibility=hidden" ]
  44
  45       # Required for clock_gettime()
  46       libs += [ "rt" ]
  47     }
  48
  49     # TODO(jschuh) crbug.com/167187
  50     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  51   }
  52 }