remoting/client/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//remoting/remoting_srcs.gni")
   6
   7 source_set("client") {
   8   # Disabled the source filters because there are _mac files that need to
   9   # be compiled on all platforms.
  10   set_sources_assignment_filter([])
  11   sources = rebase_path(remoting_srcs_gypi_values.remoting_client_sources,
  12                         ".",
  13                         "//remoting")
  14   set_sources_assignment_filter(sources_assignment_filter)
  15
  16   configs += [
  17     "//build/config/compiler:wexit_time_destructors",
  18     "//remoting:version",
  19   ]
  20
  21   deps = [
  22     "//remoting/base",
  23     "//remoting/codec",
  24     "//remoting/protocol",
  25     "//third_party/libyuv",
  26     "//third_party/webrtc/modules/desktop_capture:primitives",
  27   ]
  28
  29   if (is_nacl) {
  30     sources -= [
  31       "client_status_logger.cc",
  32       "server_log_entry_client.cc",
  33     ]
  34   }
  35 }
  36
  37 source_set("unit_tests") {
  38   testonly = true
  39
  40   # Disabled the source filters because there are _mac files that need to
  41   # be compiled on all platforms.
  42   set_sources_assignment_filter([])
  43   sources = [
  44     "audio_player_unittest.cc",
  45     "client_status_logger_unittest.cc",
  46     "empty_cursor_filter_unittest.cc",
  47     "key_event_mapper_unittest.cc",
  48     "normalizing_input_filter_cros_unittest.cc",
  49     "normalizing_input_filter_mac_unittest.cc",
  50     "server_log_entry_client_unittest.cc",
  51     "software_video_renderer_unittest.cc",
  52     "touch_input_scaler_unittest.cc",
  53   ]
  54   set_sources_assignment_filter(sources_assignment_filter)
  55
  56   configs += [ "//remoting:version" ]
  57
  58   deps = [
  59     ":client",
  60     "//remoting/proto",
  61     "//testing/gmock",
  62     "//testing/gtest",
  63     "//third_party/webrtc",
  64   ]
  65 }