third_party/minigbm/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/linux/pkg_config.gni")
   6
   7 assert(is_linux)
   8
   9 declare_args() {
  10   # Controls whether the build should use the version of minigbm library
  11   # shipped with the system. In release builds of Chrome OS we use the
  12   # system version, but when building on dev workstations or the Chrome
  13   # waterfall we bundle it because Ubuntu doesn't ship a usable version.
  14   use_system_minigbm = false
  15 }
  16
  17 if (!use_system_minigbm) {
  18   config("minigbm_config") {
  19     include_dirs = [ "src" ]
  20   }
  21
  22   pkg_config("libdrm") {
  23     packages = [ "libdrm" ]
  24   }
  25
  26   static_library("minigbm") {
  27     sources = [
  28       "src/cirrus.c",
  29       "src/exynos.c",
  30       "src/gbm.c",
  31       "src/gma500.c",
  32       "src/helpers.c",
  33       "src/i915.c",
  34       "src/mediatek.c",
  35       "src/rockchip.c",
  36       "src/tegra.c",
  37       "src/udl.c",
  38     ]
  39
  40     configs -= [ "//build/config/compiler:chromium_code" ]
  41     configs += [
  42       ":libdrm",
  43       "//build/config/compiler:no_chromium_code",
  44     ]
  45
  46     public_configs = [ ":minigbm_config" ]
  47   }
  48 }
  49
  50 if (use_system_minigbm) {
  51   pkg_config("libgbm") {
  52     packages = [ "gbm" ]
  53   }
  54
  55   group("minigbm") {
  56     public_configs = [ ":libgbm" ]
  57   }
  58 }