chrome/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//components/nacl/nacl_defines.gni")
   9 # //build/config/android/rules.gni imports //tools/grit/grit_rule.gni, which
  10 # produces a conflict for the "grit" template so we have to only include one.
  11 if (is_android) {
  12   import("//build/config/android/rules.gni")
  13 } else {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16 if (is_desktop_linux) {
  17   import("//build/config/linux/pkg_config.gni")
  18 }
  19
  20 about_credits_file = "$target_gen_dir/about_credits.html"
  21 additional_modules_list_file =
  22     "$root_gen_dir/chrome/browser/internal/additional_modules_list.txt"
  23
  24 gypi_values = exec_script(
  25     "//build/gypi_to_gn.py",
  26     [ rebase_path("../chrome_browser.gypi") ],
  27     "scope",
  28     [ "../chrome_browser.gypi" ])
  29
  30 if (is_desktop_linux) {
  31   pkg_config("gnome_keyring") {
  32     packages = [ "gnome-keyring-1" ]
  33   }
  34 }
  35
  36 static_library("browser") {
  37   configs += [
  38     "//build/config/compiler:wexit_time_destructors",
  39     "//third_party/WebKit/public:debug_devtools",
  40   ]
  41   defines = []
  42   sources = []
  43   libs = []
  44   ldflags = []
  45
  46   # iOS/non-iOS shared deps. New dependencies should generally be added in the
  47   # non-iOS deps below.
  48   public_deps = [
  49     "//components/autofill/core/browser",
  50     "//content/public/browser",
  51     "//sql",
  52     "//sync",
  53   ]
  54   deps = [
  55     "//base/allocator",
  56     "//chrome:extra_resources",
  57     "//chrome:resources",
  58     "//chrome:strings",
  59     "//chrome/app:generated_resources_map",
  60     "//chrome/app/resources:platform_locale_settings",
  61     "//chrome/app/theme:theme_resources",
  62     "//chrome/browser/history:in_memory_url_index_cache_proto",
  63     "//chrome/browser/net:cert_logger_proto",
  64     "//chrome/browser/net:probe_message_proto",
  65     "//chrome/browser/ui",
  66     "//chrome/common",
  67     "//chrome/common/net",
  68     "//components/autofill/core/browser",
  69     "//components/bookmarks/browser",
  70     "//components/captive_portal",
  71     "//components/cloud_devices/common",
  72     "//components/component_updater",
  73     "//components/content_settings/core/browser",
  74     "//components/content_settings/core/common",
  75     "//components/crx_file",
  76     "//components/data_reduction_proxy/core/browser",
  77     "//components/domain_reliability",
  78     "//components/enhanced_bookmarks",
  79     "//components/favicon_base",
  80     "//components/favicon/core",
  81     "//components/feedback",
  82     "//components/gcm_driver",
  83     "//components/google/core/browser",
  84     "//components/history/core/browser",
  85     "//components/history/core/common",
  86     "//components/infobars/core",
  87     "//components/invalidation",
  88     "//components/metrics:gpu",
  89     "//components/metrics:net",
  90     "//components/metrics:profiler",
  91     "//components/metrics/proto:proto",
  92     "//components/navigation_metrics",
  93     "//components/network_time",
  94     "//components/omaha_query_params",
  95     "//components/omnibox",
  96     "//components/os_crypt",
  97     "//components/password_manager/core/browser",
  98     "//components/password_manager/core/common",
  99     "//components/policy:policy_component",
 100     "//components/precache/core",
 101     "//components/query_parser",
 102     "//components/rappor",
 103     "//components/renderer_context_menu",
 104     "//components/search",
 105     "//components/search_engines",
 106     "//components/search_provider_logos",
 107     "//components/signin/core/browser",
 108     "//components/startup_metric_utils",
 109     "//components/strings",
 110     "//components/suggestions",
 111     "//components/sync_driver",
 112     "//components/translate/core/browser",
 113     "//components/translate/core/common",
 114     "//components/url_fixer",
 115     "//components/user_prefs",
 116     "//components/webdata/common",
 117     "//content/public/browser",
 118     "//content/public/common",
 119     "//courgette:courgette_lib",
 120     "//crypto",
 121     "//google_apis",
 122     "//gpu/config",
 123     "//jingle:notifier",
 124     "//skia",
 125     "//sql",
 126     "//sync",
 127     "//third_party/cacheinvalidation",
 128     "//third_party/icu",
 129     "//third_party/libxml",
 130     "//third_party/libjingle",
 131     "//third_party/widevine/cdm:version_h",
 132     "//third_party/zlib",
 133     "//third_party/zlib:minizip",
 134     "//third_party/zlib:zip",
 135     "//ui/base",
 136     "//ui/events",
 137     "//ui/gfx",
 138     "//ui/gfx/geometry",
 139     "//ui/message_center",
 140     "//ui/shell_dialogs",
 141     "//ui/strings",
 142     "//ui/resources",
 143   ]
 144
 145   sources += rebase_path(gypi_values.chrome_browser_undo_sources,
 146                          ".", "//chrome")
 147
 148   if (!is_ios) {
 149     sources += rebase_path(gypi_values.chrome_browser_non_ios_sources,
 150                            ".", "//chrome")
 151     #TODO(GYP) Add these sources:
 152     #        # These files are generated by GRIT.
 153     #        '<(grit_out_dir)/grit/component_extension_resources_map.cc',
 154     #        '<(grit_out_dir)/grit/theme_resources_map.cc',
 155     #        '<(SHARED_INTERMEDIATE_DIR)/ui/resources/grit/ui_resources_map.cc',
 156     #
 157     #        # This file is generated by
 158     #        # chrome/browser/metrics/variations/generate_resources_map.py
 159     #        '<(SHARED_INTERMEDIATE_DIR)/chrome/browser/metrics/variations/generated_resources_map.cc',
 160
 161     defines = nacl_defines
 162
 163     deps += [
 164       "//apps",
 165       "//cc",
 166       "//chrome/browser/devtools",
 167       "//chrome/installer/util",
 168       "//components/autofill/content/browser",
 169       "//components/dom_distiller/content",
 170       "//components/keyed_service/content",
 171       "//components/navigation_interception",
 172       "//components/password_manager/content/browser",
 173       "//components/precache/content",
 174       "//components/sessions",
 175       "//components/storage_monitor",
 176       "//components/translate/content/browser",
 177       "//components/url_matcher",
 178       "//components/visitedlink/browser",
 179       "//components/visitedlink/common",
 180       "//components/web_cache/browser",
 181       "//components/web_modal",
 182       "//content/app/resources",
 183       "//media",
 184       "//media/cast:net",
 185       "//mojo/edk/system",
 186       "//mojo/environment:chromium",
 187       "//mojo/public/cpp/bindings",
 188       "//mojo/public/js/bindings",
 189       "//net:extras",
 190       "//net:net_with_v8",
 191       "//storage/browser",
 192       "//storage/common",
 193       "//third_party/WebKit/public:resources",
 194       "//third_party/expat",
 195       "//third_party/leveldatabase",
 196       "//third_party/libaddressinput",
 197       "//third_party/libyuv",
 198       "//third_party/npapi",
 199       "//third_party/re2",
 200       "//third_party/smhasher:cityhash",
 201       "//third_party/webrtc/modules/desktop_capture",
 202       "//ui/gl",
 203       "//ui/surface",
 204       "//ui/web_dialogs",
 205       "//v8",
 206       ## TODO(tonyg): Remove this dependency (crbug.com/280157).
 207       #"../testing/perf/perf_test.gyp:*",  TODO(GYP)
 208     ]
 209   } else {  # iOS
 210     sources += rebase_path(gypi_values.chrome_browser_ios_sources,
 211                           ".", "//chrome")
 212     deps += [
 213       "//net",
 214     ]
 215     libs += [
 216       "CoreTelephony.framework",
 217       "CoreText.framework",
 218       "MobileCoreServices.framework",
 219       "QuartzCore.framework",
 220     ]
 221     ldflags += [ "-weak_framework", "CoreImage" ]
 222   }
 223
 224   if (is_win || is_mac) {
 225     sources += rebase_path(gypi_values.chrome_browser_win_mac_sources,
 226                            ".", "//chrome")
 227   }
 228   if (!is_android && !is_ios && !is_chromeos && enable_configuration_policy) {
 229     sources += [
 230       "net/disk_cache_dir_policy_handler.cc",
 231       "net/disk_cache_dir_policy_handler.h",
 232     ]
 233   }
 234   if (!is_android && !is_ios && enable_configuration_policy) {
 235     sources += [
 236       "download/download_dir_policy_handler.cc",
 237       "download/download_dir_policy_handler.h",
 238     ]
 239   }
 240   if (is_mac) {
 241     sources += rebase_path(gypi_values.chrome_browser_mac_sources,
 242                            ".", "//chrome")
 243     deps += [
 244       #"app_shim"  TODO(GYP)
 245       #"browser_app_shim"  TODO(GYP)
 246     ]
 247   }
 248   if (cld2_data_source == "component") {
 249     sources += [
 250       "component_updater/cld_component_installer.cc",
 251       "component_updater/cld_component_installer.h",
 252     ]
 253   }
 254   if (enable_extensions) {
 255     public_deps += [ "//chrome/browser/extensions" ]
 256     deps += [
 257       "//chrome/browser/sync_file_system/drive_backend:sync_file_system_drive_proto",
 258       "//chrome/common/extensions/api",
 259       "//chrome/common/extensions/api:api_registration",
 260     ]
 261     sources += rebase_path(gypi_values.chrome_browser_extensions_sources,
 262                            ".", "//chrome")
 263   }
 264   if (enable_background) {
 265     sources += rebase_path(gypi_values.chrome_browser_background_sources,
 266                            ".", "//chrome")
 267     if (!use_aura || is_win) {
 268       sources -= [ "background/background_mode_manager_aura.cc" ]
 269     }
 270   }
 271   if (enable_task_manager) {
 272     sources += rebase_path(gypi_values.chrome_browser_task_manager_sources,
 273                            ".", "//chrome")
 274   }
 275   if (enable_spellcheck) {
 276     sources += rebase_path(gypi_values.chrome_browser_spellchecker_sources,
 277                            ".", "//chrome")
 278     deps += [ "//third_party/hunspell" ]
 279   }
 280   if (enable_nacl) {
 281     sources += rebase_path(gypi_values.chrome_browser_nacl_sources,
 282                            ".", "//chrome")
 283     #deps += [ "//components/nacl:nacl_browser" ]  TODO(GYP)
 284   }
 285
 286   if (enable_configuration_policy) {
 287     sources += rebase_path(
 288         gypi_values.chrome_browser_policy_shared_with_ios_sources,
 289         ".", "//chrome")
 290     deps += [
 291       "//components/policy",
 292       "//components/policy/proto",
 293     ]
 294     if (!is_ios) {
 295       sources += rebase_path(
 296           gypi_values.chrome_browser_policy_non_ios_sources,
 297           ".", "//chrome")
 298     }
 299     if (!is_chromeos) {
 300       sources += rebase_path(
 301           gypi_values.chrome_browser_policy_shared_with_ios_not_chromeos_sources,
 302           ".", "//chrome")
 303     }
 304     if (is_win || is_mac || is_desktop_linux) {
 305       sources += rebase_path(gypi_values.chrome_browser_policy_desktop_sources,
 306                              ".", "//chrome")
 307     }
 308     if (!is_android && !is_ios) {  # Non-mobile
 309       deps += [
 310         "//chrome/browser/policy:path_parser",
 311       ]
 312     }
 313   } else {
 314     # Configuration policy disabled.
 315     sources += rebase_path(gypi_values.chrome_browser_policy_disabled_sources,
 316                            ".", "//chrome")
 317   }
 318
 319   if (enable_plugins) {
 320     sources += rebase_path(gypi_values.chrome_browser_plugins_sources,
 321                            ".", "//chrome")
 322     deps += [
 323       "//components/pdf/browser",
 324       "//ppapi:ppapi_ipc",
 325       "//third_party/adobe/flash:flapper_version_h",
 326     ]
 327   }
 328   if (safe_browsing_mode != 0) {
 329     sources += rebase_path(
 330         gypi_values.chrome_browser_basic_safe_browsing_sources,
 331         ".", "//chrome")
 332     deps += [
 333       "//chrome/browser/safe_browsing:chunk_proto",
 334       "//chrome/browser/safe_browsing:metadata_proto",
 335       "//chrome/browser/safe_browsing:report_proto",
 336     ]
 337     if (safe_browsing_mode == 1) {
 338       sources += rebase_path(
 339           gypi_values.chrome_browser_full_safe_browsing_sources,
 340           ".", "//chrome")
 341       defines += [ "FULL_SAFE_BROWSING" ]
 342       deps += [
 343         "//chrome/common/safe_browsing:proto",
 344       ]
 345     } else if (safe_browsing_mode == 2) {
 346       defines += [ "MOBILE_SAFE_BROWSING" ]
 347     }
 348   }
 349
 350   if (is_linux) {
 351     configs += [ "//build/config/linux:udev" ]
 352     deps += [ "//device/media_transfer_protocol" ]
 353   }
 354   if (is_linux && !is_chromeos) {
 355     deps += [ "//third_party/speech-dispatcher" ]
 356   }
 357
 358   if (is_chromeos) {
 359     sources += rebase_path(gypi_values.chrome_browser_chromeos_sources,
 360                            ".", "//chrome")
 361     deps += [
 362       "//chrome/browser/chromeos",
 363     ]
 364   } else {
 365     # Non-ChromeOS.
 366     sources += rebase_path(gypi_values.chrome_browser_non_chromeos_sources,
 367                            ".", "//chrome")
 368   }
 369
 370   if (is_chromeos || is_ios) {
 371     sources -= [
 372       "metrics/signin_status_metrics_provider.cc",
 373       "metrics/signin_status_metrics_provider.h",
 374     ]
 375   }
 376
 377   if (use_cups) {
 378     configs += [ "//printing:cups" ]
 379   }
 380   if (is_desktop_linux) {
 381     sources += rebase_path(gypi_values.chrome_browser_gnome_keyring_sources,
 382                            ".", "//chrome")
 383     configs += [ ":gnome_keyring" ]
 384   }
 385   if (use_aura) {
 386     sources += rebase_path(gypi_values.chrome_browser_aura_sources,
 387                            ".", "//chrome")
 388     deps += [
 389       "//ui/aura",
 390       "//ui/compositor",
 391       "//ui/keyboard",
 392     ]
 393   }
 394   if (ui_compositor_image_transport) {
 395     deps += [ "//ui/gl" ]
 396   }
 397
 398   if (use_ash) {
 399     sources += rebase_path(gypi_values.chrome_browser_ash_sources,
 400                            ".", "//chrome")
 401   }
 402
 403   if (use_x11) {
 404     sources += rebase_path(gypi_values.chrome_browser_x11_sources,
 405                            ".", "//chrome")
 406     if (!is_chromeos) {
 407       configs += [ "//build/config/linux:xscrnsaver" ]
 408     }
 409   }
 410   if (is_posix && !is_mac && !is_ios) {
 411     sources += [
 412       "//chrome/app/chrome_crash_reporter_client.cc",
 413       "//chrome/app/chrome_crash_reporter_client.h",
 414     ]
 415     deps += [
 416       "//components/crash/app",
 417       "//components/crash/browser",
 418     ]
 419   }
 420   if (use_nss_certs) {
 421     sources += rebase_path(gypi_values.chrome_browser_nss_sources,
 422                            ".", "//chrome")
 423     if (is_chromeos) {
 424       sources -= [ "net/nss_context_linux.cc" ]
 425     }
 426   }
 427   if (enable_notifications) {
 428     sources += rebase_path(gypi_values.chrome_browser_notifications_sources,
 429                            ".", "//chrome")
 430     if (!is_android) {
 431       sources += rebase_path(
 432           gypi_values.chrome_browser_non_android_notifications_sources,
 433           ".", "//chrome")
 434     }
 435   }
 436   if (enable_themes) {
 437     sources += rebase_path(gypi_values.chrome_browser_themes_sources,
 438                            ".", "//chrome")
 439   }
 440
 441   if (printing_mode != 0) {
 442     # Some form of printing support.
 443     sources += rebase_path(gypi_values.chrome_browser_basic_printing_sources,
 444                            ".", "//chrome")
 445     deps += [
 446       "//printing",
 447     ]
 448     if (is_win) {
 449       sources += rebase_path(gypi_values.chrome_browser_printing_emf_sources,
 450                              ".", "//chrome")
 451     }
 452     if (printing_mode == 1) {
 453       # Full printing on top of the above.
 454       sources += rebase_path(gypi_values.chrome_browser_full_printing_sources,
 455                              ".", "//chrome")
 456     } else if (printing_mode == 2) {
 457       # Partial-only printing support.
 458       sources += rebase_path(
 459           gypi_values.chrome_browser_basic_only_printing_sources,
 460           ".", "//chrome")
 461     }
 462   }
 463   if (enable_captive_portal_detection) {
 464     sources += rebase_path(gypi_values.chrome_browser_captive_portal_sources,
 465                            ".", "//chrome")
 466   }
 467   if (enable_session_service) {
 468     sources += rebase_path(gypi_values.chrome_browser_session_service_sources,
 469                            ".", "//chrome")
 470   }
 471
 472   if (is_android || is_ios) {
 473     # Mobile.
 474     sources += rebase_path(gypi_values.chrome_browser_mobile_sources,
 475                            ".", "//chrome")
 476   } else {
 477     # Non-mobile.
 478     sources += rebase_path(gypi_values.chrome_browser_non_mobile_sources,
 479                            ".", "//chrome")
 480     deps += [
 481       "//device/core",
 482       "//device/usb",
 483     ]
 484   }
 485
 486   if (is_android) {
 487     sources += rebase_path(gypi_values.chrome_browser_android_sources,
 488                            ".", "//chrome")
 489     deps += [
 490       ":jni_headers",
 491       "//components/cdm/browser",
 492       #"../components/components.gyp:web_contents_delegate_android",  TODO(GYP)
 493     ]
 494     deps -= [
 495       "//third_party/libaddressinput",
 496       "//components/feedback",
 497       "//components/storage_monitor",
 498       "//components/web_modal",
 499     ]
 500   } else {
 501     sources += rebase_path(gypi_values.chrome_browser_non_android_sources,
 502                            ".", "//chrome")
 503   }
 504
 505   if (is_mac) {
 506     deps += [
 507       "//third_party/google_toolbox_for_mac",
 508       #"../third_party/mozilla/mozilla.gyp:mozilla",  TODO(GYP)
 509     ]
 510     libs += [
 511       "Accelerate.framework",
 512       "AddressBook.framework",
 513       "AudioUnit.framework",
 514       "DiskArbitration.framework",
 515       "IOKit.framework",
 516       "ImageCaptureCore.framework",
 517       "OpenGL.framework",
 518       "QuartzCore.framework",
 519       "SecurityInterface.framework",
 520     ]
 521   }
 522
 523   if (enable_rlz) {
 524     sources += rebase_path(gypi_values.chrome_browser_rlz_sources,
 525                            ".", "//chrome")
 526     deps += [ "//rlz:rlz_lib" ]
 527   }
 528
 529   # TODO(GYP)
 530   # Temporary fix to break the browser target into smaller chunks so it
 531   # will link with goma builds.
 532   #["OS=="win" and chromium_win_pch==0", {
 533   #  "msvs_shard": 4,
 534   #}],
 535
 536   if (is_win) {
 537     sources += rebase_path(gypi_values.chrome_browser_win_sources,
 538                            ".", "//chrome")
 539     public_deps += [
 540       "//ui/views",
 541       "//ui/views/controls/webview",
 542     ]
 543     deps += [
 544       "//chrome:version_header",
 545       "//chrome/installer/util:strings",
 546       "//third_party/iaccessible2",
 547       "//third_party/isimpledom",
 548       "//third_party/wtl",
 549       #"chrome_process_finder",  TODO(GYP)
 550       #"../chrome_elf/chrome_elf.gyp:chrome_elf",  TODO(GYP)
 551       #"../chrome_elf/chrome_elf.gyp:chrome_elf_constants",  TODO(GYP)
 552       #"../chrome_elf/chrome_elf.gyp:dll_hash",  TODO(GYP)
 553       #"../google_update/google_update.gyp:google_update",  TODO(GYP)
 554       #"../ui/metro_viewer/metro_viewer.gyp:metro_viewer_messages",  TODO(GYP)
 555       #"../win8/win8.gyp:metro_viewer",  TODO(GYP)
 556     ]
 557   } else {
 558     # Non-Windows.
 559     sources += rebase_path(gypi_values.chrome_browser_non_win_sources,
 560                            ".", "//chrome")
 561     if (toolkit_views) {
 562       deps += [
 563       "//ui/views",
 564       "//ui/views/controls/webview",
 565       ]
 566       # TODO(GYP) why is this needed? Very susicious.
 567       #  "include_dirs": [
 568       #    "<(INTERMEDIATE_DIR)/chrome",
 569       #  ],
 570     }
 571   }
 572
 573   if (is_linux) {
 574     sources += rebase_path(gypi_values.chrome_browser_linux_sources,
 575                            ".", "//chrome")
 576     if (use_aura) {
 577       configs += [
 578         "//build/config/linux:dbus",
 579         "//build/config/linux:fontconfig",
 580       ]
 581       deps += [
 582         "//dbus",
 583       ]
 584     }
 585     if (use_x11) {
 586       configs += [ "//build/config/linux:x11" ]
 587       deps += [ "//ui/gfx/x" ]
 588     }
 589   }
 590
 591   if (is_desktop_linux) {
 592     sources += rebase_path(gypi_values.chrome_browser_desktop_linux_sources,
 593                            ".", "//chrome")
 594   }
 595   if (enable_plugin_installation) {
 596     sources += rebase_path(
 597         gypi_values.chrome_browser_plugin_installation_sources,
 598         ".", "//chrome")
 599   }
 600   if (enable_app_list) {
 601     deps += [
 602       "//ui/app_list",
 603     ]
 604   }
 605   if (enable_managed_users) {
 606     sources += rebase_path(
 607         gypi_values.chrome_browser_supervised_user_sources,
 608         ".", "//chrome")
 609   }
 610   if (enable_webrtc) {
 611     sources += rebase_path(
 612         gypi_values.chrome_browser_webrtc_sources,
 613         ".", "//chrome")
 614   }
 615   if (enable_service_discovery) {
 616     sources += rebase_path(
 617         gypi_values.chrome_browser_service_discovery_sources,
 618         ".", "//chrome")
 619   }
 620   if (enable_mdns) {
 621     sources += rebase_path(
 622         gypi_values.chrome_browser_mdns_sources,
 623         ".", "//chrome")
 624   }
 625   if (!enable_autofill_dialog || is_android || is_ios) {
 626     sources -= [
 627       "autofill/validation_rules_storage_factory.cc",
 628       "autofill/validation_rules_storage_factory.h",
 629     ]
 630   }
 631   if (enable_wifi_bootstrapping) {
 632     sources += rebase_path(
 633         gypi_values.chrome_browser_wifi_bootstrapping_sources,
 634         ".", "//chrome")
 635     if (is_win || is_mac) {
 636       # TODO(brettw) as of this writing wifi bootstrapping is set on Windows
 637       # and Mac, so this test is meaningless. Can we merge these lists?
 638       sources += rebase_path(
 639           gypi_values.chrome_browser_win_mac_wifi_bootstrapping_sources,
 640           ".", "//chrome")
 641     }
 642   }
 643 }
 644
 645 if (is_android) {
 646   # GYP version: chrome/chrome_browser.gypi:chrome_browser_jni_headers
 647   generate_jni("jni_headers") {
 648     sources = rebase_path(
 649         gypi_values.chrome_browser_jni_sources, ".", "//chrome")
 650     jni_package = "chrome"
 651   }
 652 }
 653
 654 # GYP version: chrome/chrome_resources.gyp:chrome_resources
 655 # (generate_browser_resources action)
 656 grit("resources") {
 657   source = "browser_resources.grd"
 658   output_dir = "$root_gen_dir/chrome"
 659   outputs = [
 660     "grit/browser_resources.h",
 661     "browser_resources.pak",
 662   ]
 663
 664   omnibox_mojom_file = "$root_gen_dir/chrome/browser/ui/webui/omnibox/omnibox.mojom.js"
 665
 666   grit_flags = [
 667     "-E", "about_credits_file=" +
 668           rebase_path(about_credits_file, root_build_dir),
 669     "-E", "additional_modules_list_file=" +
 670           rebase_path(additional_modules_list_file, root_build_dir),
 671     "-E", "omnibox_mojom_file=" +
 672           rebase_path(omnibox_mojom_file, root_build_dir),
 673   ]
 674
 675   deps = [
 676     ":about_credits",
 677     ":chrome_internal_resources_gen",
 678     "//chrome/browser/ui/webui/omnibox:mojo_bindings",
 679     "//mojo/environment:chromium",
 680   ]
 681 }
 682
 683 # GYP version: chrome/chrome_resource.gyp:about_credits
 684 action("about_credits") {
 685   script = "//tools/licenses.py"
 686
 687   # TODO(phajdan.jr): input dependencies so this can be regenerated
 688   # automatically when one of the credits changes. The way this should work is
 689   # that licenses.py should write a .d file listing the input dependencies (see
 690   # "depfile" in GN).
 691   outputs = [ about_credits_file ]
 692
 693   args = [
 694     "credits",
 695     rebase_path(about_credits_file, root_build_dir),
 696   ]
 697 }
 698
 699 # GYP version: chrome/chrome_resource.gyp:chrome_internal_resources_gen
 700 if (is_chrome_branded) {
 701   action("chrome_internal_resources_gen") {
 702     script = "internal/transform_additional_modules_list.py"
 703     sources = [ "internal/resources/additional_modules_list.input" ]
 704     outputs = [ additional_modules_list_file ]
 705     args = rebase_path(sources, root_build_dir) +
 706            rebase_path(outputs, root_build_dir)
 707   }
 708 } else {
 709   group("chrome_internal_resources_gen") {
 710     # Empty placeholder.
 711   }
 712 }
 713
 714 # In GYP this is part of test_support_common.
 715 source_set("test_support") {
 716   testonly = true
 717
 718   # Always include this via the main test support target.
 719   visibility = [ "//chrome/test:test_support" ]
 720
 721   sources = [
 722     "browsing_data/mock_browsing_data_appcache_helper.cc",
 723     "browsing_data/mock_browsing_data_appcache_helper.h",
 724     "browsing_data/mock_browsing_data_channel_id_helper.cc",
 725     "browsing_data/mock_browsing_data_channel_id_helper.h",
 726     "browsing_data/mock_browsing_data_cookie_helper.cc",
 727     "browsing_data/mock_browsing_data_cookie_helper.h",
 728     "browsing_data/mock_browsing_data_database_helper.cc",
 729     "browsing_data/mock_browsing_data_database_helper.h",
 730     "browsing_data/mock_browsing_data_file_system_helper.cc",
 731     "browsing_data/mock_browsing_data_file_system_helper.h",
 732     "browsing_data/mock_browsing_data_flash_lso_helper.cc",
 733     "browsing_data/mock_browsing_data_flash_lso_helper.h",
 734     "browsing_data/mock_browsing_data_indexed_db_helper.cc",
 735     "browsing_data/mock_browsing_data_indexed_db_helper.h",
 736     "browsing_data/mock_browsing_data_local_storage_helper.cc",
 737     "browsing_data/mock_browsing_data_local_storage_helper.h",
 738     "browsing_data/mock_browsing_data_quota_helper.cc",
 739     "browsing_data/mock_browsing_data_quota_helper.h",
 740     "browsing_data/mock_browsing_data_service_worker_helper.cc",
 741     "browsing_data/mock_browsing_data_service_worker_helper.h",
 742     "download/download_test_file_activity_observer.cc",
 743     "download/download_test_file_activity_observer.h",
 744     "download/test_download_shelf.cc",
 745     "download/test_download_shelf.h",
 746     "extensions/extension_action_test_util.cc",
 747     "extensions/extension_action_test_util.h",
 748     "invalidation/fake_invalidation_service.cc",
 749     "invalidation/fake_invalidation_service.h",
 750     "media/fake_desktop_media_list.cc",
 751     "media/fake_desktop_media_list.h",
 752     "net/dns_probe_test_util.cc",
 753     "net/dns_probe_test_util.h",
 754     "net/url_request_mock_util.cc",
 755     "net/url_request_mock_util.h",
 756     "notifications/notification_test_util.cc",
 757     "notifications/notification_test_util.h",
 758     "password_manager/mock_password_store_service.cc",
 759     "password_manager/mock_password_store_service.h",
 760     "password_manager/null_password_store_service.cc",
 761     "password_manager/null_password_store_service.h",
 762     "password_manager/test_password_store_service.cc",
 763     "password_manager/test_password_store_service.h",
 764     "prefs/pref_service_mock_factory.cc",
 765     "prefs/pref_service_mock_factory.h",
 766     "profile_resetter/profile_resetter_test_base.cc",
 767     "profile_resetter/profile_resetter_test_base.h",
 768     "search_engines/template_url_service_factory_test_util.cc",
 769     "search_engines/template_url_service_factory_test_util.h",
 770     "search_engines/template_url_service_test_util.cc",
 771     "search_engines/template_url_service_test_util.h",
 772     "sessions/session_service_test_helper.cc",
 773     "sessions/session_service_test_helper.h",
 774     "signin/fake_account_reconcilor.cc",
 775     "signin/fake_account_reconcilor.h",
 776     "signin/fake_account_tracker_service.cc",
 777     "signin/fake_account_tracker_service.h",
 778     "signin/fake_profile_oauth2_token_service.cc",
 779     "signin/fake_profile_oauth2_token_service.h",
 780     "signin/fake_profile_oauth2_token_service_builder.cc",
 781     "signin/fake_profile_oauth2_token_service_builder.h",
 782     "signin/fake_signin_manager.cc",
 783     "signin/fake_signin_manager.h",
 784     "ssl/ssl_client_auth_requestor_mock.cc",
 785     "ssl/ssl_client_auth_requestor_mock.h",
 786     "sync/profile_sync_components_factory_mock.cc",
 787     "sync/profile_sync_components_factory_mock.h",
 788     "sync/profile_sync_service_mock.cc",
 789     "sync/profile_sync_service_mock.h",
 790   ]
 791
 792   public_deps = [
 793     ":browser",
 794     "//chrome/browser/ui:test_support",
 795   ]
 796   deps = [
 797     "//base:prefs_test_support",
 798     "//chrome/browser",
 799     "//chrome/common",
 800     "//chrome/common/safe_browsing:proto",
 801     "//components/invalidation",
 802     "//components/invalidation:test_support",
 803     "//components/password_manager/core/browser:test_support",
 804     "//components/search_engines:test_support",
 805     "//content/test:test_support",
 806     "//chrome/app/theme:theme_resources",
 807     "//net:test_support",
 808     "//skia",
 809     "//testing/gmock",
 810     "//testing/gtest",
 811     "//ui/gfx",
 812   ]
 813
 814   if (!is_ios) {
 815     deps += [
 816       "//components/sessions:test_support",
 817       "//google_apis:test_support",
 818     ]
 819   }
 820
 821   if (enable_extensions) {
 822     deps += [
 823       "//extensions:test_support",
 824     ]
 825   }
 826
 827   if (is_chromeos) {
 828     sources += [
 829       "chromeos/app_mode/fake_cws.cc",
 830       "chromeos/app_mode/fake_cws.h",
 831       "chromeos/file_manager/fake_disk_mount_manager.cc",
 832       "chromeos/file_manager/fake_disk_mount_manager.h",
 833       "chromeos/input_method/mock_candidate_window_controller.cc",
 834       "chromeos/input_method/mock_candidate_window_controller.h",
 835       "chromeos/input_method/mock_input_method_engine.cc",
 836       "chromeos/input_method/mock_input_method_engine.h",
 837       "chromeos/input_method/mock_input_method_manager.cc",
 838       "chromeos/input_method/mock_input_method_manager.h",
 839       "chromeos/login/fake_login_utils.cc",
 840       "chromeos/login/fake_login_utils.h",
 841       "chromeos/login/mock_login_utils.cc",
 842       "chromeos/login/mock_login_utils.h",
 843       "chromeos/login/users/avatar/mock_user_image_manager.cc",
 844       "chromeos/login/users/avatar/mock_user_image_manager.h",
 845       "chromeos/login/users/fake_supervised_user_manager.cc",
 846       "chromeos/login/users/fake_supervised_user_manager.h",
 847       "chromeos/login/users/fake_user_manager.cc",
 848       "chromeos/login/users/fake_user_manager.h",
 849       "chromeos/login/users/mock_user_manager.cc",
 850       "chromeos/login/users/mock_user_manager.h",
 851       "chromeos/login/test/oobe_screen_waiter.cc",
 852       "chromeos/login/test/oobe_screen_waiter.h",
 853       "chromeos/login/test/js_checker.cc",
 854       "chromeos/login/test/js_checker.h",
 855       "chromeos/login/ui/mock_login_display.cc",
 856       "chromeos/login/ui/mock_login_display.h",
 857       "chromeos/login/ui/mock_login_display_host.cc",
 858       "chromeos/login/ui/mock_login_display_host.h",
 859       "chromeos/net/network_portal_detector_test_utils.cc",
 860       "chromeos/net/network_portal_detector_test_utils.h",
 861       "chromeos/policy/cloud_external_data_manager_base_test_util.cc",
 862       "chromeos/policy/cloud_external_data_manager_base_test_util.h",
 863       "chromeos/policy/device_policy_builder.cc",
 864       "chromeos/policy/device_policy_builder.h",
 865       "chromeos/policy/fake_device_cloud_policy_initializer.cc",
 866       "chromeos/policy/fake_device_cloud_policy_initializer.h",
 867       "chromeos/policy/stub_enterprise_install_attributes.cc",
 868       "chromeos/policy/stub_enterprise_install_attributes.h",
 869       "chromeos/settings/device_settings_test_helper.cc",
 870       "chromeos/settings/device_settings_test_helper.h",
 871       "chromeos/system/fake_input_device_settings.cc",
 872       "chromeos/system/fake_input_device_settings.h",
 873     ]
 874     configs += [ "//build/config/linux:dbus" ]
 875     deps += [ "//chromeos:test_support" ]
 876   }
 877
 878   if (enable_configuration_policy) {
 879     sources += [
 880       "policy/test/local_policy_test_server.cc",
 881       "policy/test/local_policy_test_server.h",
 882     ]
 883     public_deps += [
 884       "//components/policy:policy_component_test_support",
 885       "//components/policy:test_support",
 886     ]
 887   }
 888
 889   if (safe_browsing_mode == 1) {
 890     sources += [
 891       "extensions/fake_safe_browsing_database_manager.cc",
 892       "extensions/fake_safe_browsing_database_manager.h",
 893     ]
 894   }
 895
 896   if (enable_extensions) {
 897     sources += [
 898       "drive/dummy_drive_service.cc",
 899       "drive/dummy_drive_service.h",
 900       "drive/fake_drive_service.cc",
 901       "drive/fake_drive_service.h",
 902       "drive/test_util.cc",
 903       "drive/test_util.h",
 904       "extensions/api/messaging/native_messaging_test_util.cc",
 905       "extensions/api/messaging/native_messaging_test_util.h",
 906       "extensions/extension_notification_observer.cc",
 907       "extensions/extension_notification_observer.h",
 908       "extensions/mock_extension_special_storage_policy.cc",
 909       "extensions/mock_extension_special_storage_policy.h",
 910       "extensions/test_blacklist.cc",
 911       "extensions/test_blacklist.h",
 912       "extensions/test_blacklist_state_fetcher.cc",
 913       "extensions/test_blacklist_state_fetcher.h",
 914       "extensions/test_extension_environment.cc",
 915       "extensions/test_extension_environment.h",
 916       "extensions/test_extension_prefs.cc",
 917       "extensions/test_extension_prefs.h",
 918       "extensions/test_extension_service.cc",
 919       "extensions/test_extension_service.h",
 920       "extensions/test_extension_system.cc",
 921       "extensions/test_extension_system.h",
 922       "media_galleries/media_galleries_test_util.cc",
 923       "media_galleries/media_galleries_test_util.h",
 924     ]
 925     deps += [
 926       "//components/storage_monitor:test_support",
 927     ]
 928   }
 929
 930   if (enable_mdns) {
 931     sources += [
 932       "local_discovery/test_service_discovery_client.cc",
 933       "local_discovery/test_service_discovery_client.h",
 934     ]
 935   }
 936
 937   if (enable_app_list) {
 938     sources += [
 939       "ui/app_list/test/chrome_app_list_test_support.cc",
 940       "ui/app_list/test/chrome_app_list_test_support.h",
 941     ]
 942   }
 943
 944   if (enable_wifi_bootstrapping) {
 945     sources += [
 946       "local_discovery/wifi/mock_wifi_manager.cc",
 947       "local_discovery/wifi/mock_wifi_manager.h",
 948     ]
 949   }
 950 }