courgette/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//testing/test.gni")
   6
   7 static_library("courgette_lib") {
   8   sources = [
   9     "adjustment_method.cc",
  10     "adjustment_method.h",
  11     "adjustment_method_2.cc",
  12     "assembly_program.cc",
  13     "assembly_program.h",
  14     "courgette.h",
  15     "crc.cc",
  16     "crc.h",
  17     "difference_estimator.cc",
  18     "difference_estimator.h",
  19     "disassembler.cc",
  20     "disassembler.h",
  21     "disassembler_elf_32.cc",
  22     "disassembler_elf_32.h",
  23     "disassembler_elf_32_arm.cc",
  24     "disassembler_elf_32_arm.h",
  25     "disassembler_elf_32_x86.cc",
  26     "disassembler_elf_32_x86.h",
  27     "disassembler_win32_x64.cc",
  28     "disassembler_win32_x64.h",
  29     "disassembler_win32_x86.cc",
  30     "disassembler_win32_x86.h",
  31     "encoded_program.cc",
  32     "encoded_program.h",
  33     "ensemble.cc",
  34     "ensemble.h",
  35     "ensemble_apply.cc",
  36     "ensemble_create.cc",
  37     "memory_allocator.cc",
  38     "memory_allocator.h",
  39     "patch_generator_x86_32.h",
  40     "patcher_x86_32.h",
  41     "region.h",
  42     "simple_delta.cc",
  43     "simple_delta.h",
  44     "streams.cc",
  45     "streams.h",
  46     "third_party/bsdiff.h",
  47     "third_party/bsdiff_apply.cc",
  48     "third_party/bsdiff_create.cc",
  49     "third_party/paged_array.h",
  50     "types_elf.h",
  51     "types_win_pe.h",
  52   ]
  53
  54   deps = [
  55     "//base",
  56     "//third_party/lzma_sdk",
  57   ]
  58 }
  59
  60 executable("courgette") {
  61   if (is_win && current_cpu == "x64") {
  62     # The build infrastructure needs courgette to be named courgette64.
  63     output_name = "courgette64"
  64   }
  65
  66   sources = [
  67     "courgette_tool.cc",
  68   ]
  69
  70   if (is_win) {
  71     ldflags = [ "/LARGEADDRESSAWARE" ]
  72   }
  73
  74   deps = [
  75     ":courgette_lib",
  76     "//base",
  77   ]
  78 }
  79
  80 executable("courgette_minimal_tool") {
  81   sources = [
  82     "courgette_minimal_tool.cc",
  83   ]
  84
  85   deps = [
  86     ":courgette_lib",
  87     "//base",
  88   ]
  89 }
  90
  91 test("courgette_unittests") {
  92   sources = [
  93     "adjustment_method_unittest.cc",
  94     "base_test_unittest.cc",
  95     "base_test_unittest.h",
  96     "bsdiff_memory_unittest.cc",
  97     "difference_estimator_unittest.cc",
  98     "disassembler_elf_32_x86_unittest.cc",
  99     "disassembler_win32_x64_unittest.cc",
 100     "disassembler_win32_x86_unittest.cc",
 101     "encode_decode_unittest.cc",
 102     "encoded_program_unittest.cc",
 103     "ensemble_unittest.cc",
 104     "memory_allocator_unittest.cc",
 105     "streams_unittest.cc",
 106     "third_party/paged_array_unittest.cc",
 107     "typedrva_unittest.cc",
 108     "versioning_unittest.cc",
 109   ]
 110
 111   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 112   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 113
 114   deps = [
 115     ":courgette_lib",
 116     "//base",
 117     "//base:i18n",
 118     "//base/allocator",
 119     "//base/test:run_all_unittests",
 120     "//base/test:test_support",
 121     "//testing/gtest",
 122   ]
 123 }
 124
 125 test("courgette_fuzz") {
 126   sources = [
 127     "base_test_unittest.cc",
 128     "base_test_unittest.h",
 129     "encoded_program_fuzz_unittest.cc",
 130   ]
 131   deps = [
 132     ":courgette_lib",
 133     "//base",
 134     "//base:i18n",
 135     "//base/test:test_support",
 136     "//testing/gtest",
 137   ]
 138 }