ppapi/native_client/src/untrusted/pnacl_irt_shim/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(is_nacl,
   6        "These targets must only be built using the untrusted NaCl toolchains.")
   7
   8 # We need to actually ship this library in the SDK.
   9 static_library("aot") {
  10   output_name = "pnacl_irt_shim"
  11   sources = [
  12     "irt_shim_ppapi.c",
  13     "pnacl_shim.c",
  14     "shim_entry.c",
  15     "shim_ppapi.c",
  16   ]
  17
  18   # Indicate that this variant of the shim library should not depend on
  19   # the unstable/private IRT hook interface.
  20   defines = [ "PNACL_SHIM_AOT" ]
  21 }
  22
  23 # We need to actually ship this library with component updater.
  24 # TODO(jvoung): Also strip-debug to keep the size of this down,
  25 # though it is only 14KB with debug info, so not a high priority.
  26 static_library("browser") {
  27   # Use a different name from the AOT variant. Have the
  28   # pnacl_support_extension rename this to the canonical name when
  29   # copying to the final target directory.
  30   output_name = "pnacl_irt_shim_browser"
  31   sources = [
  32     "shim_entry.c",
  33     "shim_ppapi.c",
  34   ]
  35 }
  36
  37 # This is an intermediate "library" that gets linked into the IRT
  38 # executable, so this can just be a source_set.
  39 source_set("irt") {
  40   sources = [
  41     "irt_shim_ppapi.c",
  42     "pnacl_shim.c",
  43   ]
  44 }