device/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/rules.gni")  # For generate_jni().
  10 }
  11
  12 if (is_mac) {
  13   import("//build/config/mac/mac_sdk.gni")
  14 }
  15
  16 is_linux_without_udev = is_linux && !use_udev
  17 is_linux_without_dbus = is_linux && !use_dbus
  18
  19 # TODO(GYP): Delete this after we've converted everything to GN.
  20 # The _run targets exist only for compatibility w/ GYP.
  21 group("device_unittests_run") {
  22   testonly = true
  23   deps = [
  24     ":device_unittests",
  25   ]
  26 }
  27
  28 test("device_unittests") {
  29   sources = [
  30     "battery/battery_status_manager_win_unittest.cc",
  31     "battery/battery_status_service_unittest.cc",
  32     "bluetooth/bluetooth_adapter_mac_unittest.mm",
  33     "bluetooth/bluetooth_adapter_profile_chromeos_unittest.cc",
  34     "bluetooth/bluetooth_adapter_unittest.cc",
  35     "bluetooth/bluetooth_adapter_win_unittest.cc",
  36     "bluetooth/bluetooth_advertisement_chromeos_unittest.cc",
  37     "bluetooth/bluetooth_audio_sink_chromeos_unittest.cc",
  38     "bluetooth/bluetooth_chromeos_unittest.cc",
  39     "bluetooth/bluetooth_device_unittest.cc",
  40     "bluetooth/bluetooth_device_win_unittest.cc",
  41     "bluetooth/bluetooth_discovery_filter_unittest.cc",
  42     "bluetooth/bluetooth_gatt_chromeos_unittest.cc",
  43     "bluetooth/bluetooth_low_energy_win_unittest.cc",
  44     "bluetooth/bluetooth_service_record_win_unittest.cc",
  45     "bluetooth/bluetooth_socket_chromeos_unittest.cc",
  46     "bluetooth/bluetooth_task_manager_win_unittest.cc",
  47     "bluetooth/bluetooth_uuid_unittest.cc",
  48     "bluetooth/test/bluetooth_test.cc",
  49     "bluetooth/test/bluetooth_test.h",
  50     "bluetooth/test/bluetooth_test_android.cc",
  51     "bluetooth/test/bluetooth_test_android.h",
  52     "bluetooth/test/bluetooth_test_mac.h",
  53     "bluetooth/test/bluetooth_test_mac.mm",
  54     "bluetooth/test/test_bluetooth_adapter_observer.cc",
  55     "bluetooth/test/test_bluetooth_adapter_observer.h",
  56     "nfc/nfc_chromeos_unittest.cc",
  57     "nfc/nfc_ndef_record_unittest.cc",
  58     "test/run_all_unittests.cc",
  59   ]
  60
  61   deps = [
  62     "//base/test:test_support",
  63     "//device/battery",
  64     "//device/battery:mojo_bindings",
  65     "//device/bluetooth",
  66     "//device/nfc",
  67     "//mojo/environment:chromium",
  68     "//net",
  69     "//testing/gmock",
  70     "//testing/gtest",
  71     "//third_party/mojo/src/mojo/edk/system",
  72     "//third_party/mojo/src/mojo/public/cpp/bindings",
  73     "//url",
  74   ]
  75
  76   if (!is_linux_without_dbus && !is_chromeos) {
  77     sources += [ "battery/battery_status_manager_linux_unittest.cc" ]
  78   }
  79
  80   # HID and Serial:
  81   # Android doesn't compile.
  82   # Linux, requires udev.
  83   if (!is_linux_without_udev && !is_android) {
  84     sources += [
  85       "hid/hid_connection_unittest.cc",
  86       "hid/hid_device_filter_unittest.cc",
  87       "hid/hid_report_descriptor_unittest.cc",
  88       "hid/input_service_linux_unittest.cc",
  89       "hid/test_report_descriptors.cc",
  90       "hid/test_report_descriptors.h",
  91       "serial/data_sink_unittest.cc",
  92       "serial/data_source_unittest.cc",
  93       "serial/serial_connection_unittest.cc",
  94       "serial/serial_io_handler_posix_unittest.cc",
  95       "serial/serial_service_unittest.cc",
  96     ]
  97     deps += [
  98       "//device/hid",
  99       "//device/serial",
 100       "//device/serial:test_support",
 101     ]
 102   }
 103
 104   if (use_udev) {
 105     sources += [ "udev_linux/udev_unittest.cc" ]
 106     deps += [ "//device/udev_linux" ]
 107   }
 108
 109   # USB does not compile on mobile platforms.
 110   if (!is_android && !is_ios) {
 111     sources += [
 112       "devices_app/usb/device_impl_unittest.cc",
 113       "devices_app/usb/device_manager_impl_unittest.cc",
 114       "test/usb_test_gadget_impl.cc",
 115       "usb/usb_context_unittest.cc",
 116       "usb/usb_descriptors_unittest.cc",
 117       "usb/usb_device_filter_unittest.cc",
 118       "usb/usb_device_handle_unittest.cc",
 119       "usb/usb_ids_unittest.cc",
 120       "usb/usb_service_unittest.cc",
 121       "usb/webusb_descriptors_unittest.cc",
 122     ]
 123     deps += [
 124       "//device/core",
 125       "//device/devices_app:lib",
 126       "//device/devices_app/usb/public/cpp",
 127       "//device/devices_app/usb/public/interfaces",
 128       "//device/usb",
 129       "//device/usb:mocks",
 130       "//third_party/libusb",
 131     ]
 132   }
 133
 134   if (is_android) {
 135     deps += [ ":bluetooth_test_jni_headers" ]
 136     apk_deps = [ ":bluetooth_test_java" ]
 137   }
 138
 139   if (is_chromeos) {
 140     configs += [ "//build/config/linux:dbus" ]
 141
 142     deps += [
 143       "//chromeos",
 144       "//chromeos:test_support",
 145       "//chromeos:test_support_without_gmock",
 146       "//dbus",
 147     ]
 148   }
 149
 150   if (is_posix && !is_android && !is_mac) {
 151     libs = [ "rt" ]
 152   }
 153
 154   if (is_mac) {
 155     deps += [ "//third_party/ocmock" ]
 156     ldflags = [ "-ObjC" ]
 157     libs = [ "IOBluetooth.framework" ]
 158
 159     # In the OSX 10.10 SDK, CoreBluetooth became a top level framework.
 160     # Previously, it was nested in IOBluetooth. In order for Chrome to run on
 161     # OSes older than OSX 10.10, the top level CoreBluetooth framework must be
 162     # weakly linked.
 163     if (mac_sdk_version == "10.10") {
 164       ldflags += [ "-weak_framework CoreBluetooth" ]
 165     }
 166   }
 167 }
 168
 169 if (is_android) {
 170   bluetooth_java_sources_needing_jni = [ "bluetooth/test/android/java/src/org/chromium/device/bluetooth/Fakes.java" ]
 171
 172   generate_jni("bluetooth_test_jni_headers") {
 173     sources = bluetooth_java_sources_needing_jni
 174     jni_package = "bluetooth"
 175   }
 176
 177   android_library("bluetooth_test_java") {
 178     java_files = bluetooth_java_sources_needing_jni
 179     deps = [
 180       "//base:base_java",
 181       "//device/bluetooth:java",
 182     ]
 183   }
 184 }