base/native_library_mac.mm

   1 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "base/native_library.h"
   6
   7 #include <dlfcn.h>
   8 #include <mach-o/getsect.h>
   9
  10 #include "base/file_util.h"
  11 #include "base/files/file_path.h"
  12 #include "base/logging.h"
  13 #include "base/mac/scoped_cftyperef.h"
  14 #include "base/strings/string_util.h"
  15 #include "base/strings/utf_string_conversions.h"
  16 #include "base/threading/thread_restrictions.h"
  17
  18 namespace base {
  19
  20 static NativeLibraryObjCStatus GetObjCStatusForImage(
  21     const void* function_pointer) {
  22   Dl_info info;
  23   if (!dladdr(function_pointer, &info))
  24     return OBJC_UNKNOWN;
  25
  26   // See if the the image contains an "ObjC image info" segment. This method
  27   // of testing is used in _CFBundleGrokObjcImageInfoFromFile in
  28   // CF-744/CFBundle.c, around lines 2447-2474.
  29   //
  30   // In 32-bit images, ObjC can be recognized in __OBJC,__image_info, whereas
  31   // in 64-bit, the data is in __DATA,__objc_imageinfo.
  32 #if __LP64__
  33   const section_64* section = getsectbynamefromheader_64(
  34       reinterpret_cast<const struct mach_header_64*>(info.dli_fbase),
  35       SEG_DATA, "__objc_imageinfo");
  36 #else
  37   const section* section = getsectbynamefromheader(
  38       reinterpret_cast<const struct mach_header*>(info.dli_fbase),
  39       SEG_OBJC, "__image_info");
  40 #endif
  41   return section == NULL ? OBJC_NOT_PRESENT : OBJC_PRESENT;
  42 }
  43
  44 std::string NativeLibraryLoadError::ToString() const {
  45   return message;
  46 }
  47
  48 // static
  49 // TODO(xhwang): Fill |error|. See http://crbug.com/353771
  50 NativeLibrary LoadNativeLibrary(const base::FilePath& library_path,
  51                                 NativeLibraryLoadError* /* error */) {
  52   // dlopen() etc. open the file off disk.
  53   if (library_path.Extension() == "dylib" || !DirectoryExists(library_path)) {
  54     void* dylib = dlopen(library_path.value().c_str(), RTLD_LAZY);
  55     if (!dylib)
  56       return NULL;
  57     NativeLibrary native_lib = new NativeLibraryStruct();
  58     native_lib->type = DYNAMIC_LIB;
  59     native_lib->dylib = dylib;
  60     native_lib->objc_status = OBJC_UNKNOWN;
  61     return native_lib;
  62   }
  63   base::ScopedCFTypeRef<CFURLRef> url(CFURLCreateFromFileSystemRepresentation(
  64       kCFAllocatorDefault,
  65       (const UInt8*)library_path.value().c_str(),
  66       library_path.value().length(),
  67       true));
  68   if (!url)
  69     return NULL;
  70   CFBundleRef bundle = CFBundleCreate(kCFAllocatorDefault, url.get());
  71   if (!bundle)
  72     return NULL;
  73
  74   NativeLibrary native_lib = new NativeLibraryStruct();
  75   native_lib->type = BUNDLE;
  76   native_lib->bundle = bundle;
  77   native_lib->bundle_resource_ref = CFBundleOpenBundleResourceMap(bundle);
  78   native_lib->objc_status = OBJC_UNKNOWN;
  79   return native_lib;
  80 }
  81
  82 // static
  83 void UnloadNativeLibrary(NativeLibrary library) {
  84   if (library->objc_status == OBJC_NOT_PRESENT) {
  85     if (library->type == BUNDLE) {
  86       CFBundleCloseBundleResourceMap(library->bundle,
  87                                      library->bundle_resource_ref);
  88       CFRelease(library->bundle);
  89     } else {
  90       dlclose(library->dylib);
  91     }
  92   } else {
  93     VLOG(2) << "Not unloading NativeLibrary because it may contain an ObjC "
  94                "segment. library->objc_status = " << library->objc_status;
  95     // Deliberately do not CFRelease the bundle or dlclose the dylib because
  96     // doing so can corrupt the ObjC runtime method caches. See
  97     // http://crbug.com/172319 for details.
  98   }
  99   delete library;
 100 }
 101
 102 // static
 103 void* GetFunctionPointerFromNativeLibrary(NativeLibrary library,
 104                                           const char* name) {
 105   void* function_pointer = NULL;
 106
 107   // Get the function pointer using the right API for the type.
 108   if (library->type == BUNDLE) {
 109     base::ScopedCFTypeRef<CFStringRef> symbol_name(CFStringCreateWithCString(
 110         kCFAllocatorDefault, name, kCFStringEncodingUTF8));
 111     function_pointer = CFBundleGetFunctionPointerForName(library->bundle,
 112                                                          symbol_name);
 113   } else {
 114     function_pointer = dlsym(library->dylib, name);
 115   }
 116
 117   // If this library hasn't been tested for having ObjC, use the function
 118   // pointer to look up the section information for the library.
 119   if (function_pointer && library->objc_status == OBJC_UNKNOWN)
 120     library->objc_status = GetObjCStatusForImage(function_pointer);
 121
 122   return function_pointer;
 123 }
 124
 125 // static
 126 string16 GetNativeLibraryName(const string16& name) {
 127   return name + ASCIIToUTF16(".dylib");
 128 }
 129
 130 }  // namespace base