content/public/renderer/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//content/renderer/renderer.gni")
   7
   8 # See //content/BUILD.gn for how this works.
   9 group("renderer") {
  10   if (is_component_build) {
  11     public_deps = [
  12       "//content",
  13     ]
  14   } else {
  15     public_deps = [
  16       ":renderer_sources",
  17     ]
  18   }
  19 }
  20
  21 source_set("renderer_sources") {
  22   visibility = [ "//content/*" ]
  23
  24   sources = rebase_path(content_renderer_gypi_values.public_renderer_sources,
  25                         ".",
  26                         "//content")
  27
  28   configs += [ "//content:content_implementation" ]
  29
  30   deps = [
  31     "//content/public/common:common_sources",
  32     "//content/renderer",
  33     "//skia",
  34     "//third_party/libjingle",
  35     "//third_party/WebKit/public:blink_headers",
  36     "//third_party/widevine/cdm:version_h",
  37     "//ui/gfx",
  38     "//v8",
  39   ]
  40
  41   allow_circular_includes_from = [
  42     # This target is a pair with content/renderer. They always go together and
  43     # include headers from each other.
  44     "//content/renderer",
  45   ]
  46
  47   if (enable_webrtc) {
  48     sources +=
  49         rebase_path(content_renderer_gypi_values.public_renderer_webrtc_sources,
  50                     ".",
  51                     "//content")
  52     deps += [ "//third_party/webrtc" ]
  53   }
  54
  55   if (enable_plugins) {
  56     sources +=
  57         rebase_path(content_renderer_gypi_values.public_renderer_plugin_sources,
  58                     ".",
  59                     "//content")
  60   }
  61 }