third_party/iaccessible2/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(is_win)
   6
   7 import("//build/toolchain/win/midl.gni")
   8
   9 midl("iaccessible2") {
  10   sources = [
  11     "ia2_api_all.idl",
  12   ]
  13 }
  14
  15 config("IAccessible2Proxy_warnings") {
  16   if (is_clang) {
  17     cflags = [
  18       # MIDL generated code has a habit of omitting optional braces.
  19       "-Wno-missing-braces",
  20       "-Wno-incompatible-pointer-types",
  21     ]
  22   }
  23 }
  24
  25 # Generate a proxy DLL from the generated code.
  26 shared_library("IAccessible2Proxy") {
  27   sources = [
  28     "$target_gen_dir/ia2_api_all.dlldata.c",
  29     "$target_gen_dir/ia2_api_all_p.c",
  30     "IAccessible2Proxy.def",
  31   ]
  32
  33   configs -= [ "//build/config/compiler:chromium_code" ]
  34   configs += [ "//build/config/compiler:no_chromium_code" ]
  35   configs += [ ":IAccessible2Proxy_warnings" ]
  36
  37   defines = [ "REGISTER_PROXY_DLL" ]
  38
  39   libs = [ "rpcrt4.lib" ]
  40
  41   deps = [
  42     ":iaccessible2",
  43     "//build/config/sanitizers:deps",
  44   ]
  45 }