content/public/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//content/browser/browser.gni")
   6 import("//build/config/ui.gni")
   7
   8 # See //content/BUILD.gn for how this works.
   9 group("browser") {
  10   if (is_component_build) {
  11     public_deps = [
  12       "//content",
  13     ]
  14   } else {
  15     public_deps = [
  16       ":browser_sources",
  17     ]
  18   }
  19 }
  20
  21 source_set("browser_sources") {
  22   visibility = [ "//content/*" ]
  23
  24   if (is_ios) {
  25     # iOS doesn't get the normal file list and only takes these whitelisted
  26     # files.
  27     sources = [
  28       "browser_main_parts.cc",
  29       "content_browser_client.cc",
  30       "favicon_status.cc",
  31       "navigation_details.cc",
  32       "notification_registrar.cc",
  33       "page_navigator.cc",
  34       "web_ui_controller.cc",
  35     ]
  36   } else {
  37     sources = rebase_path(content_browser_gypi_values.public_browser_sources,
  38                           ".",
  39                           "//content")
  40   }
  41
  42   if (use_aura) {
  43     sources -= [ "context_factory.h" ]
  44   }
  45
  46   configs += [
  47     "//build/config:precompiled_headers",
  48     "//content:content_implementation",
  49   ]
  50
  51   public_deps = [
  52     "//content/public/common:mojo_bindings",
  53
  54     # We expose skia headers in the public API.
  55     "//skia",
  56     "//third_party/mojo/src/mojo/public/cpp/bindings",
  57     "//third_party/mojo/src/mojo/public/cpp/system",
  58   ]
  59   deps = [
  60     "//content/browser",
  61     "//content/public/common:common_sources",
  62     "//net",
  63     "//ui/accessibility",
  64     "//ui/base",
  65     "//ui/events",
  66   ]
  67
  68   allow_circular_includes_from = [
  69     # This target is a pair with content/browser. They always go together and
  70     # include headers from each other.
  71     "//content/browser",
  72   ]
  73 }