ui/app_list/cocoa/app_list_view_controller.mm

   1 // Copyright 2013 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "ui/app_list/cocoa/app_list_view_controller.h"
   6
   7 #include "base/mac/foundation_util.h"
   8 #include "base/strings/string_util.h"
   9 #include "skia/ext/skia_utils_mac.h"
  10 #include "ui/app_list/app_list_constants.h"
  11 #include "ui/app_list/app_list_model.h"
  12 #include "ui/app_list/app_list_view_delegate.h"
  13 #include "ui/app_list/signin_delegate.h"
  14 #include "ui/app_list/signin_delegate_observer.h"
  15 #import "ui/app_list/cocoa/app_list_pager_view.h"
  16 #import "ui/app_list/cocoa/apps_grid_controller.h"
  17 #import "ui/app_list/cocoa/signin_view_controller.h"
  18 #import "ui/base/cocoa/flipped_view.h"
  19 #include "ui/app_list/search_box_model.h"
  20 #include "ui/gfx/scoped_ns_graphics_context_save_gstate_mac.h"
  21
  22 namespace {
  23
  24 // The roundedness of the corners of the bubble.
  25 const CGFloat kBubbleCornerRadius = 3;
  26
  27 // Height of the pager.
  28 const CGFloat kPagerPreferredHeight = 57;
  29
  30 // Height of separator line drawn between the searchbox and grid view.
  31 const CGFloat kTopSeparatorSize = 1;
  32
  33 // Height of the search input.
  34 const CGFloat kSearchInputHeight = 48;
  35
  36 // Minimum margin on either side of the pager. If the pager grows beyond this,
  37 // the segment size is reduced.
  38 const CGFloat kMinPagerMargin = 40;
  39 // Maximum width of a single segment.
  40 const CGFloat kMaxSegmentWidth = 80;
  41
  42 // Duration of the animation for sliding in and out search results.
  43 const NSTimeInterval kResultsAnimationDuration = 0.2;
  44
  45 }  // namespace
  46
  47 @interface BackgroundView : FlippedView;
  48 @end
  49
  50 @implementation BackgroundView
  51
  52 - (void)drawRect:(NSRect)dirtyRect {
  53   gfx::ScopedNSGraphicsContextSaveGState context;
  54   NSRect boundsRect = [self bounds];
  55   NSRect searchAreaRect = NSMakeRect(0, 0,
  56                                      NSWidth(boundsRect), kSearchInputHeight);
  57   NSRect separatorRect = NSMakeRect(0, NSMaxY(searchAreaRect),
  58                                     NSWidth(boundsRect), kTopSeparatorSize);
  59
  60   [[NSBezierPath bezierPathWithRoundedRect:boundsRect
  61                                    xRadius:kBubbleCornerRadius
  62                                    yRadius:kBubbleCornerRadius] addClip];
  63
  64   [gfx::SkColorToSRGBNSColor(app_list::kContentsBackgroundColor) set];
  65   NSRectFill(boundsRect);
  66   [gfx::SkColorToSRGBNSColor(app_list::kSearchBoxBackground) set];
  67   NSRectFill(searchAreaRect);
  68   [gfx::SkColorToSRGBNSColor(app_list::kTopSeparatorColor) set];
  69   NSRectFill(separatorRect);
  70 }
  71
  72 @end
  73
  74 @interface AppListViewController ()
  75
  76 - (void)loadAndSetView;
  77 - (void)revealSearchResults:(BOOL)show;
  78 - (app_list::SigninDelegate*)signinDelegate;
  79
  80 @end
  81
  82 namespace app_list {
  83
  84 class SigninDelegateObserverBridge : public SigninDelegateObserver {
  85  public:
  86   SigninDelegateObserverBridge(AppListViewController* parent)
  87       : parent_(parent) {
  88     [parent_ signinDelegate]->AddObserver(this);
  89   }
  90
  91   virtual ~SigninDelegateObserverBridge() {
  92     [parent_ signinDelegate]->RemoveObserver(this);
  93   }
  94
  95  private:
  96   // SigninDelegateObserver override:
  97   virtual void OnSigninSuccess() OVERRIDE {
  98     [parent_ onSigninStatusChanged];
  99   }
 100
 101   AppListViewController* parent_;  // Weak. Owns us.
 102
 103   DISALLOW_COPY_AND_ASSIGN(SigninDelegateObserverBridge);
 104 };
 105
 106 }  // namespace app_list
 107
 108 @implementation AppListViewController
 109
 110 - (id)init {
 111   if ((self = [super init])) {
 112     appsGridController_.reset([[AppsGridController alloc] init]);
 113     [self loadAndSetView];
 114
 115     [self totalPagesChanged];
 116     [self selectedPageChanged:0];
 117     [appsGridController_ setPaginationObserver:self];
 118   }
 119   return self;
 120 }
 121
 122 - (void)dealloc {
 123   // Ensure that setDelegate(NULL) has been called before destruction, because
 124   // dealloc can be called at odd times, and Objective C destruction order does
 125   // not properly tear down these dependencies.
 126   DCHECK(delegate_ == NULL);
 127   [appsGridController_ setPaginationObserver:nil];
 128   [super dealloc];
 129 }
 130
 131 - (AppsGridController*)appsGridController {
 132   return appsGridController_;
 133 }
 134
 135 - (NSSegmentedControl*)pagerControl {
 136   return pagerControl_;
 137 }
 138
 139 - (NSView*)backgroundView {
 140   return backgroundView_;
 141 }
 142
 143 - (app_list::AppListViewDelegate*)delegate {
 144   return delegate_.get();
 145 }
 146
 147 - (void)setDelegate:(scoped_ptr<app_list::AppListViewDelegate>)newDelegate
 148       withTestModel:(scoped_ptr<app_list::AppListModel>)newModel {
 149   if (delegate_) {
 150     // First clean up, in reverse order.
 151     signin_observer_bridge_.reset();
 152     [appsSearchResultsController_ setDelegate:nil];
 153     [appsSearchBoxController_ setDelegate:nil];
 154   }
 155   delegate_.reset(newDelegate.release());
 156   [appsGridController_ setDelegate:delegate_.get()];
 157   if (newModel.get())
 158     [appsGridController_ setModel:newModel.Pass()];
 159   [appsSearchBoxController_ setDelegate:self];
 160   [appsSearchResultsController_ setDelegate:self];
 161   [self onSigninStatusChanged];
 162 }
 163
 164 - (void)setDelegate:(scoped_ptr<app_list::AppListViewDelegate>)newDelegate {
 165   [self setDelegate:newDelegate.Pass()
 166       withTestModel:scoped_ptr<app_list::AppListModel>()];
 167 }
 168
 169 -(void)loadAndSetView {
 170   pagerControl_.reset([[AppListPagerView alloc] init]);
 171   [pagerControl_ setTarget:appsGridController_];
 172   [pagerControl_ setAction:@selector(onPagerClicked:)];
 173
 174   NSRect gridFrame = [[appsGridController_ view] frame];
 175   NSRect contentsRect = NSMakeRect(0, kSearchInputHeight + kTopSeparatorSize,
 176       NSWidth(gridFrame), NSHeight(gridFrame) + kPagerPreferredHeight -
 177           [AppsGridController scrollerPadding]);
 178
 179   contentsView_.reset([[FlippedView alloc] initWithFrame:contentsRect]);
 180   backgroundView_.reset(
 181       [[BackgroundView alloc] initWithFrame:
 182               NSMakeRect(0, 0, NSMaxX(contentsRect), NSMaxY(contentsRect))]);
 183   appsSearchBoxController_.reset(
 184       [[AppsSearchBoxController alloc] initWithFrame:
 185           NSMakeRect(0, 0, NSWidth(contentsRect), kSearchInputHeight)]);
 186   appsSearchResultsController_.reset(
 187       [[AppsSearchResultsController alloc] initWithAppsSearchResultsFrameSize:
 188           [contentsView_ bounds].size]);
 189   base::scoped_nsobject<NSView> containerView(
 190       [[NSView alloc] initWithFrame:[backgroundView_ frame]]);
 191
 192   [contentsView_ addSubview:[appsGridController_ view]];
 193   [contentsView_ addSubview:pagerControl_];
 194   [backgroundView_ addSubview:contentsView_];
 195   [backgroundView_ addSubview:[appsSearchResultsController_ view]];
 196   [backgroundView_ addSubview:[appsSearchBoxController_ view]];
 197   [containerView addSubview:backgroundView_];
 198   [self setView:containerView];
 199 }
 200
 201 - (void)revealSearchResults:(BOOL)show {
 202   if (show == showingSearchResults_)
 203     return;
 204
 205   showingSearchResults_ = show;
 206   NSSize contentsSize = [contentsView_ frame].size;
 207   NSRect resultsTargetRect = NSMakeRect(
 208       0, kSearchInputHeight + kTopSeparatorSize,
 209       contentsSize.width, contentsSize.height);
 210   NSRect contentsTargetRect = resultsTargetRect;
 211
 212   // Shows results by sliding the grid and pager down to the bottom of the view.
 213   // Hides results by collapsing the search results container to a height of 0.
 214   if (show)
 215     contentsTargetRect.origin.y += NSHeight(contentsTargetRect);
 216   else
 217     resultsTargetRect.size.height = 0;
 218
 219   [[NSAnimationContext currentContext] setDuration:kResultsAnimationDuration];
 220   [[contentsView_ animator] setFrame:contentsTargetRect];
 221   [[[appsSearchResultsController_ view] animator] setFrame:resultsTargetRect];
 222 }
 223
 224 - (void)totalPagesChanged {
 225   size_t pageCount = [appsGridController_ pageCount];
 226   [pagerControl_ setSegmentCount:pageCount];
 227
 228   NSRect viewFrame = [[pagerControl_ superview] bounds];
 229   CGFloat segmentWidth = std::min(
 230       kMaxSegmentWidth,
 231       (viewFrame.size.width - 2 * kMinPagerMargin) / pageCount);
 232
 233   for (size_t i = 0; i < pageCount; ++i) {
 234     [pagerControl_ setWidth:segmentWidth
 235                  forSegment:i];
 236     [[pagerControl_ cell] setTag:i
 237                       forSegment:i];
 238   }
 239
 240   // Center in view.
 241   [pagerControl_ sizeToFit];
 242   [pagerControl_ setFrame:
 243       NSMakeRect(NSMidX(viewFrame) - NSMidX([pagerControl_ bounds]),
 244                  viewFrame.size.height - kPagerPreferredHeight,
 245                  [pagerControl_ bounds].size.width,
 246                  kPagerPreferredHeight)];
 247 }
 248
 249 - (void)selectedPageChanged:(int)newSelected {
 250   [pagerControl_ selectSegmentWithTag:newSelected];
 251 }
 252
 253 - (void)pageVisibilityChanged {
 254   [pagerControl_ setNeedsDisplay:YES];
 255 }
 256
 257 - (NSInteger)pagerSegmentAtLocation:(NSPoint)locationInWindow {
 258   return [pagerControl_ findAndHighlightSegmentAtLocation:locationInWindow];
 259 }
 260
 261 - (app_list::SearchBoxModel*)searchBoxModel {
 262   app_list::AppListModel* appListModel = [appsGridController_ model];
 263   return appListModel ? appListModel->search_box() : NULL;
 264 }
 265
 266 - (app_list::AppListViewDelegate*)appListDelegate {
 267   return [self delegate];
 268 }
 269
 270 - (BOOL)control:(NSControl*)control
 271                textView:(NSTextView*)textView
 272     doCommandBySelector:(SEL)command {
 273   if (showingSearchResults_)
 274     return [appsSearchResultsController_ handleCommandBySelector:command];
 275
 276   // If anything has been written, let the search view handle it.
 277   if ([[control stringValue] length] > 0)
 278     return NO;
 279
 280   // Handle escape.
 281   if (command == @selector(complete:) ||
 282       command == @selector(cancel:) ||
 283       command == @selector(cancelOperation:)) {
 284     if (delegate_)
 285       delegate_->Dismiss();
 286     return YES;
 287   }
 288
 289   // Possibly handle grid navigation.
 290   return [appsGridController_ handleCommandBySelector:command];
 291 }
 292
 293 - (void)modelTextDidChange {
 294   app_list::SearchBoxModel* searchBoxModel = [self searchBoxModel];
 295   if (!searchBoxModel || !delegate_)
 296     return;
 297
 298   base::string16 query;
 299   TrimWhitespace(searchBoxModel->text(), TRIM_ALL, &query);
 300   BOOL shouldShowSearch = !query.empty();
 301   [self revealSearchResults:shouldShowSearch];
 302   if (shouldShowSearch)
 303     delegate_->StartSearch();
 304   else
 305     delegate_->StopSearch();
 306 }
 307
 308 - (app_list::AppListModel*)appListModel {
 309   return [appsGridController_ model];
 310 }
 311
 312 - (void)openResult:(app_list::SearchResult*)result {
 313   if (delegate_)
 314     delegate_->OpenSearchResult(result, 0 /* event flags */);
 315
 316   [appsSearchBoxController_ clearSearch];
 317 }
 318
 319 - (void)onSigninStatusChanged {
 320   [appsSearchBoxController_ rebuildMenu];
 321   app_list::SigninDelegate* signinDelegate = [self signinDelegate];
 322   BOOL needsSignin = signinDelegate && signinDelegate->NeedSignin();
 323   if (!needsSignin) {
 324     [[signinViewController_ view] removeFromSuperview];
 325     signin_observer_bridge_.reset();
 326     signinViewController_.reset();
 327     [backgroundView_ setHidden:NO];
 328     return;
 329   }
 330
 331   [backgroundView_ setHidden:YES];
 332   signinViewController_.reset(
 333       [[SigninViewController alloc] initWithFrame:[backgroundView_ frame]
 334                                      cornerRadius:kBubbleCornerRadius
 335                                          delegate:signinDelegate]);
 336   signin_observer_bridge_.reset(
 337       new app_list::SigninDelegateObserverBridge(self));
 338   [[self view] addSubview:[signinViewController_ view]];
 339 }
 340
 341 - (app_list::SigninDelegate*)signinDelegate {
 342   return delegate_ ? delegate_->GetSigninDelegate() : NULL;
 343 }
 344
 345 @end