BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This is the root build file for GN. GN will start processing by loading this
   6 # file, and recursively load all dependencies until all dependencies are either
   7 # resolved or known not to exist (which will cause the build to fail). So if
   8 # you add a new build file, there must be some path of dependencies from this
   9 # file to your new one or GN won't know about it.
  10
  11 import("//build/config/ui.gni")
  12 if (is_android) {
  13   import("//build/config/android/config.gni")
  14 }
  15
  16 declare_args() {
  17   # A list of extra dependencies to add to the root target. This allows a
  18   # checkout to add additional targets without explicitly changing any checked-
  19   # in files.
  20   root_extra_deps = []
  21 }
  22
  23 # In GN, a "group" is a dummy target that just lists other targets.
  24 group("root") {
  25   # This should not be linked into production and depends on test targets.
  26   testonly = true
  27
  28   # Note that some dependencies are commented out. These are things that are
  29   # currently written but not hooked up to the build yet. They may need to be
  30   # completed or possibly just tested and then re-enabled.
  31   deps = [
  32     "//apps",
  33     "//ash",
  34     "//cc",
  35     "//cc/blink",
  36     "//chrome/browser",
  37     "//chrome/browser/devtools",
  38     "//chrome/common",
  39     "//chrome/plugin",
  40     "//chrome/renderer",
  41     "//chrome/utility",
  42     "//components:all_components",
  43     "//content",
  44     "//content/shell:content_shell",
  45     "//content/test:test_support",
  46     "//crypto",
  47     "//device/bluetooth",
  48     "//device/nfc",
  49     "//extensions/browser",
  50     "//extensions/common",
  51     "//extensions/common/api",
  52     "//extensions/renderer",
  53     "//gin",
  54     "//gpu",
  55     "//google_apis",
  56     "//google_apis/gcm",
  57     "//ipc",
  58     "//ipc/mojo",
  59     "//jingle:notifier",
  60     "//media",
  61     "//media/blink",
  62     "//media/cast",
  63     "//media/mojo",
  64     "//mojo",
  65     "//net",
  66     "//pdf",
  67     "//ppapi:ppapi_c",
  68     "//printing",
  69     "//remoting/client/plugin",
  70     "//sandbox",
  71     "//sdch",
  72     "//skia",
  73     "//storage/browser",
  74     "//sql",
  75     "//sync",
  76     "//third_party/WebKit/public:all_blink",
  77     "//third_party/angle:translator",
  78     "//third_party/brotli",
  79     "//third_party/cacheinvalidation",
  80     "//third_party/cld",
  81     "//third_party/cld_2",
  82     "//third_party/ffmpeg",
  83     "//third_party/flac",
  84     "//third_party/harfbuzz-ng",
  85     "//third_party/hunspell",
  86     "//third_party/iccjpeg",
  87     "//third_party/icu",
  88     "//third_party/leveldatabase",
  89     "//third_party/libphonenumber",
  90     "//third_party/libjingle",
  91     "//third_party/libpng",
  92     "//third_party/libsrtp",
  93     "//third_party/libusb",
  94     "//third_party/libwebm",
  95     "//third_party/libwebp",
  96     "//third_party/libxslt",
  97     "//third_party/libvpx",
  98     "//third_party/libyuv",
  99     "//third_party/lzma_sdk",
 100     "//third_party/mesa",
 101     "//third_party/opus",
 102     "//third_party/ots",
 103     "//third_party/protobuf:protobuf_lite",
 104     "//third_party/qcms",
 105     "//third_party/re2",
 106     "//third_party/smhasher:cityhash",
 107     "//third_party/smhasher:murmurhash3",
 108     "//third_party/smhasher:pmurhash",
 109     "//third_party/snappy",
 110     "//third_party/speex",
 111     "//third_party/usrsctp",
 112     "//third_party/widevine/cdm:version_h",
 113     "//third_party/webrtc",
 114     "//third_party/zlib",
 115     "//third_party:jpeg",
 116     "//tools/gn",
 117     "//tools/imagediff($host_toolchain)",
 118     "//ui/accessibility",
 119     "//ui/app_list",
 120     "//ui/aura",
 121     "//ui/base",
 122     "//ui/display",
 123     "//ui/events",
 124     "//ui/gfx",
 125     "//ui/gl",
 126     "//ui/keyboard",
 127     "//ui/native_theme",
 128     "//ui/resources",
 129     "//ui/snapshot",
 130     "//ui/strings",
 131     "//ui/surface",
 132     "//ui/views",
 133     "//ui/views/controls/webview",
 134     "//ui/web_dialogs",
 135     "//url",
 136     "//v8:v8",
 137   ] + root_extra_deps
 138
 139   if (!is_win) {
 140     deps += [ "//breakpad:symupload" ]
 141   }
 142
 143   if (is_linux) {
 144     deps += [
 145       "//dbus",
 146       "//third_party/fontconfig",
 147       "//third_party/freetype2",
 148     ]
 149   }
 150
 151   if (use_x11) {
 152     deps += [ "//tools/xdisplaycheck" ]
 153   }
 154
 155   if (use_aura) {
 156     deps += [ "//ui/wm" ]
 157   }
 158
 159   if (is_win) {
 160     deps += [
 161       "//ui/metro_viewer",
 162     ]
 163   }
 164
 165   if (is_win || is_mac || is_chromeos) {
 166     # RLZ works on these platforms.
 167     deps += [
 168       "//rlz:rlz_lib",
 169     ]
 170   }
 171
 172   if (cpu_arch == "x86" || cpu_arch == "x64") {
 173     # YASM is x86/x64 only.
 174     deps += [ "//third_party/yasm($host_toolchain)" ]
 175   }
 176
 177   if (is_android) {
 178     deps += [
 179       "//base/android/linker:chromium_android_linker",
 180       "//build/android/rezip",
 181       "//third_party/openmax_dl/dl",
 182       "//content/shell/android:content_shell_apk",
 183       "//chrome/android:chrome_shell_apk",
 184       "//chrome/test/chromedriver/test/webview_shell:chromedriver_webview_shell_apk",
 185       "//ui/android:ui_java",
 186       "//third_party/android_tools:android_gcm_java",
 187       "//third_party/android_tools:uiautomator_java",
 188       "//third_party/android_tools:android_support_v13_java",
 189       "//third_party/android_tools:android_support_v7_appcompat_java",
 190       "//third_party/android_tools:android_support_v7_mediarouter_java",
 191       "//third_party/eyesfree:eyesfree_java",
 192     ]
 193
 194     if (has_chrome_android_internal) {
 195       deps += [
 196         "//clank",
 197       ]
 198     }
 199
 200     deps -= [
 201       "//apps",  # Needs testing.
 202       "//chrome/browser",
 203       "//chrome/browser/devtools",
 204       "//chrome/common",
 205       "//chrome/plugin",
 206       "//chrome/renderer",
 207       "//chrome/utility",
 208       "//content/shell:content_shell",
 209       "//extensions/browser",
 210       "//extensions/common",
 211       "//extensions/common/api",
 212       "//extensions/renderer",
 213       "//pdf",  # Not compiled on Android in GYP yet, either.
 214       "//ppapi:ppapi_c",
 215       "//third_party/libusb",
 216       "//ui/keyboard",  # Blocked on content.
 217
 218       # Seems to not be compiled on Android. Otherwise it will need a config.h.
 219       "//third_party/libxslt",
 220
 221       # Not relevant to Android.
 222       "//ash",
 223       "//tools/gn",
 224       "//ui/aura",
 225       "//ui/display",
 226       "//ui/views",
 227       "//ui/views/controls/webview",
 228
 229       # Fails on Android for unknown reasons.
 230       "//third_party/flac",
 231       "//breakpad:symupload",
 232
 233       # Not tested on Android yet:
 234       "//google_apis/gcm",
 235       "//remoting/client/plugin",
 236       "//storage/browser",
 237       "//third_party/cld_2",
 238       "//third_party/ffmpeg",
 239       "//ui/app_list",
 240       "//ui/web_dialogs",
 241     ]
 242   }
 243
 244   if (use_ozone) {
 245     deps += [
 246       "//ui/ozone",
 247       "//ui/ozone/demo",
 248     ]
 249   }
 250
 251   # Non-mobile builds.
 252   if (!is_android && !is_ios) {
 253     deps += [
 254       "//device/usb",
 255     ]
 256   }
 257 }