chromeos/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/allocator.gni")
   6 import("//build/config/ui.gni")
   7 import("//third_party/protobuf/proto_library.gni")
   8
   9 assert(is_chromeos, "Non-ChromeOS builds must not depend on //chromeos")
  10
  11 gypi_values = exec_script("//build/gypi_to_gn.py",
  12                           [ rebase_path("chromeos.gyp") ],
  13                           "scope",
  14                           [ "chromeos.gyp" ])
  15
  16 component("chromeos") {
  17   configs += [ "//net/third_party/nss/ssl:ssl_config" ]
  18   public_deps = [
  19     "//dbus",
  20   ]
  21   deps = [
  22     "//base",
  23     "//base:prefs",
  24     "//base/third_party/dynamic_annotations",
  25     "//chromeos/ime:gencode",
  26     "//components/policy/proto",
  27     "//components/onc",
  28     "//crypto",
  29     "//google_apis",
  30     "//net/third_party/nss/ssl:libssl",
  31     "//third_party/icu",
  32     "//third_party/libxml",
  33     "//third_party/protobuf:protobuf_lite",
  34     "//ui/accelerometer",
  35     "//url",
  36     ":cryptohome_proto",
  37     ":power_manager_proto",
  38   ]
  39   sources = gypi_values.chromeos_sources
  40   defines = [ "CHROMEOS_IMPLEMENTATION" ]
  41 }
  42
  43 static_library("test_support") {
  44   testonly = true
  45   configs += [ "//build/config/linux:dbus" ]
  46   deps = [
  47     "//testing/gmock",
  48     ":chromeos",
  49     ":cryptohome_proto",
  50     ":power_manager_proto",
  51     ":test_support_without_gmock",
  52   ]
  53   sources = [
  54     "attestation/mock_attestation_flow.cc",
  55     "attestation/mock_attestation_flow.h",
  56     "chromeos_test_utils.cc",
  57     "chromeos_test_utils.h",
  58     "cryptohome/mock_async_method_caller.cc",
  59     "cryptohome/mock_async_method_caller.h",
  60     "cryptohome/mock_homedir_methods.cc",
  61     "cryptohome/mock_homedir_methods.h",
  62     "dbus/mock_cryptohome_client.cc",
  63     "dbus/mock_cryptohome_client.h",
  64     "dbus/mock_lorgnette_manager_client.cc",
  65     "dbus/mock_lorgnette_manager_client.h",
  66     "dbus/mock_session_manager_client.cc",
  67     "dbus/mock_session_manager_client.h",
  68     "dbus/mock_shill_manager_client.cc",
  69     "dbus/mock_shill_manager_client.h",
  70     "dbus/mock_shill_profile_client.cc",
  71     "dbus/mock_shill_profile_client.h",
  72     "dbus/mock_shill_service_client.cc",
  73     "dbus/mock_shill_service_client.h",
  74     "dbus/services/service_provider_test_helper.cc",
  75     "dbus/services/service_provider_test_helper.h",
  76     "disks/mock_disk_mount_manager.cc",
  77     "disks/mock_disk_mount_manager.h",
  78     "login/auth/fake_extended_authenticator.cc",
  79     "login/auth/fake_extended_authenticator.h",
  80     "login/auth/mock_auth_attempt_state_resolver.cc",
  81     "login/auth/mock_auth_attempt_state_resolver.h",
  82     "login/auth/mock_auth_status_consumer.cc",
  83     "login/auth/mock_auth_status_consumer.h",
  84     "login/auth/mock_authenticator.cc",
  85     "login/auth/mock_authenticator.h",
  86     "login/auth/mock_url_fetchers.cc",
  87     "login/auth/mock_url_fetchers.h",
  88     "network/fake_network_device_handler.cc",
  89     "network/fake_network_device_handler.h",
  90     "network/mock_managed_network_configuration_handler.cc",
  91     "network/mock_managed_network_configuration_handler.h",
  92     "network/onc/onc_test_utils.cc",
  93     "network/onc/onc_test_utils.h",
  94     "system/fake_statistics_provider.cc",
  95     "system/fake_statistics_provider.h",
  96   ]
  97 }
  98
  99 static_library("test_support_without_gmock") {
 100   testonly = true
 101   configs += [ "//build/config/linux:dbus" ]
 102   deps = [
 103     "//crypto",
 104     ":chromeos",
 105     ":cryptohome_proto",
 106     ":power_manager_proto",
 107   ]
 108   sources = [
 109     "dbus/fake_cros_disks_client.cc",
 110     "dbus/fake_cros_disks_client.h",
 111     "dbus/fake_power_manager_client.cc",
 112     "dbus/fake_power_manager_client.h",
 113     "dbus/fake_session_manager_client.cc",
 114     "dbus/fake_session_manager_client.h",
 115     "dbus/fake_shill_manager_client.cc",
 116     "dbus/fake_shill_manager_client.h",
 117     "dbus/fake_update_engine_client.cc",
 118     "dbus/fake_update_engine_client.h",
 119   ]
 120 }
 121
 122 test("chromeos_unittests") {
 123   configs += [
 124     "//build/config/linux:dbus",
 125     "//net/third_party/nss/ssl:ssl_config",
 126   ]
 127   deps = [
 128     "//base:prefs_test_support",
 129     "//base/test:run_all_unittests",
 130     "//base/test:test_support",
 131     "//components/onc",
 132     "//crypto",
 133     "//crypto:test_support",
 134     "//dbus:test_support",
 135     "//google_apis",
 136     "//net",
 137     "//net:test_support",
 138     "//testing/gmock",
 139     "//testing/gtest",
 140     "//url",
 141     ":cryptohome_proto",
 142     ":power_manager_proto",
 143     ":test_support",
 144   ]
 145   sources = gypi_values.chromeos_test_sources
 146   if (use_allocator != "none") {
 147     deps += [ "//base/allocator" ]
 148   }
 149 }
 150
 151 proto_library("power_manager_proto") {
 152   sources = [
 153     "//third_party/cros_system_api/dbus/power_manager/input_event.proto",
 154     "//third_party/cros_system_api/dbus/power_manager/peripheral_battery_status.proto",
 155     "//third_party/cros_system_api/dbus/power_manager/policy.proto",
 156     "//third_party/cros_system_api/dbus/power_manager/power_supply_properties.proto",
 157     "//third_party/cros_system_api/dbus/power_manager/suspend.proto",
 158   ]
 159
 160   proto_out_dir = "chromeos/dbus/power_manager"
 161 }
 162
 163 proto_library("cryptohome_proto") {
 164   sources = [
 165     "//third_party/cros_system_api/dbus/cryptohome/key.proto",
 166     "//third_party/cros_system_api/dbus/cryptohome/rpc.proto",
 167   ]
 168
 169   proto_out_dir = "chromeos/dbus/cryptohome"
 170 }
 171
 172 proto_library("cryptohome_signkey_proto") {
 173   sources = [
 174     "//third_party/cros_system_api/dbus/cryptohome/signed_secret.proto",
 175   ]
 176
 177   proto_out_dir = "chromeos/cryptohome"
 178 }