net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//tools/grit/grit_rule.gni")
   9 import("//url/config.gni")
  10
  11 if (is_android) {
  12   import("//build/config/android/config.gni")
  13   import("//build/config/android/rules.gni")
  14 } else if (is_mac) {
  15   import("//build/config/mac/mac_sdk.gni")
  16 }
  17
  18 # The list of net files is kept in net.gypi. Read it.
  19 gypi_values = exec_script(
  20     "//build/gypi_to_gn.py",
  21     [ rebase_path("net.gypi") ],
  22     "scope",
  23     [ "net.gypi" ])
  24
  25 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  26 # configuration (krb5.conf and so on).
  27 use_kerberos = !is_chromeos && !is_android && !is_ios
  28
  29 # The way the cache uses mmap() is inefficient on some Android devices. If
  30 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  31 # pretty confident that mmap-ing the index would not hurt any existing x86
  32 # android devices, but we cannot be so sure about the variety of ARM devices.
  33 # So enable it for x86 only for now.
  34 posix_avoid_mmap = is_android && cpu_arch != "x86"
  35
  36 # WebSockets and socket stream code are used everywhere except iOS.
  37 enable_websockets = !is_ios
  38 use_v8_in_net = !is_ios
  39 enable_built_in_dns = !is_ios
  40 disable_ftp_support = is_ios
  41
  42 declare_args() {
  43   # Disables support for file URLs.  File URL support requires use of icu.
  44   disable_file_support = false
  45 }
  46
  47 config("net_config") {
  48   defines = []
  49   if (posix_avoid_mmap) {
  50     defines += [ "POSIX_AVOID_MMAP" ]
  51   }
  52   if (disable_file_support) {
  53     defines += [ "DISABLE_FILE_SUPPORT" ]
  54   }
  55 }
  56
  57 # Disables Windows warning about size to int truncations.
  58 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  59 config("net_win_size_truncation") {
  60   if (is_win) {
  61     cflags = [ "/wd4267" ]
  62   }
  63 }
  64
  65 component("net") {
  66   sources =
  67     gypi_values.net_nacl_common_sources +
  68     gypi_values.net_non_nacl_sources
  69
  70   cflags = []
  71   defines = [
  72     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  73     # 0) which implies that we run pkg_config on kerberos and link to that
  74     # rather than setting this define which will dynamically open it. That
  75     # doesn't seem to be set in the regular builds, so we're skipping this
  76     # capability here.
  77     "DLOPEN_KERBEROS",
  78     "NET_IMPLEMENTATION"
  79   ]
  80   configs += [ ":net_win_size_truncation" ]
  81   direct_dependent_configs = [ ":net_config" ]
  82   include_dirs = []
  83
  84   deps = [
  85    ":net_resources",
  86     "//base",
  87     "//base:i18n",
  88     "//base/third_party/dynamic_annotations",
  89     "//crypto",
  90     "//crypto:platform",
  91     "//net/base/registry_controlled_domains",
  92     "//sdch",
  93     "//third_party/icu",
  94     "//third_party/zlib",
  95     "//url",
  96   ]
  97   forward_dependent_configs_from = [
  98     "//crypto",
  99     "//crypto:platform"
 100   ]
 101
 102   if (use_kerberos) {
 103     defines += [ "USE_KERBEROS" ]
 104     if (is_android) {
 105       include_dirs += [ "/usr/include/kerberosV" ]
 106     }
 107   } else {
 108     sources -= [
 109       "http/http_auth_gssapi_posix.cc",
 110       "http/http_auth_gssapi_posix.h",
 111       "http/http_auth_handler_negotiate.h",
 112       "http/http_auth_handler_negotiate.cc",
 113     ]
 114   }
 115
 116   if (is_posix) {
 117     if (posix_avoid_mmap) {
 118       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 119     } else {
 120       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 121     }
 122   }
 123
 124   if (disable_file_support) {
 125     sources -= [
 126       "base/directory_lister.cc",
 127       "base/directory_lister.h",
 128       "url_request/url_request_file_dir_job.cc",
 129       "url_request/url_request_file_dir_job.h",
 130       "url_request/url_request_file_job.cc",
 131       "url_request/url_request_file_job.h",
 132       "url_request/file_protocol_handler.cc",
 133       "url_request/file_protocol_handler.h",
 134     ]
 135   }
 136
 137   if (disable_ftp_support) {
 138     sources -= [
 139       "ftp/ftp_auth_cache.cc",
 140       "ftp/ftp_auth_cache.h",
 141       "ftp/ftp_ctrl_response_buffer.cc",
 142       "ftp/ftp_ctrl_response_buffer.h",
 143       "ftp/ftp_directory_listing_parser.cc",
 144       "ftp/ftp_directory_listing_parser.h",
 145       "ftp/ftp_directory_listing_parser_ls.cc",
 146       "ftp/ftp_directory_listing_parser_ls.h",
 147       "ftp/ftp_directory_listing_parser_netware.cc",
 148       "ftp/ftp_directory_listing_parser_netware.h",
 149       "ftp/ftp_directory_listing_parser_os2.cc",
 150       "ftp/ftp_directory_listing_parser_os2.h",
 151       "ftp/ftp_directory_listing_parser_vms.cc",
 152       "ftp/ftp_directory_listing_parser_vms.h",
 153       "ftp/ftp_directory_listing_parser_windows.cc",
 154       "ftp/ftp_directory_listing_parser_windows.h",
 155       "ftp/ftp_network_layer.cc",
 156       "ftp/ftp_network_layer.h",
 157       "ftp/ftp_network_session.cc",
 158       "ftp/ftp_network_session.h",
 159       "ftp/ftp_network_transaction.cc",
 160       "ftp/ftp_network_transaction.h",
 161       "ftp/ftp_request_info.h",
 162       "ftp/ftp_response_info.cc",
 163       "ftp/ftp_response_info.h",
 164       "ftp/ftp_server_type_histograms.cc",
 165       "ftp/ftp_server_type_histograms.h",
 166       "ftp/ftp_transaction.h",
 167       "ftp/ftp_transaction_factory.h",
 168       "ftp/ftp_util.cc",
 169       "ftp/ftp_util.h",
 170       "url_request/ftp_protocol_handler.cc",
 171       "url_request/ftp_protocol_handler.h",
 172       "url_request/url_request_ftp_job.cc",
 173       "url_request/url_request_ftp_job.h",
 174     ]
 175   }
 176
 177   if (enable_built_in_dns) {
 178     defines += [ "ENABLE_BUILT_IN_DNS" ]
 179   } else {
 180     sources -= [
 181       "dns/address_sorter_posix.cc",
 182       "dns/address_sorter_posix.h",
 183       "dns/dns_client.cc",
 184     ]
 185   }
 186
 187   if (use_openssl) {
 188     sources -= [
 189       "base/nss_memio.c",
 190       "base/nss_memio.h",
 191       "cert/ct_log_verifier_nss.cc",
 192       "cert/ct_objects_extractor_nss.cc",
 193       "cert/jwk_serializer_nss.cc",
 194       "cert/scoped_nss_types.h",
 195       "cert/x509_util_nss.cc",
 196       "cert/x509_util_nss.h",
 197       "quic/crypto/aead_base_decrypter_nss.cc",
 198       "quic/crypto/aead_base_encrypter_nss.cc",
 199       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 200       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 201       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 202       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 203       "quic/crypto/channel_id_nss.cc",
 204       "quic/crypto/p256_key_exchange_nss.cc",
 205       "socket/nss_ssl_util.cc",
 206       "socket/nss_ssl_util.h",
 207       "socket/ssl_client_socket_nss.cc",
 208       "socket/ssl_client_socket_nss.h",
 209       "socket/ssl_server_socket_nss.cc",
 210       "socket/ssl_server_socket_nss.h",
 211     ]
 212     if (is_chromeos) {
 213       sources -= [
 214         "cert/nss_cert_database_chromeos.cc",
 215         "cert/nss_cert_database_chromeos.h",
 216         "cert/nss_profile_filter_chromeos.cc",
 217         "cert/nss_profile_filter_chromeos.h",
 218       ]
 219     }
 220     if (is_linux) {
 221       # These are always removed for non-Linux cases below.
 222       sources -= [
 223         "base/crypto_module_nss.cc",
 224         "base/keygen_handler_nss.cc",
 225         "cert/cert_database_nss.cc",
 226         "cert/nss_cert_database.cc",
 227         "cert/nss_cert_database.h",
 228         "cert/x509_certificate_nss.cc",
 229         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 230         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 231         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 232         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 233         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 234         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 235       ]
 236     }
 237     if (is_ios) {
 238       # Always removed for !ios below.
 239       sources -= [
 240         "cert/cert_verify_proc_nss.cc",
 241         "cert/cert_verify_proc_nss.h",
 242         "cert/test_root_certs_nss.cc",
 243         "ocsp/nss_ocsp.cc",
 244         "ocsp/nss_ocsp.h",
 245       ]
 246     }
 247   } else {
 248     sources -= [
 249       "base/crypto_module_openssl.cc",
 250       "base/keygen_handler_openssl.cc",
 251       "cert/ct_log_verifier_openssl.cc",
 252       "cert/ct_objects_extractor_openssl.cc",
 253       "cert/jwk_serializer_openssl.cc",
 254       "cert/x509_util_openssl.cc",
 255       "cert/x509_util_openssl.h",
 256       "quic/crypto/aead_base_decrypter_openssl.cc",
 257       "quic/crypto/aead_base_encrypter_openssl.cc",
 258       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 259       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 260       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 261       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 262       "quic/crypto/channel_id_openssl.cc",
 263       "quic/crypto/p256_key_exchange_openssl.cc",
 264       "quic/crypto/scoped_evp_aead_ctx.cc",
 265       "quic/crypto/scoped_evp_aead_ctx.h",
 266       "socket/openssl_ssl_util.cc",
 267       "socket/openssl_ssl_util.h",
 268       "socket/ssl_client_socket_openssl.cc",
 269       "socket/ssl_client_socket_openssl.h",
 270       "socket/ssl_server_socket_openssl.cc",
 271       "socket/ssl_server_socket_openssl.h",
 272       "socket/ssl_session_cache_openssl.cc",
 273       "socket/ssl_session_cache_openssl.h",
 274     ]
 275   }
 276
 277   if (!use_openssl_certs) {
 278     sources -= [
 279       "base/openssl_private_key_store.h",
 280       "base/openssl_private_key_store_memory.cc",
 281       "cert/cert_database_openssl.cc",
 282       "cert/cert_verify_proc_openssl.cc",
 283       "cert/cert_verify_proc_openssl.h",
 284       "cert/test_root_certs_openssl.cc",
 285       "cert/x509_certificate_openssl.cc",
 286       "ssl/openssl_client_key_store.cc",
 287       "ssl/openssl_client_key_store.h",
 288     ]
 289     if (is_android) {
 290       sources -= [
 291         "base/openssl_private_key_store_android.cc",
 292       ]
 293     }
 294   } else if (is_android) {
 295     # Android doesn't use these even when using OpenSSL.
 296     sources -= [
 297       "base/openssl_private_key_store_memory.cc",
 298       "cert/cert_database_openssl.cc",
 299       "cert/cert_verify_proc_openssl.cc",
 300       "cert/test_root_certs_openssl.cc",
 301     ]
 302   }
 303
 304   if (use_glib) {
 305     configs += [ "//build/config/linux:gconf" ]
 306     deps += [ "//build/config/linux:gio" ]
 307   }
 308
 309   if (is_linux) {
 310     configs += [ "//build/config/linux:libresolv" ]
 311   } else {
 312     sources -= [
 313       "base/crypto_module_nss.cc",
 314       "base/keygen_handler_nss.cc",
 315       "cert/cert_database_nss.cc",
 316       "cert/nss_cert_database.cc",
 317       "cert/nss_cert_database.h",
 318       "cert/x509_certificate_nss.cc",
 319       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 320       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 321       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 322       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 323       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 324       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 325     ]
 326
 327     if (!is_ios) {
 328       # These files are part of the partial implementation of NSS on iOS so
 329       # keep them in that case.
 330       sources -= [
 331         "cert/test_root_certs_nss.cc",
 332         "ocsp/nss_ocsp.cc",
 333         "ocsp/nss_ocsp.h",
 334       ]
 335     }
 336   }
 337
 338   if (!use_nss_certs) {
 339     sources -= [
 340       "ssl/client_cert_store_nss.cc",
 341       "ssl/client_cert_store_nss.h",
 342     ]
 343     if (!is_ios) {
 344       # These files are part of the partial implementation of NSS on iOS so
 345       # keep them in that case (even though use_nss_certs is not set).
 346       sources -= [
 347         "cert/cert_verify_proc_nss.cc",
 348         "cert/cert_verify_proc_nss.h",
 349       ]
 350     }
 351     if (is_chromeos) {
 352       # These were already removed on non-ChromeOS.
 353       sources -= [
 354         "ssl/client_cert_store_chromeos.cc",
 355         "ssl/client_cert_store_chromeos.h",
 356       ]
 357     }
 358   }
 359
 360   if (!enable_websockets) {
 361     sources -= [
 362       "socket_stream/socket_stream.cc",
 363       "socket_stream/socket_stream.h",
 364       "socket_stream/socket_stream_job.cc",
 365       "socket_stream/socket_stream_job.h",
 366       "socket_stream/socket_stream_job_manager.cc",
 367       "socket_stream/socket_stream_job_manager.h",
 368       "socket_stream/socket_stream_metrics.cc",
 369       "socket_stream/socket_stream_metrics.h",
 370       "spdy/spdy_websocket_stream.cc",
 371       "spdy/spdy_websocket_stream.h",
 372       "websockets/websocket_basic_handshake_stream.cc",
 373       "websockets/websocket_basic_handshake_stream.h",
 374       "websockets/websocket_basic_stream.cc",
 375       "websockets/websocket_basic_stream.h",
 376       "websockets/websocket_channel.cc",
 377       "websockets/websocket_channel.h",
 378       "websockets/websocket_deflate_predictor.h",
 379       "websockets/websocket_deflate_predictor_impl.cc",
 380       "websockets/websocket_deflate_predictor_impl.h",
 381       "websockets/websocket_deflate_stream.cc",
 382       "websockets/websocket_deflate_stream.h",
 383       "websockets/websocket_deflater.cc",
 384       "websockets/websocket_deflater.h",
 385       "websockets/websocket_errors.cc",
 386       "websockets/websocket_errors.h",
 387       "websockets/websocket_extension.cc",
 388       "websockets/websocket_extension.h",
 389       "websockets/websocket_extension_parser.cc",
 390       "websockets/websocket_extension_parser.h",
 391       "websockets/websocket_frame.cc",
 392       "websockets/websocket_frame.h",
 393       "websockets/websocket_frame_parser.cc",
 394       "websockets/websocket_frame_parser.h",
 395       "websockets/websocket_handshake_constants.cc",
 396       "websockets/websocket_handshake_constants.h",
 397       "websockets/websocket_handshake_handler.cc",
 398       "websockets/websocket_handshake_handler.h",
 399       "websockets/websocket_handshake_request_info.cc",
 400       "websockets/websocket_handshake_request_info.h",
 401       "websockets/websocket_handshake_response_info.cc",
 402       "websockets/websocket_handshake_response_info.h",
 403       "websockets/websocket_handshake_stream_base.h",
 404       "websockets/websocket_handshake_stream_create_helper.cc",
 405       "websockets/websocket_handshake_stream_create_helper.h",
 406       "websockets/websocket_inflater.cc",
 407       "websockets/websocket_inflater.h",
 408       "websockets/websocket_job.cc",
 409       "websockets/websocket_job.h",
 410       "websockets/websocket_mux.h",
 411       "websockets/websocket_net_log_params.cc",
 412       "websockets/websocket_net_log_params.h",
 413       "websockets/websocket_stream.cc",
 414       "websockets/websocket_stream.h",
 415       "websockets/websocket_throttle.cc",
 416       "websockets/websocket_throttle.h",
 417     ]
 418   }
 419
 420   if (!enable_mdns) {
 421     sources -= [
 422       "dns/mdns_cache.cc",
 423       "dns/mdns_cache.h",
 424       "dns/mdns_client.cc",
 425       "dns/mdns_client.h",
 426       "dns/mdns_client_impl.cc",
 427       "dns/mdns_client_impl.h",
 428       "dns/record_parsed.cc",
 429       "dns/record_parsed.h",
 430       "dns/record_rdata.cc",
 431       "dns/record_rdata.h",
 432     ]
 433   }
 434
 435   if (is_win) {
 436     sources -= [
 437       "http/http_auth_handler_ntlm_portable.cc",
 438       "socket/tcp_socket_libevent.cc",
 439       "socket/tcp_socket_libevent.h",
 440       "udp/udp_socket_libevent.cc",
 441       "udp/udp_socket_libevent.h",
 442     ]
 443     deps += [
 444       "//third_party/nss:nspr",
 445       "//third_party/nss",
 446     ]
 447   } else {  # !is_win
 448     sources -= [
 449       "base/winsock_init.cc",
 450       "base/winsock_init.h",
 451       "base/winsock_util.cc",
 452       "base/winsock_util.h",
 453       "proxy/proxy_resolver_winhttp.cc",
 454       "proxy/proxy_resolver_winhttp.h",
 455     ]
 456   }
 457
 458   if (is_mac) {
 459     deps += [
 460       "//third_party/nss:nspr",
 461       "//third_party/nss",
 462     ]
 463     libs = [
 464       "Foundation.framework",
 465       "Security.framework",
 466       "SystemConfiguration.framework",
 467       "resolv",
 468     ]
 469   }
 470
 471   if (is_ios) {
 472     # Add back some sources that were otherwise filtered out. iOS additionally
 473     # doesn't set USE_NSS but needs some of the files.
 474     set_sources_assignment_filter([])
 475     sources += [
 476       "base/network_change_notifier_mac.cc",
 477       "base/network_config_watcher_mac.cc",
 478       "base/platform_mime_util_mac.mm",
 479       "cert/cert_verify_proc_nss.cc",
 480       "cert/cert_verify_proc_nss.h",
 481       "cert/test_root_certs_nss.cc",
 482       "cert/x509_util_nss.cc",
 483       "cert/x509_util_nss.h",
 484       "proxy/proxy_resolver_mac.cc",
 485       "proxy/proxy_server_mac.cc",
 486       "ocsp/nss_ocsp.cc",
 487       "ocsp/nss_ocsp.h",
 488     ]
 489     set_sources_assignment_filter(sources_assignment_filter)
 490
 491     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 492     deps += [
 493       "//third_party/nss",
 494     ]
 495     libs = [
 496       "CFNetwork.framework",
 497       "MobileCoreServices.framework",
 498       "Security.framework",
 499       "SystemConfiguration.framework",
 500       "resolv",
 501     ]
 502   }
 503
 504   if (is_android) {
 505     # Add some Linux sources that were excluded by the filter, but which
 506     # are needed.
 507     set_sources_assignment_filter([])
 508     sources += [
 509       "base/platform_mime_util_linux.cc",
 510       "base/address_tracker_linux.cc",
 511       "base/address_tracker_linux.h",
 512     ]
 513     set_sources_assignment_filter(sources_assignment_filter)
 514
 515     if (!is_android_webview_build) {
 516       deps += [ ":net_jni_headers" ]
 517
 518       # The net/android/keystore_openssl.cc source file needs to access an
 519       # OpenSSL-internal header.
 520       include_dirs = [ "//third_party/openssl" ]
 521     }
 522   }
 523
 524   if (use_icu_alternatives_on_android) {
 525     deps -= [
 526       "//base:i18n",
 527       "//third_party/icu",
 528     ]
 529     sources -= [
 530       "base/filename_util_icu.cc",
 531       "base/net_string_util_icu.cc",
 532       "base/net_util_icu.cc",
 533     ]
 534     sources += [
 535       "base/net_string_util_icu_alternatives_android.cc",
 536       "base/net_string_util_icu_alternatives_android.h",
 537     ]
 538   }
 539 }
 540
 541 grit("net_resources") {
 542   source = "base/net_resources.grd"
 543 }
 544
 545 static_library("http_server") {
 546   sources = [
 547     "server/http_connection.cc",
 548     "server/http_connection.h",
 549     "server/http_server.cc",
 550     "server/http_server.h",
 551     "server/http_server_request_info.cc",
 552     "server/http_server_request_info.h",
 553     "server/http_server_response_info.cc",
 554     "server/http_server_response_info.h",
 555     "server/web_socket.cc",
 556     "server/web_socket.h",
 557   ]
 558   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 559   deps = [
 560     ":net",
 561     "//base",
 562   ]
 563 }
 564
 565 executable("dump_cache") {
 566   sources = [
 567     "tools/dump_cache/cache_dumper.cc",
 568     "tools/dump_cache/cache_dumper.h",
 569     "tools/dump_cache/dump_cache.cc",
 570     "tools/dump_cache/dump_files.cc",
 571     "tools/dump_cache/dump_files.h",
 572     "tools/dump_cache/simple_cache_dumper.cc",
 573     "tools/dump_cache/simple_cache_dumper.h",
 574     "tools/dump_cache/upgrade_win.cc",
 575     "tools/dump_cache/upgrade_win.h",
 576     "tools/dump_cache/url_to_filename_encoder.cc",
 577     "tools/dump_cache/url_to_filename_encoder.h",
 578     "tools/dump_cache/url_utilities.h",
 579     "tools/dump_cache/url_utilities.cc",
 580   ]
 581
 582   configs += [ ":net_win_size_truncation" ]
 583
 584   deps = [
 585     "//base",
 586     ":net",
 587     ":test_support",
 588   ]
 589 }
 590
 591 source_set("test_support") {
 592   sources = [
 593     "base/capturing_net_log.cc",
 594     "base/capturing_net_log.h",
 595     "base/load_timing_info_test_util.cc",
 596     "base/load_timing_info_test_util.h",
 597     "base/mock_file_stream.cc",
 598     "base/mock_file_stream.h",
 599     "base/test_completion_callback.cc",
 600     "base/test_completion_callback.h",
 601     "base/test_data_directory.cc",
 602     "base/test_data_directory.h",
 603     "cert/mock_cert_verifier.cc",
 604     "cert/mock_cert_verifier.h",
 605     "cookies/cookie_monster_store_test.cc",
 606     "cookies/cookie_monster_store_test.h",
 607     "cookies/cookie_store_test_callbacks.cc",
 608     "cookies/cookie_store_test_callbacks.h",
 609     "cookies/cookie_store_test_helpers.cc",
 610     "cookies/cookie_store_test_helpers.h",
 611     "disk_cache/disk_cache_test_base.cc",
 612     "disk_cache/disk_cache_test_base.h",
 613     "disk_cache/disk_cache_test_util.cc",
 614     "disk_cache/disk_cache_test_util.h",
 615     "dns/dns_test_util.cc",
 616     "dns/dns_test_util.h",
 617     "dns/mock_host_resolver.cc",
 618     "dns/mock_host_resolver.h",
 619     "dns/mock_mdns_socket_factory.cc",
 620     "dns/mock_mdns_socket_factory.h",
 621     "http/http_transaction_test_util.cc",
 622     "http/http_transaction_test_util.h",
 623     "proxy/mock_proxy_resolver.cc",
 624     "proxy/mock_proxy_resolver.h",
 625     "proxy/mock_proxy_script_fetcher.cc",
 626     "proxy/mock_proxy_script_fetcher.h",
 627     "proxy/proxy_config_service_common_unittest.cc",
 628     "proxy/proxy_config_service_common_unittest.h",
 629     "socket/socket_test_util.cc",
 630     "socket/socket_test_util.h",
 631     "test/cert_test_util.cc",
 632     "test/cert_test_util.h",
 633     "test/ct_test_util.cc",
 634     "test/ct_test_util.h",
 635     "test/embedded_test_server/embedded_test_server.cc",
 636     "test/embedded_test_server/embedded_test_server.h",
 637     "test/embedded_test_server/http_connection.cc",
 638     "test/embedded_test_server/http_connection.h",
 639     "test/embedded_test_server/http_request.cc",
 640     "test/embedded_test_server/http_request.h",
 641     "test/embedded_test_server/http_response.cc",
 642     "test/embedded_test_server/http_response.h",
 643     "test/net_test_suite.cc",
 644     "test/net_test_suite.h",
 645     "test/python_utils.cc",
 646     "test/python_utils.h",
 647     "test/spawned_test_server/base_test_server.cc",
 648     "test/spawned_test_server/base_test_server.h",
 649     "test/spawned_test_server/local_test_server_posix.cc",
 650     "test/spawned_test_server/local_test_server_win.cc",
 651     "test/spawned_test_server/local_test_server.cc",
 652     "test/spawned_test_server/local_test_server.h",
 653     "test/spawned_test_server/remote_test_server.cc",
 654     "test/spawned_test_server/remote_test_server.h",
 655     "test/spawned_test_server/spawned_test_server.h",
 656     "test/spawned_test_server/spawner_communicator.cc",
 657     "test/spawned_test_server/spawner_communicator.h",
 658     "url_request/test_url_fetcher_factory.cc",
 659     "url_request/test_url_fetcher_factory.h",
 660     "url_request/url_request_test_util.cc",
 661     "url_request/url_request_test_util.h",
 662   ]
 663
 664   configs += [ ":net_win_size_truncation" ]
 665
 666   deps = [
 667     "//base",
 668     "//base/test:test_support",
 669     "//crypto:platform",
 670     "//net",
 671     "//net/tools/tld_cleanup",
 672     "//testing/gmock",
 673     "//testing/gtest",
 674     "//url",
 675   ]
 676
 677   if (is_ios) {
 678     deps += [ "//third_party/nss" ]
 679   }
 680
 681   if (!is_android) {
 682     sources -= [
 683       "test/spawned_test_server/remote_test_server.cc",
 684       "test/spawned_test_server/remote_test_server.h",
 685       "test/spawned_test_server/spawner_communicator.cc",
 686       "test/spawned_test_server/spawner_communicator.h",
 687     ]
 688   }
 689
 690   if (use_v8_in_net) {
 691     deps += [ ":net_with_v8" ]
 692   }
 693
 694   if (!enable_mdns) {
 695     sources -= [
 696       "dns/mock_mdns_socket_factory.cc",
 697       "dns/mock_mdns_socket_factory.h",
 698     ]
 699   }
 700
 701   forward_dependent_configs_from = deps
 702 }
 703
 704 source_set("balsa") {
 705   sources = [
 706     "tools/balsa/balsa_enums.h",
 707     "tools/balsa/balsa_frame.cc",
 708     "tools/balsa/balsa_frame.h",
 709     "tools/balsa/balsa_headers.cc",
 710     "tools/balsa/balsa_headers.h",
 711     "tools/balsa/balsa_headers_token_utils.cc",
 712     "tools/balsa/balsa_headers_token_utils.h",
 713     "tools/balsa/balsa_visitor_interface.h",
 714     "tools/balsa/http_message_constants.cc",
 715     "tools/balsa/http_message_constants.h",
 716     "tools/balsa/noop_balsa_visitor.h",
 717     "tools/balsa/simple_buffer.cc",
 718     "tools/balsa/simple_buffer.h",
 719     "tools/balsa/split.cc",
 720     "tools/balsa/split.h",
 721     "tools/balsa/string_piece_utils.h",
 722     "tools/quic/spdy_utils.cc",
 723     "tools/quic/spdy_utils.h",
 724   ]
 725   deps = [
 726     ":net",
 727     "//base",
 728   ]
 729 }
 730
 731 if (use_v8_in_net) {
 732   component("net_with_v8") {
 733     sources = [
 734       "proxy/proxy_resolver_v8.cc",
 735       "proxy/proxy_resolver_v8.h",
 736       "proxy/proxy_resolver_v8_tracing.cc",
 737       "proxy/proxy_resolver_v8_tracing.h",
 738       "proxy/proxy_service_v8.cc",
 739       "proxy/proxy_service_v8.h",
 740     ]
 741
 742     defines = [ "NET_IMPLEMENTATION" ]
 743     configs += [
 744       ":net_win_size_truncation",
 745       "//build/config/compiler:wexit_time_destructors",
 746     ]
 747
 748     deps = [
 749       ":net",
 750       "//base",
 751       "//gin",
 752       "//url",
 753       "//v8",
 754     ]
 755   }
 756 }
 757
 758 if (!is_ios && !is_android) {
 759   executable("crash_cache") {
 760     sources = [ "tools/crash_cache/crash_cache.cc" ]
 761     configs += [ ":net_win_size_truncation" ]
 762     deps = [
 763       ":net",
 764       ":test_support",
 765       "//base",
 766     ]
 767   }
 768
 769   executable("crl_set_dump") {
 770     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 771     configs += [ ":net_win_size_truncation" ]
 772     deps = [
 773       ":net",
 774       "//base",
 775     ]
 776   }
 777
 778   executable("dns_fuzz_stub") {
 779     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 780     configs += [ ":net_win_size_truncation" ]
 781     deps = [
 782       ":net",
 783       "//base",
 784     ]
 785   }
 786
 787   executable("gdig") {
 788     sources = [
 789       "tools/gdig/file_net_log.cc",
 790       "tools/gdig/gdig.cc",
 791     ]
 792     deps = [
 793       ":net",
 794       "//base",
 795     ]
 796   }
 797
 798   executable("get_server_time") {
 799     sources = [ "tools/get_server_time/get_server_time.cc" ]
 800     configs += [ ":net_win_size_truncation" ]
 801     deps = [
 802       ":net",
 803       "//base",
 804       "//base:i18n",
 805       "//url",
 806     ]
 807   }
 808
 809   if (use_v8_in_net) {
 810     executable("net_watcher") {
 811       sources = [ "tools/net_watcher/net_watcher.cc" ]
 812       deps = [
 813         ":net",
 814         ":net_with_v8",
 815         "//base",
 816       ]
 817
 818       if (is_linux) {
 819         configs += [ "//build/config/linux:gconf" ]
 820         deps += [ "//build/config/linux:gio" ]
 821       }
 822     }
 823   }
 824
 825   executable("run_testserver") {
 826     sources = [ "tools/testserver/run_testserver.cc" ]
 827     deps = [
 828       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 829                # in the GYP build, and can be removed when the bug is fixed.
 830       ":test_support",
 831       "//base",
 832       "//base/test:test_support",
 833       "//testing/gtest",
 834     ]
 835   }
 836
 837   executable("stress_cache") {
 838     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 839     configs += [ ":net_win_size_truncation" ]
 840     deps = [
 841       ":net",
 842       ":test_support",
 843       "//base",
 844     ]
 845   }
 846
 847   executable("tld_cleanup") {
 848     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 849     configs += [ ":net_win_size_truncation" ]
 850     deps = [
 851       "//base",
 852       "//base:i18n",
 853       "//net/tools/tld_cleanup",
 854     ]
 855   }
 856 }
 857
 858 if (is_linux) {
 859   static_library("epoll_server") {
 860     sources = [
 861       "tools/epoll_server/epoll_server.cc",
 862       "tools/epoll_server/epoll_server.h",
 863     ]
 864     deps = [
 865       ":net",
 866       "//base",
 867     ]
 868   }
 869
 870   static_library("flip_in_mem_edsm_server_base") {
 871     sources = [
 872       "tools/dump_cache/url_to_filename_encoder.cc",
 873       "tools/dump_cache/url_to_filename_encoder.h",
 874       "tools/dump_cache/url_utilities.h",
 875       "tools/dump_cache/url_utilities.cc",
 876       "tools/flip_server/acceptor_thread.h",
 877       "tools/flip_server/acceptor_thread.cc",
 878       "tools/flip_server/create_listener.cc",
 879       "tools/flip_server/create_listener.h",
 880       "tools/flip_server/constants.h",
 881       "tools/flip_server/flip_config.cc",
 882       "tools/flip_server/flip_config.h",
 883       "tools/flip_server/http_interface.cc",
 884       "tools/flip_server/http_interface.h",
 885       "tools/flip_server/loadtime_measurement.h",
 886       "tools/flip_server/mem_cache.h",
 887       "tools/flip_server/mem_cache.cc",
 888       "tools/flip_server/output_ordering.cc",
 889       "tools/flip_server/output_ordering.h",
 890       "tools/flip_server/ring_buffer.cc",
 891       "tools/flip_server/ring_buffer.h",
 892       "tools/flip_server/sm_connection.cc",
 893       "tools/flip_server/sm_connection.h",
 894       "tools/flip_server/sm_interface.h",
 895       "tools/flip_server/spdy_ssl.cc",
 896       "tools/flip_server/spdy_ssl.h",
 897       "tools/flip_server/spdy_interface.cc",
 898       "tools/flip_server/spdy_interface.h",
 899       "tools/flip_server/spdy_util.cc",
 900       "tools/flip_server/spdy_util.h",
 901       "tools/flip_server/streamer_interface.cc",
 902       "tools/flip_server/streamer_interface.h",
 903     ]
 904     deps = [
 905       ":balsa",
 906       ":epoll_server",
 907       ":net",
 908       "//base",
 909       "//third_party/openssl",
 910     ]
 911   }
 912
 913   executable("flip_in_mem_edsm_server_unittests") {
 914     sources = [
 915       "tools/flip_server/flip_test_utils.cc",
 916       "tools/flip_server/flip_test_utils.h",
 917       "tools/flip_server/http_interface_test.cc",
 918       "tools/flip_server/mem_cache_test.cc",
 919       "tools/flip_server/run_all_tests.cc",
 920       "tools/flip_server/spdy_interface_test.cc",
 921     ]
 922     deps = [
 923       ":flip_in_mem_edsm_server_base",
 924       ":net",
 925       ":test_support",
 926       "//testing/gtest",
 927       "//testing/gmock",
 928       "//third_party/openssl",
 929     ]
 930   }
 931
 932   executable("flip_in_mem_edsm_server") {
 933     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 934     deps = [
 935       ":flip_in_mem_edsm_server_base",
 936       ":net",
 937       "//base",
 938     ]
 939   }
 940
 941   source_set("quic_base") {
 942     sources = [
 943       "tools/quic/quic_client.cc",
 944       "tools/quic/quic_client.h",
 945       "tools/quic/quic_client_session.cc",
 946       "tools/quic/quic_client_session.h",
 947       "tools/quic/quic_default_packet_writer.cc",
 948       "tools/quic/quic_default_packet_writer.h",
 949       "tools/quic/quic_dispatcher.h",
 950       "tools/quic/quic_dispatcher.cc",
 951       "tools/quic/quic_epoll_clock.cc",
 952       "tools/quic/quic_epoll_clock.h",
 953       "tools/quic/quic_epoll_connection_helper.cc",
 954       "tools/quic/quic_epoll_connection_helper.h",
 955       "tools/quic/quic_in_memory_cache.cc",
 956       "tools/quic/quic_in_memory_cache.h",
 957       "tools/quic/quic_packet_writer_wrapper.cc",
 958       "tools/quic/quic_packet_writer_wrapper.h",
 959       "tools/quic/quic_server.cc",
 960       "tools/quic/quic_server.h",
 961       "tools/quic/quic_server_session.cc",
 962       "tools/quic/quic_server_session.h",
 963       "tools/quic/quic_socket_utils.cc",
 964       "tools/quic/quic_socket_utils.h",
 965       "tools/quic/quic_spdy_client_stream.cc",
 966       "tools/quic/quic_spdy_client_stream.h",
 967       "tools/quic/quic_spdy_server_stream.cc",
 968       "tools/quic/quic_spdy_server_stream.h",
 969       "tools/quic/quic_time_wait_list_manager.h",
 970       "tools/quic/quic_time_wait_list_manager.cc",
 971     ]
 972     deps = [
 973       ":balsa",
 974       ":epoll_server",
 975       ":net",
 976       "//base",
 977       "//base/third_party/dynamic_annotations",
 978       "//crypto",
 979       "//third_party/openssl",
 980       "//url",
 981     ]
 982   }
 983
 984   executable("quic_client") {
 985     sources = [ "tools/quic/quic_client_bin.cc" ]
 986     deps = [
 987       ":quic_base",
 988       ":net",
 989       "//base",
 990       "//third_party/openssl",
 991     ]
 992   }
 993 }
 994
 995 if (is_android) {
 996   generate_jni("net_jni_headers") {
 997     sources = [
 998       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
 999       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1000       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1001       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1002       "android/java/src/org/chromium/net/GURLUtils.java",
1003       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1004       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1005       "android/java/src/org/chromium/net/X509Util.java",
1006     ]
1007     jni_package = "net"
1008   }
1009 }
1010
1011 if (is_android || is_linux) {
1012   executable("disk_cache_memory_test") {
1013     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1014     deps = [
1015       ":net",
1016       "//base",
1017     ]
1018   }
1019 }
1020
1021 # TODO(GYP) make this compile on Android, we need some native test deps done.
1022 if (!is_android) {
1023
1024 source_set("quic_tools") {
1025   sources = [
1026     "quic/quic_dispatcher.cc",
1027     "quic/quic_dispatcher.h",
1028     "quic/quic_in_memory_cache.cc",
1029     "quic/quic_in_memory_cache.h",
1030     "quic/quic_per_connection_packet_writer.cc",
1031     "quic/quic_per_connection_packet_writer.h",
1032     "quic/quic_server.cc",
1033     "quic/quic_server.h",
1034     "quic/quic_server_packet_writer.cc",
1035     "quic/quic_server_packet_writer.h",
1036     "quic/quic_server_session.cc",
1037     "quic/quic_server_session.h",
1038     "quic/quic_spdy_server_stream.cc",
1039     "quic/quic_spdy_server_stream.h",
1040     "quic/quic_time_wait_list_manager.cc",
1041     "quic/quic_time_wait_list_manager.h",
1042   ]
1043   deps = [
1044     ":balsa",
1045     ":net",
1046     "//base",
1047     "//base/third_party/dynamic_annotations",
1048     "//url",
1049   ]
1050 }
1051
1052 test("net_unittests") {
1053   sources = gypi_values.net_test_sources
1054
1055   configs += [ ":net_win_size_truncation" ]
1056   defines = []
1057
1058   deps = [
1059     ":http_server",
1060     ":net",
1061     ":quic_tools",
1062     ":test_support",
1063     "//base",
1064     "//base:i18n",
1065     "//base/allocator",
1066     "//base/third_party/dynamic_annotations",
1067     "//crypto",
1068     "//crypto:platform",
1069     "//net/base/registry_controlled_domains",
1070     "//testing/gmock",
1071     "//testing/gtest",
1072     "//third_party/zlib",
1073     "//url",
1074   ]
1075
1076   if (is_linux) {
1077     sources += gypi_values.net_linux_test_sources
1078     deps += [
1079       ":balsa",
1080       ":epoll_server",
1081       ":flip_in_mem_edsm_server_base",
1082       ":quic_base",
1083     ]
1084   }
1085
1086   if (is_chromeos) {
1087     sources -= [
1088       "base/network_change_notifier_linux_unittest.cc",
1089       "proxy/proxy_config_service_linux_unittest.cc",
1090     ]
1091   }
1092
1093   if (is_android) {
1094     sources -= [
1095       # See bug http://crbug.com/344533.
1096       "disk_cache/blockfile/index_table_v3_unittest.cc",
1097       # No res_ninit() et al on Android, so this doesn't make a lot of
1098       # sense.
1099       "dns/dns_config_service_posix_unittest.cc",
1100     ]
1101     deps += [
1102       ":net_javatests",  # FIXME(brettw)
1103       ":net_test_jni_headers",
1104     ]
1105   }
1106
1107   if (!use_nss_certs) {
1108     sources -= [
1109       "ssl/client_cert_store_nss_unittest.cc",
1110     ]
1111     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1112       sources -= [
1113         "ssl/client_cert_store_chromeos_unittest.cc",
1114       ]
1115     }
1116   }
1117
1118   if (use_openssl) {
1119     # When building for OpenSSL, we need to exclude NSS specific tests
1120     # or functionality not supported by OpenSSL yet.
1121     # TODO(bulach): Add equivalent tests when the underlying
1122     #               functionality is ported to OpenSSL.
1123     sources -= [
1124       "cert/ct_objects_extractor_unittest.cc",
1125       "cert/multi_log_ct_verifier_unittest.cc",
1126       "cert/nss_cert_database_unittest.cc",
1127       "cert/nss_cert_database_chromeos_unittest.cc",
1128       "cert/nss_profile_filter_chromeos_unittest.cc",
1129       "cert/x509_util_nss_unittest.cc",
1130       "quic/test_tools/crypto_test_utils_nss.cc",
1131     ]
1132   } else {
1133     sources -= [
1134       "cert/x509_util_openssl_unittest.cc",
1135       "quic/test_tools/crypto_test_utils_openssl.cc",
1136       "socket/ssl_client_socket_openssl_unittest.cc",
1137       "socket/ssl_session_cache_openssl_unittest.cc",
1138     ]
1139     if (!is_desktop_linux && !is_chromeos) {
1140       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1141     }
1142   }
1143
1144   if (use_kerberos) {
1145     defines += [ "USE_KERBEROS" ]
1146   } else {
1147     sources -= [
1148       "http/http_auth_gssapi_posix_unittest.cc",
1149       "http/http_auth_handler_negotiate_unittest.cc",
1150       "http/mock_gssapi_library_posix.cc",
1151       "http/mock_gssapi_library_posix.h",
1152     ]
1153   }
1154
1155   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1156     # Only include this test when on Posix and using NSS for
1157     # cert verification or on iOS (which also uses NSS for certs).
1158     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1159   }
1160
1161   if (!use_openssl_certs) {
1162     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1163   }
1164
1165   if (!enable_websockets) {
1166     sources -= [
1167       "socket_stream/socket_stream_metrics_unittest.cc",
1168       "socket_stream/socket_stream_unittest.cc",
1169       "spdy/spdy_websocket_stream_unittest.cc",
1170       "websockets/websocket_basic_stream_test.cc",
1171       "websockets/websocket_channel_test.cc",
1172       "websockets/websocket_deflate_predictor_impl_test.cc",
1173       "websockets/websocket_deflate_stream_test.cc",
1174       "websockets/websocket_deflater_test.cc",
1175       "websockets/websocket_errors_test.cc",
1176       "websockets/websocket_extension_parser_test.cc",
1177       "websockets/websocket_frame_parser_test.cc",
1178       "websockets/websocket_frame_test.cc",
1179       "websockets/websocket_handshake_handler_spdy_test.cc",
1180       "websockets/websocket_handshake_handler_test.cc",
1181       "websockets/websocket_handshake_stream_create_helper_test.cc",
1182       "websockets/websocket_inflater_test.cc",
1183       "websockets/websocket_job_test.cc",
1184       "websockets/websocket_net_log_params_test.cc",
1185       "websockets/websocket_stream_test.cc",
1186       "websockets/websocket_test_util.cc",
1187       "websockets/websocket_test_util.h",
1188       "websockets/websocket_throttle_test.cc",
1189     ]
1190   }
1191
1192   if (disable_file_support) {
1193     sources -= [
1194       "base/directory_lister_unittest.cc",
1195       "url_request/url_request_file_job_unittest.cc",
1196     ]
1197   }
1198
1199   if (disable_ftp_support) {
1200     sources -= [
1201       "ftp/ftp_auth_cache_unittest.cc",
1202       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1203       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1204       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1205       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1206       "ftp/ftp_directory_listing_parser_unittest.cc",
1207       "ftp/ftp_directory_listing_parser_unittest.h",
1208       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1209       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1210       "ftp/ftp_network_transaction_unittest.cc",
1211       "ftp/ftp_util_unittest.cc",
1212       "url_request/url_request_ftp_job_unittest.cc",
1213     ]
1214   }
1215
1216   if (!enable_built_in_dns) {
1217     sources -= [
1218       "dns/address_sorter_posix_unittest.cc",
1219       "dns/address_sorter_unittest.cc",
1220     ]
1221   }
1222
1223   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1224   # net_unittest's dependency on v8 when using icu alternatives instead of
1225   # setting use_v8_in_net to 0.
1226   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1227     deps += [ ":net_with_v8" ]
1228   } else {
1229     sources -= [
1230       "proxy/proxy_resolver_v8_unittest.cc",
1231       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1232     ]
1233   }
1234
1235   if (!enable_mdns) {
1236     sources -= [
1237       "dns/mdns_cache_unittest.cc",
1238       "dns/mdns_client_unittest.cc",
1239       "dns/record_parsed_unittest.cc",
1240       "dns/record_rdata_unittest.cc",
1241     ]
1242   }
1243
1244   if (is_ios) {
1245     # TODO(GYP)
1246     #  'actions': [
1247     #    {
1248     #      'action_name': 'copy_test_data',
1249     #      'variables': {
1250     #        'test_data_files': [
1251     #          'data/ssl/certificates/',
1252     #          'data/test.html',
1253     #          'data/url_request_unittest/',
1254     #        ],
1255     #        'test_data_prefix': 'net',
1256     #      },
1257     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1258     #    },
1259     #  ],
1260     sources -= [
1261       # TODO(droger): The following tests are disabled because the
1262       # implementation is missing or incomplete.
1263       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1264       "base/keygen_handler_unittest.cc",
1265       "disk_cache/backend_unittest.cc",
1266       "disk_cache/blockfile/block_files_unittest.cc",
1267       # Need to read input data files.
1268       "filter/gzip_filter_unittest.cc",
1269       "socket/ssl_server_socket_unittest.cc",
1270       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1271       # Need TestServer.
1272       "proxy/proxy_script_fetcher_impl_unittest.cc",
1273       "socket/ssl_client_socket_unittest.cc",
1274       "url_request/url_fetcher_impl_unittest.cc",
1275       "url_request/url_request_context_builder_unittest.cc",
1276       # Needs GetAppOutput().
1277       "test/python_utils_unittest.cc",
1278
1279       # The following tests are disabled because they don't apply to
1280       # iOS.
1281       # OS is not "linux" or "freebsd" or "openbsd".
1282       "socket/unix_domain_socket_posix_unittest.cc",
1283
1284       # See bug http://crbug.com/344533.
1285       "disk_cache/blockfile/index_table_v3_unittest.cc",
1286     ]
1287   }
1288
1289   if (is_android) {
1290     sources -= [
1291       "dns/dns_config_service_posix_unittest.cc",
1292     ]
1293     # TODO(GYP)
1294     # # TODO(mmenke):  This depends on test_support_base, which depends on
1295     # #                icu.  Figure out a way to remove that dependency.
1296     # 'dependencies': [
1297     #   '../testing/android/native_test.gyp:native_test_native_code',
1298     # ]
1299
1300     set_sources_assignment_filter([])
1301     sources += [ "base/address_tracker_linux_unittest.cc" ]
1302     set_sources_assignment_filter(sources_assignment_filter)
1303   }
1304
1305   if (use_icu_alternatives_on_android) {
1306     sources -= [
1307       "base/filename_util_unittest.cc",
1308       "base/net_util_icu_unittest.cc",
1309     ]
1310     deps -= [ "//base:i18n" ]
1311   }
1312 }
1313
1314 executable("quic_server") {
1315   sources = [ "quic/quic_server_bin.cc" ]
1316   deps = [
1317     ":quic_tools",
1318     ":net",
1319     "//base",
1320     "//third_party/openssl",
1321   ]
1322 }
1323
1324 }  # !is_android