mandoline/app/android/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(is_android)
   6
   7 import("//third_party/mojo/src/mojo/public/mojo.gni")
   8 import("//build/config/android/config.gni")
   9 import("//build/config/android/rules.gni")
  10 import("//mojo/generate_mojo_shell_assets_list.gni")
  11
  12 mandoline_assets_dir = "$root_build_dir/mandoline_assets"
  13
  14 group("android") {
  15   deps = [
  16     ":mandoline_apk",
  17   ]
  18 }
  19
  20 executable("mandoline_runner") {
  21   deps = [
  22     "//mojo/common",
  23     "//mojo/environment:chromium",
  24     "//mojo/runner:mojo_runner_lib",
  25   ]
  26
  27   sources = [
  28     "../core_services_initialization.cc",
  29     "mandoline_context_init.cc",
  30   ]
  31
  32   # On android, the executable is also the native library used by the apk.
  33   # It means dynamic symbols must be preserved and exported.
  34   ldflags = [ "-Wl,--export-dynamic" ]
  35 }
  36
  37 copy("copy_mandoline_runner") {
  38   deps = [
  39     ":mandoline_runner",
  40   ]
  41   sources = [
  42     "$root_out_dir/exe.stripped/mandoline_runner",
  43   ]
  44   outputs = [
  45     "$root_out_dir/lib.stripped/libmandoline_runner.so",
  46   ]
  47 }
  48
  49 copy_ex("copy_mandoline_assets") {
  50   clear_dir = true
  51   dest = mandoline_assets_dir
  52   deps = [
  53     "//components/html_viewer",
  54     "//components/surfaces",
  55     "//mandoline/services/core_services",
  56   ]
  57   sources = [
  58     "$root_out_dir/core_services.mojo",
  59     "$root_out_dir/html_viewer",
  60     "$root_out_dir/lib.stripped/libbootstrap.so",
  61     "$root_out_dir/network_service.mojo",
  62     "$root_out_dir/obj/mojo/runner/bootstrap_java.dex.jar",
  63     "$root_out_dir/surfaces_service.mojo",
  64   ]
  65 }
  66
  67 generate_mojo_shell_assets_list("build_mandoline_assets") {
  68   deps = [
  69     ":copy_mandoline_assets",
  70   ]
  71   dir = mandoline_assets_dir
  72 }
  73
  74 android_apk("mandoline_apk") {
  75   apk_name = "Mandoline"
  76
  77   android_manifest = "apk/AndroidManifest.xml"
  78
  79   native_libs = [ "libmandoline_runner.so" ]
  80
  81   asset_location = mandoline_assets_dir
  82
  83   deps = [
  84     ":build_mandoline_assets",
  85     ":copy_mandoline_runner",
  86     "//mojo/runner:java",
  87     "//mojo/runner:resources",
  88     "//base:base_java",
  89     "//components/native_viewport:native_viewport_java",
  90     "//third_party/android_tools:google_play_services_default_resources",
  91   ]
  92 }