ui/keyboard/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//testing/test.gni")
   6 import("//third_party/google_input_tools/closure.gni")
   7 import("//third_party/google_input_tools/inputview.gni")
   8 import("//tools/grit/grit_rule.gni")
   9
  10 component("keyboard") {
  11   sources = [
  12     "keyboard.cc",
  13     "keyboard.h",
  14     "keyboard_constants.cc",
  15     "keyboard_constants.h",
  16     "keyboard_controller.cc",
  17     "keyboard_controller.h",
  18     "keyboard_controller_observer.h",
  19     "keyboard_controller_proxy.cc",
  20     "keyboard_controller_proxy.h",
  21     "keyboard_export.h",
  22     "keyboard_layout_manager.cc",
  23     "keyboard_layout_manager.h",
  24     "keyboard_switches.cc",
  25     "keyboard_switches.h",
  26     "keyboard_util.cc",
  27     "keyboard_util.h",
  28   ]
  29
  30   defines = [ "KEYBOARD_IMPLEMENTATION" ]
  31
  32   deps = [
  33     ":resources",
  34     "//base",
  35     "//base/third_party/dynamic_annotations",
  36     "//content/public/browser",
  37     "//content/public/common",
  38     "//ipc",
  39     "//skia",
  40     "//ui/aura",
  41     "//ui/base",
  42     "//ui/base/ime",
  43     "//ui/compositor",
  44     "//ui/events",
  45     "//ui/events:dom4_keycode_converter",
  46     "//ui/events:events_base",
  47     "//ui/gfx",
  48     "//ui/gfx/geometry",
  49     "//ui/wm",
  50     "//url",
  51   ]
  52 }
  53
  54 grit("resources_grit") {
  55   source = "keyboard_resources.grd"
  56   outputs = [
  57     "grit/keyboard_resources.h",
  58     "grit/keyboard_resources_map.h",
  59     "keyboard_resources.pak",
  60     "keyboard_resources.rc",
  61   ]
  62
  63   input_tools_root_dir = "//third_party/google_input_tools/src/chrome/os"
  64   inputview_gen_js = "$root_gen_dir/ui/keyboard/resources/inputview.js"
  65   grit_flags = [
  66     "-E",
  67     "input_tools_root_dir=" + rebase_path(input_tools_root_dir, "."),
  68     "-E",
  69     "inputview_gen_js=" + rebase_path(inputview_gen_js, root_build_dir),
  70   ]
  71
  72   deps = [
  73     ":inputview",
  74   ]
  75 }
  76
  77 copy("resources") {
  78   sources = [
  79     "$target_gen_dir/keyboard_resources.pak",
  80   ]
  81   outputs = [
  82     "$root_out_dir/keyboard_resources.pak",
  83   ]
  84   public_deps = [
  85     ":resources_grit",
  86   ]
  87 }
  88
  89 build_closure("inputview") {
  90   sources = inputview_sources
  91   target = "$target_gen_dir/resources/inputview.js"
  92   json_file = "//third_party/google_input_tools/inputview.gypi"
  93   sources += [ json_file ]
  94   json_sources = "variables.inputview_sources"
  95   path = rebase_path("//third_party/google_input_tools")
  96 }
  97
  98 test("keyboard_unittests") {
  99   sources = [
 100     "keyboard_controller_unittest.cc",
 101     "test/run_all_unittests.cc",
 102   ]
 103
 104   deps = [
 105     ":keyboard",
 106     "//base",
 107     "//base/allocator",
 108     "//base/test:test_support",
 109     "//content",
 110     "//skia",
 111     "//testing/gtest",
 112     "//ui/aura:test_support",
 113     "//ui/base",
 114     "//ui/base/ime",
 115     "//ui/base:test_support",
 116     "//ui/compositor:test_support",
 117     "//ui/events:test_support",
 118     "//ui/gfx",
 119     "//ui/gfx/geometry",
 120     "//ui/gl",
 121     "//ui/resources:ui_test_pak",
 122     "//ui/wm",
 123     "//url",
 124   ]
 125 }