skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11
  12 skia_support_gpu = !is_ios
  13 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  14
  15 # The list of Skia defines that are to be set for blink.
  16 gypi_blink_skia_defines =
  17     exec_script("//build/gypi_to_gn.py",
  18                 [
  19                   rebase_path(
  20                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  21                   "--replace=<(skia_include_path)=//third_party/skia/include",
  22                   "--replace=<(skia_src_path)=//third_party/skia/src",
  23                 ],
  24                 "scope",
  25                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  26
  27 # The list of Skia defines that are to be set for chromium.
  28 gypi_skia_defines =
  29     exec_script("//build/gypi_to_gn.py",
  30                 [
  31                   rebase_path(
  32                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  33                   "--replace=<(skia_include_path)=//third_party/skia/include",
  34                   "--replace=<(skia_src_path)=//third_party/skia/src",
  35                 ],
  36                 "scope",
  37                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  38
  39 # The list of Skia core sources that are to be set for chromium.
  40 gypi_skia_core =
  41     exec_script("//build/gypi_to_gn.py",
  42                 [
  43                   rebase_path("//third_party/skia/gyp/core.gypi"),
  44                   "--replace=<(skia_include_path)=//third_party/skia/include",
  45                   "--replace=<(skia_src_path)=//third_party/skia/src",
  46                 ],
  47                 "scope",
  48                 [ "//third_party/skia/gyp/core.gypi" ])
  49
  50 # The list of Skia gpu sources that are to be set for chromium.
  51 gypi_skia_gpu =
  52     exec_script("//build/gypi_to_gn.py",
  53                 [
  54                   rebase_path("//third_party/skia/gyp/gpu.gypi"),
  55                   "--replace=<(skia_include_path)=//third_party/skia/include",
  56                   "--replace=<(skia_src_path)=//third_party/skia/src",
  57                 ],
  58                 "scope",
  59                 [ "//third_party/skia/gyp/gpu.gypi" ])
  60
  61 # The list of Skia pdf sources that are to be set for chromium.
  62 gypi_skia_pdf =
  63     exec_script("//build/gypi_to_gn.py",
  64                 [
  65                   rebase_path("//third_party/skia/gyp/pdf.gypi"),
  66                   "--replace=<(skia_include_path)=//third_party/skia/include",
  67                   "--replace=<(skia_src_path)=//third_party/skia/src",
  68                 ],
  69                 "scope",
  70                 [ "//third_party/skia/gyp/pdf.gypi" ])
  71
  72 # The list of Skia effects that are to be set for chromium.
  73 gypi_skia_effects =
  74     exec_script("//build/gypi_to_gn.py",
  75                 [
  76                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  77                   "--replace=<(skia_include_path)=//third_party/skia/include",
  78                   "--replace=<(skia_src_path)=//third_party/skia/src",
  79                 ],
  80                 "scope",
  81                 [ "//third_party/skia/gyp/effects.gypi" ])
  82
  83 # The list of Skia utils that are to be set for chromium.
  84 gypi_skia_utils =
  85     exec_script("//build/gypi_to_gn.py",
  86                 [
  87                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  88                   "--replace=<(skia_include_path)=//third_party/skia/include",
  89                   "--replace=<(skia_src_path)=//third_party/skia/src",
  90                 ],
  91                 "scope",
  92                 [ "//third_party/skia/gyp/utils.gypi" ])
  93
  94 gypi_skia_opts =
  95     exec_script("//build/gypi_to_gn.py",
  96                 [
  97                   rebase_path("//third_party/skia/gyp/opts.gypi"),
  98                   "--replace=<(skia_include_path)=//third_party/skia/include",
  99                   "--replace=<(skia_src_path)=//third_party/skia/src",
 100                 ],
 101                 "scope",
 102                 [ "//third_party/skia/gyp/opts.gypi" ])
 103
 104 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 105 gypi_values =
 106     exec_script("//build/gypi_to_gn.py",
 107                 [
 108                   rebase_path("skia_gn_files.gypi"),
 109                   "--replace=<(skia_include_path)=//third_party/skia/include",
 110                   "--replace=<(skia_src_path)=//third_party/skia/src",
 111                 ],
 112                 "scope",
 113                 [ "skia_gn_files.gypi" ])
 114
 115 # External-facing config for dependent code.
 116 config("skia_config") {
 117   include_dirs = [
 118     "config",
 119     "ext",
 120     "//third_party/skia/include/c",
 121     "//third_party/skia/include/config",
 122     "//third_party/skia/include/core",
 123     "//third_party/skia/include/effects",
 124     "//third_party/skia/include/images",
 125     "//third_party/skia/include/lazy",
 126     "//third_party/skia/include/pathops",
 127     "//third_party/skia/include/pdf",
 128     "//third_party/skia/include/pipe",
 129     "//third_party/skia/include/ports",
 130     "//third_party/skia/include/utils",
 131   ]
 132
 133   defines = gypi_blink_skia_defines.blink_skia_defines
 134   defines += gypi_skia_defines.skia_for_chromium_defines
 135
 136   defines += []
 137
 138   if (component_mode == "shared_library") {
 139     defines += [
 140       "SKIA_DLL",
 141       "GR_GL_IGNORE_ES3_MSAA=0",
 142     ]
 143   }
 144
 145   if (skia_support_gpu) {
 146     include_dirs += [
 147       "//third_party/skia/include/gpu",
 148       "//third_party/skia/src/gpu",
 149     ]
 150     defines += [ "SK_SUPPORT_GPU=1" ]
 151   } else {
 152     defines += [ "SK_SUPPORT_GPU=0" ]
 153   }
 154
 155   if (is_android) {
 156     defines += [
 157       "SK_BUILD_FOR_ANDROID",
 158       "USE_CHROMIUM_SKIA",
 159     ]
 160   }
 161
 162   if (is_mac) {
 163     defines += [ "SK_BUILD_FOR_MAC" ]
 164   }
 165 }
 166
 167 # Internal-facing config for Skia library code.
 168 config("skia_library_config") {
 169   # These include directories are only included for Skia code and are not
 170   # exported to dependents. It's not clear if this is on purpose, but this
 171   # matches the GYP build.
 172   include_dirs = [
 173     "//third_party/skia/src/core",
 174     "//third_party/skia/src/image",
 175     "//third_party/skia/src/opts",
 176     "//third_party/skia/src/pdf",
 177     "//third_party/skia/src/ports",
 178     "//third_party/skia/src/sfnt",
 179     "//third_party/skia/src/utils",
 180     "//third_party/skia/src/lazy",
 181   ]
 182   if (is_mac || is_ios) {
 183     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 184   }
 185   if (is_mac) {
 186     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 187   }
 188
 189   defines = []
 190
 191   if (component_mode == "shared_library") {
 192     defines += [ "SKIA_IMPLEMENTATION=1" ]
 193   }
 194
 195   if (current_cpu == "arm") {
 196     if (arm_use_neon) {
 197       defines += [ "SK_ARM_HAS_NEON" ]
 198     }
 199     if (arm_optionally_use_neon) {
 200       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 201     }
 202   }
 203
 204   # Settings for text blitting, chosen to approximate the system browser.
 205   if (is_linux) {
 206     defines += [
 207       "SK_GAMMA_EXPONENT=1.2",
 208       "SK_GAMMA_CONTRAST=0.2",
 209       "SK_HIGH_QUALITY_IS_LANCZOS",
 210     ]
 211   } else if (is_android) {
 212     defines += [
 213       "SK_GAMMA_APPLY_TO_A8",
 214       "SK_GAMMA_EXPONENT=1.4",
 215       "SK_GAMMA_CONTRAST=0.0",
 216     ]
 217   } else if (is_win) {
 218     defines += [
 219       "SK_GAMMA_SRGB",
 220       "SK_GAMMA_CONTRAST=0.5",
 221       "SK_HIGH_QUALITY_IS_LANCZOS",
 222     ]
 223   } else if (is_mac) {
 224     defines += [
 225       "SK_GAMMA_SRGB",
 226       "SK_GAMMA_CONTRAST=0.0",
 227       "SK_HIGH_QUALITY_IS_LANCZOS",
 228     ]
 229   }
 230
 231   if (is_android) {
 232     defines += [
 233       # Android devices are typically more memory constrained, so default to a
 234       # smaller glyph cache (it may be overriden at runtime when the renderer
 235       # starts up, depending on the actual device memory).
 236       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 237     ]
 238   } else {
 239     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 240   }
 241
 242   if (is_win) {
 243     include_dirs += [
 244       "//third_party/skia/include/utils/win",
 245       "//third_party/skia/src/utils/win",
 246     ]
 247
 248     defines += [
 249       # On windows, GDI handles are a scarse system-wide resource so we have to
 250       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 251       # fairly small size. http://crbug.com/314387
 252       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 253     ]
 254
 255     cflags = [
 256       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 257       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 258       "/wd4341",  # signed value is out of range for enum constant.
 259       "/wd4345",  # Object is default-initialized if initialization is omitted.
 260       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 261       "/wd4554",  # 'operator' : check operator precedence for possible error
 262       "/wd4748",  # compiler will disable optimizations if a function has inline
 263                   # assembly code contains flow control(jmp or jcc) statements.
 264
 265       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 266     ]
 267   }
 268 }
 269
 270 component("skia") {
 271   sources = [
 272     # Chrome sources.
 273     "config/SkUserConfig.h",
 274     "ext/SkDiscardableMemory_chrome.cc",
 275     "ext/SkDiscardableMemory_chrome.h",
 276     "ext/SkMemory_new_handler.cpp",
 277     "ext/analysis_canvas.cc",
 278     "ext/analysis_canvas.h",
 279     "ext/benchmarking_canvas.cc",
 280     "ext/benchmarking_canvas.h",
 281     "ext/bitmap_platform_device.h",
 282     "ext/convolver.cc",
 283     "ext/convolver.h",
 284     "ext/event_tracer_impl.cc",
 285     "ext/event_tracer_impl.h",
 286     "ext/fontmgr_default_win.cc",
 287     "ext/fontmgr_default_win.h",
 288     "ext/google_logging.cc",
 289     "ext/image_operations.cc",
 290     "ext/image_operations.h",
 291     "ext/opacity_draw_filter.cc",
 292     "ext/opacity_draw_filter.h",
 293     "ext/pixel_ref_utils.cc",
 294     "ext/pixel_ref_utils.h",
 295     "ext/platform_canvas.cc",
 296     "ext/platform_canvas.h",
 297     "ext/platform_device.cc",
 298     "ext/platform_device.h",
 299     "ext/platform_device_linux.cc",
 300     "ext/platform_device_mac.cc",
 301     "ext/platform_device_win.cc",
 302     "ext/recursive_gaussian_convolution.cc",
 303     "ext/recursive_gaussian_convolution.h",
 304     "ext/refptr.h",
 305     "ext/skia_utils_base.cc",
 306     "ext/skia_utils_base.h",
 307     "ext/skia_utils_ios.h",
 308     "ext/skia_utils_ios.mm",
 309     "ext/skia_utils_mac.h",
 310     "ext/skia_utils_mac.mm",
 311     "ext/skia_utils_win.cc",
 312     "ext/skia_utils_win.h",
 313   ]
 314
 315   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 316   sources += gypi_skia_core.sources
 317   sources += gypi_skia_effects.sources
 318   sources += gypi_skia_utils.sources
 319   sources += gypi_values.skia_library_sources
 320
 321   # This and skia_opts are really the same conceptual target so share headers.
 322   allow_circular_includes_from = [ ":skia_opts" ]
 323
 324   if (current_cpu == "arm") {
 325     sources += [
 326       "//third_party/skia/src/core/SkUtilsArm.cpp",
 327       "//third_party/skia/src/core/SkUtilsArm.h",
 328     ]
 329   }
 330
 331   # GPU
 332   if (skia_support_gpu) {
 333     sources += gypi_skia_gpu.skgpu_sources
 334     sources += gypi_skia_gpu.skgpu_null_gl_sources
 335   }
 336
 337   # Remove unused util files include in utils.gypi
 338   sources -= [
 339     "//third_party/skia/include/utils/SkBoundaryPatch.h",
 340     "//third_party/skia/include/utils/SkCamera.h",
 341     "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 342     "//third_party/skia/include/utils/SkCubicInterval.h",
 343     "//third_party/skia/include/utils/SkCullPoints.h",
 344     "//third_party/skia/include/utils/SkDebugUtils.h",
 345     "//third_party/skia/include/utils/SkDumpCanvas.h",
 346     "//third_party/skia/include/utils/SkEventTracer.h",
 347     "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 348     "//third_party/skia/include/utils/SkInterpolator.h",
 349     "//third_party/skia/include/utils/SkLayer.h",
 350     "//third_party/skia/include/utils/SkMeshUtils.h",
 351     "//third_party/skia/include/utils/SkNinePatch.h",
 352     "//third_party/skia/include/utils/SkParsePaint.h",
 353     "//third_party/skia/include/utils/SkParsePath.h",
 354     "//third_party/skia/include/utils/SkRandom.h",
 355     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 356     "//third_party/skia/src/utils/SkBitmapHasher.h",
 357     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 358     "//third_party/skia/src/utils/SkCamera.cpp",
 359     "//third_party/skia/src/utils/SkCanvasStack.h",
 360     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 361     "//third_party/skia/src/utils/SkCullPoints.cpp",
 362     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 363     "//third_party/skia/src/utils/SkFloatUtils.h",
 364     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 365     "//third_party/skia/src/utils/SkInterpolator.cpp",
 366     "//third_party/skia/src/utils/SkLayer.cpp",
 367     "//third_party/skia/src/utils/SkMD5.cpp",
 368     "//third_party/skia/src/utils/SkMD5.h",
 369     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 370     "//third_party/skia/src/utils/SkNinePatch.cpp",
 371     "//third_party/skia/src/utils/SkOSFile.cpp",
 372     "//third_party/skia/src/utils/SkParsePath.cpp",
 373     "//third_party/skia/src/utils/SkPathUtils.cpp",
 374     "//third_party/skia/src/utils/SkSHA1.cpp",
 375     "//third_party/skia/src/utils/SkSHA1.h",
 376     "//third_party/skia/src/utils/SkTFitsIn.h",
 377     "//third_party/skia/src/utils/SkTLogic.h",
 378
 379     # We don't currently need to change thread affinity, so leave out this complexity for now.
 380     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 381     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 382
 383     #testing
 384     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 385     "//third_party/skia/src/fonts/SkGScalerContext.h",
 386   ]
 387
 388   if (is_win) {
 389     sources -= [
 390       # Keeping _win.cpp
 391       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 392       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 393     ]
 394   } else {
 395     sources -= [
 396       # Keeping _pthread.cpp and _pthread_other.cpp.
 397       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 398     ]
 399   }
 400
 401   # need separate win section to handle chromes auto gn filter
 402   # (build/config/BUILDCONFIG.gn)
 403   if (is_win) {
 404     sources -= [
 405       #windows
 406       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 407       "//third_party/skia/include/utils/win/SkHRESULT.h",
 408       "//third_party/skia/include/utils/win/SkIStream.h",
 409       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 410       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 411       "//third_party/skia/src/utils/win/SkIStream.cpp",
 412       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 413     ]
 414   }
 415
 416   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 417     sources -= [ "ext/skia_utils_base.cc" ]
 418   }
 419
 420   # Fixup skia library sources.
 421   if (is_win) {
 422     sources -= [
 423       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 424       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 425       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 426     ]
 427   } else {
 428     sources -= [
 429       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 430       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 431       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 432       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 433       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 434       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 435       "//third_party/skia/src/ports/SkTLS_win.cpp",
 436       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 437       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 438     ]
 439   }
 440   if (!is_android) {
 441     sources -= [
 442       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 443       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 444     ]
 445   }
 446   if (!is_mac) {
 447     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 448   }
 449
 450   if (!is_linux) {
 451     sources -= [
 452       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 453       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 454       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 455     ]
 456   }
 457
 458   if (!is_linux && !is_android) {
 459     sources -= [
 460       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 461       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 462     ]
 463   }
 464
 465   # Select the right BitmapPlatformDevice.
 466   if (is_win) {
 467     sources += [
 468       "ext/bitmap_platform_device_win.cc",
 469       "ext/bitmap_platform_device_win.h",
 470     ]
 471   } else if (is_mac) {
 472     sources += [
 473       "ext/bitmap_platform_device_mac.cc",
 474       "ext/bitmap_platform_device_mac.h",
 475     ]
 476   } else if (use_cairo) {
 477     sources += [
 478       "ext/bitmap_platform_device_cairo.cc",
 479       "ext/bitmap_platform_device_cairo.h",
 480     ]
 481   } else {
 482     sources += [
 483       "ext/bitmap_platform_device_skia.cc",
 484       "ext/bitmap_platform_device_skia.h",
 485     ]
 486   }
 487
 488   if (is_clang) {
 489     # Skia won't compile with some of the more strict clang warnings.
 490     # e.g. it does:
 491     #  SkASSERT(!"sk_out_of_memory");
 492     configs -= [ "//build/config/clang:extra_warnings" ]
 493   }
 494
 495   configs -= [ "//build/config/compiler:chromium_code" ]
 496   configs += [
 497     ":skia_library_config",
 498     "//build/config/compiler:no_chromium_code",
 499   ]
 500   public_configs = [ ":skia_config" ]
 501
 502   deps = [
 503     ":skia_opts",
 504     "//base",
 505     "//base/third_party/dynamic_annotations",
 506     "//third_party/zlib",
 507   ]
 508
 509   if (is_linux) {
 510     configs += [
 511       "//build/config/linux:fontconfig",
 512       "//build/config/linux:freetype2",
 513     ]
 514     if (use_pango) {
 515       configs += [ "//build/config/linux:pangocairo" ]
 516     }
 517     deps += [ "//third_party/icu:icuuc" ]
 518   }
 519
 520   if (is_android) {
 521     set_sources_assignment_filter([])
 522     sources += [ "ext/platform_device_linux.cc" ]
 523     set_sources_assignment_filter(sources_assignment_filter)
 524     deps += [
 525       "//third_party/expat",
 526       "//third_party/freetype",
 527       "//third_party/android_tools:cpu_features",
 528     ]
 529   }
 530
 531   if (skia_support_pdf) {
 532     deps += [ "//third_party/sfntly" ]
 533     sources += gypi_skia_pdf.sources
 534   }
 535
 536   if (is_android && !is_debug) {
 537     configs -= [ "//build/config/compiler:optimize" ]
 538     configs += [ "//build/config/compiler:optimize_max" ]
 539   }
 540 }
 541
 542 # Separated out so it can be compiled with different flags for SSE.
 543 source_set("skia_opts") {
 544   cflags = []
 545   defines = []
 546
 547   if (current_cpu == "x86" || current_cpu == "x64") {
 548     sources = gypi_skia_opts.sse2_sources + gypi_skia_opts.ssse3_sources +
 549               gypi_skia_opts.sse41_sources +
 550               [
 551                 # Chrome-specific.
 552                 "ext/convolver_SSE2.cc",
 553               ]
 554
 555     if (is_linux || is_mac) {
 556       cflags += [ "-msse4.1" ]
 557     }
 558   } else if (current_cpu == "arm") {
 559     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 560     # ARM), the compiler doesn't like that.
 561     cflags += [ "-fomit-frame-pointer" ]
 562
 563     if (arm_version >= 7) {
 564       sources = gypi_skia_opts.armv7_sources
 565       if (arm_use_neon || arm_optionally_use_neon) {
 566         sources += gypi_skia_opts.neon_sources
 567
 568         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 569         # when running this.
 570         if (!arm_use_neon) {
 571           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 572           cflags += [ "-mfpu=neon" ]
 573         }
 574       }
 575     } else {
 576       sources = gypi_skia_opts.none_sourcees
 577     }
 578   } else if (current_cpu == "mipsel") {
 579     cflags += [ "-fomit-frame-pointer" ]
 580     sources = gypi_skia_opts.none_sources
 581   } else {
 582     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 583   }
 584
 585   if (is_android && !is_debug) {
 586     configs -= [ "//build/config/compiler:optimize" ]
 587     configs += [ "//build/config/compiler:optimize_max" ]
 588   }
 589
 590   configs -= [ "//build/config/compiler:chromium_code" ]
 591   configs += [
 592     ":skia_config",
 593     ":skia_library_config",
 594     "//build/config/compiler:no_chromium_code",
 595   ]
 596
 597   deps = [
 598     "//base",
 599   ]
 600
 601   visibility = [ ":skia" ]
 602 }
 603
 604 test("skia_unittests") {
 605   sources = [
 606     "ext/analysis_canvas_unittest.cc",
 607     "ext/bitmap_platform_device_mac_unittest.cc",
 608     "ext/convolver_unittest.cc",
 609     "ext/image_operations_unittest.cc",
 610     "ext/pixel_ref_utils_unittest.cc",
 611     "ext/platform_canvas_unittest.cc",
 612     "ext/recursive_gaussian_convolution_unittest.cc",
 613     "ext/refptr_unittest.cc",
 614     "ext/skia_utils_ios_unittest.mm",
 615     "ext/skia_utils_mac_unittest.mm",
 616   ]
 617
 618   if (!is_win && !is_mac) {
 619     sources -= [ "ext/platform_canvas_unittest.cc" ]
 620   }
 621
 622   deps = [
 623     ":skia",
 624     "//base",
 625     "//base/test:run_all_unittests",
 626     "//cc:test_support",  # TODO: Fix this test to not depend on cc.
 627     "//testing/gtest",
 628     "//ui/gfx",
 629     "//ui/gfx/geometry",
 630   ]
 631 }
 632
 633 if (is_linux && !is_chromeos) {
 634   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 635   executable("image_operations_bench") {
 636     sources = [
 637       "ext/image_operations_bench.cc",
 638     ]
 639
 640     deps = [
 641       ":skia",
 642       "//base",
 643     ]
 644   }
 645
 646   executable("filter_fuzz_stub") {
 647     sources = [
 648       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 649     ]
 650
 651     deps = [
 652       ":skia",
 653       "//base",
 654     ]
 655   }
 656 }