base/trace_event/etw_manifest/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(is_win, "This only runs on Windows.")
   6
   7 # Makes the .h/.rc files from the .man file.
   8 action("chrome_events_win_generate") {
   9   visibility = [ ":*" ]
  10   script = "build/message_compiler.py"
  11
  12   sources = [
  13     "chrome_events_win.man",
  14   ]
  15
  16   outputs = [
  17     "$target_gen_dir/chrome_events_win.h",
  18     "$target_gen_dir/chrome_events_win.rc",
  19   ]
  20
  21   args = [
  22     # Where to put the header.
  23     "-h",
  24     rebase_path("$target_gen_dir", root_build_dir),
  25
  26     # Where to put the .rc file.
  27     "-r",
  28     rebase_path("$target_gen_dir", root_build_dir),
  29
  30     # Generate the user-mode code.
  31     "-um",
  32     rebase_path("chrome_events_win.man", root_build_dir),
  33   ]
  34 }
  35
  36 # Compile the generated files.
  37 source_set("chrome_events_win") {
  38   visibility = [
  39     "//base/trace_event/*",
  40     "//chrome:main_dll",
  41   ]
  42
  43   sources = get_target_outputs(":chrome_events_win_generate")
  44
  45   deps = [
  46     ":chrome_events_win_generate",
  47   ]
  48 }