build/config/BUILDCONFIG.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # =============================================================================
   6 # PLATFORM SELECTION
   7 # =============================================================================
   8 #
   9 # There are two main things to set: "os" and "cpu". The "toolchain" is the name
  10 # of the GN thing that encodes combinations of these things.
  11 #
  12 # Users typically only set the variables "target_os" and "target_cpu" in "gn
  13 # args", the rest are set up by our build and internal to GN.
  14 #
  15 # There are three different types of each of these things: The "host"
  16 # represents the computer doing the compile and never changes. The "target"
  17 # represents the main thing we're trying to build. The "current" represents
  18 # which configuration is currently being defined, which can be either the
  19 # host, the target, or something completely different (like nacl). GN will
  20 # run the same build file multiple times for the different required
  21 # configuration in the same build.
  22 #
  23 # This gives the following variables:
  24 #  - host_os, host_cpu, host_toolchain
  25 #  - target_os, target_cpu, default_toolchain
  26 #  - current_os, current_cpu, current_toolchain.
  27 #
  28 # Note the default_toolchain isn't symmetrical (you would expect
  29 # target_toolchain). This is because the "default" toolchain is a GN built-in
  30 # concept, and "target" is something our build sets up that's symmetrical with
  31 # its GYP counterpart. Potentially the built-in default_toolchain variable
  32 # could be renamed in the future.
  33 #
  34 # When writing build files, to do something only for the host:
  35 #   if (current_toolchain == host_toolchain) { ...
  36
  37 if (target_os == "") {
  38   target_os = host_os
  39 }
  40
  41 if (target_cpu == "") {
  42   if (target_os == "android") {
  43     # If we're building for Android, we should assume that we want to
  44     # build for ARM by default, not the host_cpu (which is likely x64).
  45     # This allows us to not have to specify both target_os and target_cpu
  46     # on the command line.
  47     target_cpu = "arm"
  48   } else {
  49     target_cpu = host_cpu
  50   }
  51 }
  52
  53 if (current_cpu == "") {
  54   current_cpu = target_cpu
  55 }
  56 if (current_os == "") {
  57   current_os = target_os
  58 }
  59
  60 # =============================================================================
  61 # BUILD FLAGS
  62 # =============================================================================
  63 #
  64 # This block lists input arguments to the build, along with their default
  65 # values.
  66 #
  67 # If a value is specified on the command line, it will overwrite the defaults
  68 # given in a declare_args block, otherwise the default will be used.
  69 #
  70 # YOU SHOULD ALMOST NEVER NEED TO ADD FLAGS TO THIS FILE. GN allows any file in
  71 # the build to declare build flags. If you need a flag for a single component,
  72 # you can just declare it in the corresponding BUILD.gn file. If you need a
  73 # flag in multiple components, there are a few options:
  74 #
  75 # - If your feature is a single target, say //components/foo, and the targets
  76 #   depending on foo need to have some define set if foo is enabled: (1) Write
  77 #   a declare_args block in foo's BUILD.gn file listing your enable_foo build
  78 #   flag. (2) Write a config in that file listing the define, and list that
  79 #   config in foo's public_configs. This will propagate that define to all the
  80 #   targets depending on foo. (3) When foo is not enabled, just make it expand
  81 #   to an empty group (or whatever's appropriate for the "off" state of your
  82 #   feature.
  83 #
  84 # - If a semi-random set of targets need to know about a define: (1) In the
  85 #   lowest level of the build that knows about this feature, add a declare_args
  86 #   block in the build file for your enable flag. (2) Write a config that adds
  87 #   a define conditionally based on that build flags. (3) Manually add that
  88 #   config to the "configs" applying to the targets that need the define.
  89 #
  90 # - If a semi-random set of targets need to know about the build flag (to do
  91 #   file inclusion or exclusion, more than just defines): (1) Write a .gni file
  92 #   in the lowest-level directory that knows about the feature. (2) Put the
  93 #   declare_args block with your build flag in that .gni file. (3) Import that
  94 #   .gni file from the BUILD.gn files that need the flag.
  95 #
  96 # Other advice:
  97 #
  98 # - Use boolean values when possible. If you need a default value that expands
  99 #   to some complex thing in the default case (like the location of the
 100 #   compiler which would be computed by a script), use a default value of -1 or
 101 #   the empty string. Outside of the declare_args block, conditionally expand
 102 #   the default value as necessary.
 103 #
 104 # - Use a name like "use_foo" or "is_foo" (whatever is more appropriate for
 105 #   your feature) rather than just "foo".
 106 #
 107 # - Write good comments directly above the declaration with no blank line.
 108 #   These comments will appear as documentation in "gn args --list".
 109 #
 110 # - Don't call exec_script inside declare_args. This will execute the script
 111 #   even if the value is overridden, which is wasteful. See first bullet.
 112
 113 declare_args() {
 114   # How many symbols to include in the build. This affects the performance of
 115   # the build since the symbols are large and dealing with them is slow.
 116   #   2 means regular build with symbols.
 117   #   1 means minimal symbols, usually enough for backtraces only.
 118   #   0 means no symbols.
 119   #   -1 means auto-set (off in release, regular in debug).
 120   symbol_level = -1
 121
 122   # Component build.
 123   is_component_build = false
 124
 125   # Debug build.
 126   is_debug = true
 127
 128   # Whether we're a traditional desktop unix.
 129   is_desktop_linux = current_os == "linux" && current_os != "chromeos"
 130
 131   # Set to true when compiling with the Clang compiler. Typically this is used
 132   # to configure warnings.
 133   is_clang = current_os == "mac" || current_os == "ios" ||
 134              current_os == "linux" || current_os == "chromeos"
 135
 136   # Compile for Address Sanitizer to find memory bugs.
 137   is_asan = false
 138
 139   # Compile for Leak Sanitizer to find leaks.
 140   is_lsan = false
 141
 142   # Compile for Memory Sanitizer to find uninitialized reads.
 143   is_msan = false
 144
 145   # Compile for Thread Sanitizer to find threading bugs.
 146   is_tsan = false
 147
 148   if (current_os == "chromeos") {
 149     # Allows the target toolchain to be injected as arguments. This is needed
 150     # to support the CrOS build system which supports per-build-configuration
 151     # toolchains.
 152     cros_use_custom_toolchain = false
 153   }
 154
 155   # DON'T ADD MORE FLAGS HERE. Read the comment above.
 156 }
 157
 158 # =============================================================================
 159 # OS DEFINITIONS
 160 # =============================================================================
 161 #
 162 # We set these various is_FOO booleans for convenience in writing OS-based
 163 # conditions.
 164 #
 165 # - is_android, is_chromeos, is_ios, and is_win should be obvious.
 166 # - is_mac is set only for desktop Mac. It is not set on iOS.
 167 # - is_posix is true for mac and any Unix-like system (basically everything
 168 #   except Windows).
 169 # - is_linux is true for desktop Linux and ChromeOS, but not Android (which is
 170 #   generally too different despite being based on the Linux kernel).
 171 #
 172 # Do not add more is_* variants here for random lesser-used Unix systems like
 173 # aix or one of the BSDs. If you need to check these, just check the
 174 # current_os value directly.
 175
 176 if (current_os == "win") {
 177   is_android = false
 178   is_chromeos = false
 179   is_ios = false
 180   is_linux = false
 181   is_mac = false
 182   is_nacl = false
 183   is_posix = false
 184   is_win = true
 185 } else if (current_os == "mac") {
 186   is_android = false
 187   is_chromeos = false
 188   is_ios = false
 189   is_linux = false
 190   is_mac = true
 191   is_nacl = false
 192   is_posix = true
 193   is_win = false
 194 } else if (current_os == "android") {
 195   is_android = true
 196   is_chromeos = false
 197   is_ios = false
 198   is_linux = false
 199   is_mac = false
 200   is_nacl = false
 201   is_posix = true
 202   is_win = false
 203 } else if (current_os == "chromeos") {
 204   is_android = false
 205   is_chromeos = true
 206   is_ios = false
 207   is_linux = true
 208   is_mac = false
 209   is_nacl = false
 210   is_posix = true
 211   is_win = false
 212 } else if (current_os == "nacl") {
 213   # current_os == "nacl" will be passed by the nacl toolchain definition.
 214   # It is not set by default or on the command line. We treat is as a
 215   # Posix variant.
 216   is_android = false
 217   is_chromeos = false
 218   is_ios = false
 219   is_linux = false
 220   is_mac = false
 221   is_nacl = true
 222   is_posix = true
 223   is_win = false
 224 } else if (current_os == "ios") {
 225   is_android = false
 226   is_chromeos = false
 227   is_ios = true
 228   is_linux = false
 229   is_mac = false
 230   is_nacl = false
 231   is_posix = true
 232   is_win = false
 233 } else if (current_os == "linux") {
 234   is_android = false
 235   is_chromeos = false
 236   is_ios = false
 237   is_linux = true
 238   is_mac = false
 239   is_nacl = false
 240   is_posix = true
 241   is_win = false
 242 }
 243
 244 # =============================================================================
 245 # SOURCES FILTERS
 246 # =============================================================================
 247 #
 248 # These patterns filter out platform-specific files when assigning to the
 249 # sources variable. The magic variable |sources_assignment_filter| is applied
 250 # to each assignment or appending to the sources variable and matches are
 251 # automatcally removed.
 252 #
 253 # Note that the patterns are NOT regular expressions. Only "*" and "\b" (path
 254 # boundary = end of string or slash) are supported, and the entire string
 255 # muct match the pattern (so you need "*.cc" to match all .cc files, for
 256 # example).
 257
 258 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 259 # below.
 260 sources_assignment_filter = []
 261 if (!is_posix) {
 262   sources_assignment_filter += [
 263     "*_posix.h",
 264     "*_posix.cc",
 265     "*_posix_unittest.h",
 266     "*_posix_unittest.cc",
 267     "*\bposix/*",
 268   ]
 269 }
 270 if (!is_win) {
 271   sources_assignment_filter += [
 272     "*_win.cc",
 273     "*_win.h",
 274     "*_win_unittest.cc",
 275     "*\bwin/*",
 276     "*.def",
 277     "*.rc",
 278   ]
 279 }
 280 if (!is_mac) {
 281   sources_assignment_filter += [
 282     "*_mac.h",
 283     "*_mac.cc",
 284     "*_mac.mm",
 285     "*_mac_unittest.h",
 286     "*_mac_unittest.cc",
 287     "*_mac_unittest.mm",
 288     "*\bmac/*",
 289     "*_cocoa.h",
 290     "*_cocoa.cc",
 291     "*_cocoa.mm",
 292     "*_cocoa_unittest.h",
 293     "*_cocoa_unittest.cc",
 294     "*_cocoa_unittest.mm",
 295     "*\bcocoa/*",
 296   ]
 297 }
 298 if (!is_ios) {
 299   sources_assignment_filter += [
 300     "*_ios.h",
 301     "*_ios.cc",
 302     "*_ios.mm",
 303     "*_ios_unittest.h",
 304     "*_ios_unittest.cc",
 305     "*_ios_unittest.mm",
 306     "*\bios/*",
 307   ]
 308 }
 309 if (!is_mac && !is_ios) {
 310   sources_assignment_filter += [ "*.mm" ]
 311 }
 312 if (!is_linux) {
 313   sources_assignment_filter += [
 314     "*_linux.h",
 315     "*_linux.cc",
 316     "*_linux_unittest.h",
 317     "*_linux_unittest.cc",
 318     "*\blinux/*",
 319   ]
 320 }
 321 if (!is_android) {
 322   sources_assignment_filter += [
 323     "*_android.h",
 324     "*_android.cc",
 325     "*_android_unittest.h",
 326     "*_android_unittest.cc",
 327     "*\bandroid/*",
 328   ]
 329 }
 330 if (!is_chromeos) {
 331   sources_assignment_filter += [
 332     "*_chromeos.h",
 333     "*_chromeos.cc",
 334     "*_chromeos_unittest.h",
 335     "*_chromeos_unittest.cc",
 336     "*\bchromeos/*",
 337   ]
 338 }
 339
 340 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 341 # below.
 342
 343 # Actually save this list.
 344 #
 345 # These patterns are executed for every file in the source tree of every run.
 346 # Therefore, adding more patterns slows down the build for everybody. We should
 347 # only add automatic patterns for configurations affecting hundreds of files
 348 # across many projects in the tree.
 349 #
 350 # Therefore, we only add rules to this list corresponding to platforms on the
 351 # Chromium waterfall.  This is not for non-officially-supported platforms
 352 # (FreeBSD, etc.) toolkits, (X11, GTK, etc.), or features. For these cases,
 353 # write a conditional in the target to remove the file(s) from the list when
 354 # your platform/toolkit/feature doesn't apply.
 355 set_sources_assignment_filter(sources_assignment_filter)
 356
 357 # =============================================================================
 358 # BUILD OPTIONS
 359 # =============================================================================
 360
 361 # These Sanitizers all imply using the Clang compiler. On Windows they either
 362 # don't work or work differently.
 363 if (!is_clang && (is_asan || is_lsan || is_tsan || is_msan)) {
 364   is_clang = true
 365 }
 366
 367 # =============================================================================
 368 # TARGET DEFAULTS
 369 # =============================================================================
 370 #
 371 # Set up the default configuration for every build target of the given type.
 372 # The values configured here will be automatically set on the scope of the
 373 # corresponding target. Target definitions can add or remove to the settings
 374 # here as needed.
 375
 376 # Holds all configs used for making native executables and libraries, to avoid
 377 # duplication in each target below.
 378 _native_compiler_configs = [
 379   "//build/config:feature_flags",
 380   "//build/config/compiler:compiler",
 381   "//build/config/compiler:compiler_arm_fpu",
 382   "//build/config/compiler:chromium_code",
 383   "//build/config/compiler:default_include_dirs",
 384   "//build/config/compiler:no_rtti",
 385   "//build/config/compiler:runtime_library",
 386 ]
 387 if (is_win) {
 388   _native_compiler_configs += [
 389     "//build/config/win:lean_and_mean",
 390     "//build/config/win:nominmax",
 391     "//build/config/win:sdk",
 392     "//build/config/win:unicode",
 393     "//build/config/win:winver",
 394   ]
 395 }
 396 if (is_posix) {
 397   _native_compiler_configs += [
 398     "//build/config/gcc:no_exceptions",
 399     "//build/config/gcc:symbol_visibility_hidden",
 400   ]
 401 }
 402
 403 if (is_linux) {
 404   _native_compiler_configs += [ "//build/config/linux:sdk" ]
 405 } else if (is_mac) {
 406   _native_compiler_configs += [ "//build/config/mac:sdk" ]
 407 } else if (is_ios) {
 408   _native_compiler_configs += [ "//build/config/ios:sdk" ]
 409 } else if (is_android) {
 410   _native_compiler_configs += [ "//build/config/android:sdk" ]
 411 }
 412
 413 if (is_clang) {
 414   _native_compiler_configs += [
 415     "//build/config/clang:find_bad_constructs",
 416     "//build/config/clang:extra_warnings",
 417   ]
 418 }
 419
 420 # Optimizations and debug checking.
 421 if (is_debug) {
 422   _native_compiler_configs += [ "//build/config:debug" ]
 423   _default_optimization_config = "//build/config/compiler:no_optimize"
 424 } else {
 425   _native_compiler_configs += [ "//build/config:release" ]
 426   _default_optimization_config = "//build/config/compiler:optimize"
 427 }
 428 _native_compiler_configs += [ _default_optimization_config ]
 429
 430 # If it wasn't manually set, set to an appropriate default.
 431 if (symbol_level == -1) {
 432   # Linux is slowed by having symbols as part of the target binary, whereas
 433   # Mac and Windows have them separate, so in Release Linux, default them off.
 434   if (is_debug || !is_linux) {
 435     symbol_level = 2
 436   } else if (is_asan || is_lsan || is_tsan || is_msan) {
 437     # Sanitizers require symbols for filename suppressions to work.
 438     symbol_level = 1
 439   } else {
 440     symbol_level = 0
 441   }
 442 }
 443
 444 # Symbol setup.
 445 if (symbol_level == 2) {
 446   _default_symbols_config = "//build/config/compiler:symbols"
 447 } else if (symbol_level == 1) {
 448   _default_symbols_config = "//build/config/compiler:minimal_symbols"
 449 } else if (symbol_level == 0) {
 450   _default_symbols_config = "//build/config/compiler:no_symbols"
 451 } else {
 452   assert(false, "Bad value for symbol_level.")
 453 }
 454 _native_compiler_configs += [ _default_symbols_config ]
 455
 456 # Windows linker setup for EXEs and DLLs.
 457 if (is_win) {
 458   _windows_linker_configs = [
 459     "//build/config/win:default_incremental_linking",
 460     "//build/config/win:sdk_link",
 461     "//build/config/win:common_linker_setup",
 462
 463     # Default to console-mode apps. Most of our targets are tests and such
 464     # that shouldn't use the windows subsystem.
 465     "//build/config/win:console",
 466   ]
 467 }
 468
 469 # Executable defaults.
 470 _executable_configs =
 471     _native_compiler_configs + [ "//build/config:default_libs" ]
 472 if (is_win) {
 473   _executable_configs += _windows_linker_configs
 474 } else if (is_mac) {
 475   _executable_configs += [
 476     "//build/config/mac:mac_dynamic_flags",
 477     "//build/config/mac:mac_executable_flags",
 478   ]
 479 } else if (is_linux || is_android) {
 480   _executable_configs += [ "//build/config/gcc:executable_ldconfig" ]
 481   if (is_android) {
 482     _executable_configs += [ "//build/config/android:executable_config" ]
 483   }
 484 }
 485 set_defaults("executable") {
 486   configs = _executable_configs
 487 }
 488
 489 # Static library defaults.
 490 set_defaults("static_library") {
 491   configs = _native_compiler_configs
 492 }
 493
 494 # Shared library defaults (also for components in component mode).
 495 _shared_library_configs =
 496     _native_compiler_configs + [ "//build/config:default_libs" ]
 497 if (is_win) {
 498   _shared_library_configs += _windows_linker_configs
 499 } else if (is_mac) {
 500   _shared_library_configs += [ "//build/config/mac:mac_dynamic_flags" ]
 501 } else if (is_android) {
 502   # Strip native JNI exports from shared libraries by default. Binaries that
 503   # want this can remove this config.
 504   _shared_library_configs +=
 505       [ "//build/config/android:hide_native_jni_exports" ]
 506 }
 507 set_defaults("shared_library") {
 508   configs = _shared_library_configs
 509 }
 510 if (is_component_build) {
 511   set_defaults("component") {
 512     configs = _shared_library_configs
 513   }
 514 }
 515
 516 # Source set defaults (also for components in non-component mode).
 517 set_defaults("source_set") {
 518   configs = _native_compiler_configs
 519 }
 520 if (!is_component_build) {
 521   set_defaults("component") {
 522     configs = _native_compiler_configs
 523   }
 524 }
 525
 526 # Test defaults.
 527 set_defaults("test") {
 528   if (is_android) {
 529     configs = _shared_library_configs
 530   } else {
 531     configs = _executable_configs
 532   }
 533 }
 534
 535 # ==============================================================================
 536 # TOOLCHAIN SETUP
 537 # ==============================================================================
 538 #
 539 # Here we set the default toolchain, as well as the variable host_toolchain
 540 # which will identify the toolchain corresponding to the local system when
 541 # doing cross-compiles. When not cross-compiling, this will be the same as the
 542 # default toolchain.
 543
 544 if (is_win) {
 545   # On windows we use the same toolchain for host and target by default.
 546   if (is_clang) {
 547     host_toolchain = "//build/toolchain/win:clang_$current_cpu"
 548   } else {
 549     host_toolchain = "//build/toolchain/win:$current_cpu"
 550   }
 551   set_default_toolchain("$host_toolchain")
 552 } else if (is_android) {
 553   if (host_os == "linux") {
 554     # Use clang for the x86/64 Linux host builds.
 555     if (host_cpu == "x86" || host_cpu == "x64") {
 556       host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
 557     } else {
 558       host_toolchain = "//build/toolchain/linux:$host_cpu"
 559     }
 560   } else if (host_os == "mac") {
 561     host_toolchain = "//build/toolchain/mac:clang_$host_cpu"
 562   } else {
 563     assert(false, "Unknown host for android cross compile")
 564   }
 565   set_default_toolchain("//build/toolchain/android:$current_cpu")
 566 } else if (is_linux) {
 567   if (is_clang) {
 568     host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
 569     set_default_toolchain("//build/toolchain/linux:clang_$current_cpu")
 570   } else {
 571     host_toolchain = "//build/toolchain/linux:$host_cpu"
 572     set_default_toolchain("//build/toolchain/linux:$current_cpu")
 573   }
 574   if (is_chromeos && cros_use_custom_toolchain) {
 575     set_default_toolchain("//build/toolchain/cros:target")
 576   }
 577 } else if (is_mac) {
 578   host_toolchain = "//build/toolchain/mac:clang_x64"
 579   set_default_toolchain(host_toolchain)
 580 } else if (is_ios) {
 581   host_toolchain = "//build/toolchain/mac:clang_x64"
 582   set_default_toolchain("//build/toolchain/mac:clang_$current_cpu")
 583 } else if (is_nacl) {
 584   # TODO(GYP): This will need to change when we get NaCl working
 585   # on multiple platforms, but this whole block of code (how we define
 586   # host_toolchain) needs to be reworked regardless to key off of host_os
 587   # and host_cpu rather than the is_* variables.
 588   host_toolchain = "//build/toolchain/linux:clang_x64"
 589 }
 590
 591 # ==============================================================================
 592 # COMPONENT SETUP
 593 # ==============================================================================
 594
 595 # TODO(brettw) erase this once the built-in "component" function is removed.
 596 if (is_component_build) {
 597   component_mode = "shared_library"
 598 } else {
 599   component_mode = "source_set"
 600 }
 601
 602 template("component") {
 603   if (is_component_build) {
 604     shared_library(target_name) {
 605       # Configs will always be defined since we set_defaults for a component
 606       # above. We want to use those rather than whatever came with the nested
 607       # shared/static library inside the component.
 608       configs = []  # Prevent list overwriting warning.
 609       configs = invoker.configs
 610
 611       # The sources assignment filter will have already been applied when the
 612       # code was originally executed. We don't want to apply it again, since
 613       # the original target may have override it for some assignments.
 614       set_sources_assignment_filter([])
 615
 616       if (defined(invoker.all_dependent_configs)) {
 617         all_dependent_configs = invoker.all_dependent_configs
 618       }
 619       if (defined(invoker.allow_circular_includes_from)) {
 620         allow_circular_includes_from = invoker.allow_circular_includes_from
 621       }
 622       if (defined(invoker.cflags)) {
 623         cflags = invoker.cflags
 624       }
 625       if (defined(invoker.cflags_c)) {
 626         cflags_c = invoker.cflags_c
 627       }
 628       if (defined(invoker.cflags_cc)) {
 629         cflags_cc = invoker.cflags_cc
 630       }
 631       if (defined(invoker.cflags_objc)) {
 632         cflags_objc = invoker.cflags_objc
 633       }
 634       if (defined(invoker.cflags_objcc)) {
 635         cflags_objcc = invoker.cflags_objcc
 636       }
 637       if (defined(invoker.check_includes)) {
 638         check_includes = invoker.check_includes
 639       }
 640       if (defined(invoker.data)) {
 641         data = invoker.data
 642       }
 643       if (defined(invoker.data_deps)) {
 644         data_deps = invoker.data_deps
 645       }
 646       if (defined(invoker.datadeps)) {
 647         datadeps = invoker.datadeps
 648       }
 649       if (defined(invoker.defines)) {
 650         defines = invoker.defines
 651       }
 652
 653       # All shared libraries must have the sanitizer deps to properly link in
 654       # asan mode (this target will be empty in other cases).
 655       if (defined(invoker.deps)) {
 656         deps = invoker.deps + [ "//build/config/sanitizers:deps" ]
 657       } else {
 658         deps = [
 659           "//build/config/sanitizers:deps",
 660         ]
 661       }
 662       if (defined(invoker.direct_dependent_configs)) {
 663         direct_dependent_configs = invoker.direct_dependent_configs
 664       }
 665       if (defined(invoker.forward_dependent_configs_from)) {
 666         forward_dependent_configs_from = invoker.forward_dependent_configs_from
 667       }
 668       if (defined(invoker.include_dirs)) {
 669         include_dirs = invoker.include_dirs
 670       }
 671       if (defined(invoker.ldflags)) {
 672         ldflags = invoker.ldflags
 673       }
 674       if (defined(invoker.lib_dirs)) {
 675         lib_dirs = invoker.lib_dirs
 676       }
 677       if (defined(invoker.libs)) {
 678         libs = invoker.libs
 679       }
 680       if (defined(invoker.output_extension)) {
 681         output_extension = invoker.output_extension
 682       }
 683       if (defined(invoker.output_name)) {
 684         output_name = invoker.output_name
 685       }
 686       if (defined(invoker.public)) {
 687         public = invoker.public
 688       }
 689       if (defined(invoker.public_configs)) {
 690         public_configs = invoker.public_configs
 691       }
 692       if (defined(invoker.public_deps)) {
 693         public_deps = invoker.public_deps
 694       }
 695       if (defined(invoker.sources)) {
 696         sources = invoker.sources
 697       }
 698       if (defined(invoker.testonly)) {
 699         testonly = invoker.testonly
 700       }
 701       if (defined(invoker.visibility)) {
 702         visibility = invoker.visibility
 703       }
 704     }
 705   } else {
 706     source_set(target_name) {
 707       # See above.
 708       configs = []  # Prevent list overwriting warning.
 709       configs = invoker.configs
 710
 711       # See above call.
 712       set_sources_assignment_filter([])
 713
 714       if (defined(invoker.all_dependent_configs)) {
 715         all_dependent_configs = invoker.all_dependent_configs
 716       }
 717       if (defined(invoker.allow_circular_includes_from)) {
 718         allow_circular_includes_from = invoker.allow_circular_includes_from
 719       }
 720       if (defined(invoker.cflags)) {
 721         cflags = invoker.cflags
 722       }
 723       if (defined(invoker.cflags_c)) {
 724         cflags_c = invoker.cflags_c
 725       }
 726       if (defined(invoker.cflags_cc)) {
 727         cflags_cc = invoker.cflags_cc
 728       }
 729       if (defined(invoker.cflags_objc)) {
 730         cflags_objc = invoker.cflags_objc
 731       }
 732       if (defined(invoker.cflags_objcc)) {
 733         cflags_objcc = invoker.cflags_objcc
 734       }
 735       if (defined(invoker.check_includes)) {
 736         check_includes = invoker.check_includes
 737       }
 738       if (defined(invoker.data)) {
 739         data = invoker.data
 740       }
 741       if (defined(invoker.data_deps)) {
 742         data_deps = invoker.data_deps
 743       }
 744       if (defined(invoker.datadeps)) {
 745         datadeps = invoker.datadeps
 746       }
 747       if (defined(invoker.defines)) {
 748         defines = invoker.defines
 749       }
 750       if (defined(invoker.deps)) {
 751         deps = invoker.deps
 752       }
 753       if (defined(invoker.direct_dependent_configs)) {
 754         direct_dependent_configs = invoker.direct_dependent_configs
 755       }
 756       if (defined(invoker.forward_dependent_configs_from)) {
 757         forward_dependent_configs_from = invoker.forward_dependent_configs_from
 758       }
 759       if (defined(invoker.include_dirs)) {
 760         include_dirs = invoker.include_dirs
 761       }
 762       if (defined(invoker.ldflags)) {
 763         ldflags = invoker.ldflags
 764       }
 765       if (defined(invoker.lib_dirs)) {
 766         lib_dirs = invoker.lib_dirs
 767       }
 768       if (defined(invoker.libs)) {
 769         libs = invoker.libs
 770       }
 771       if (defined(invoker.output_extension)) {
 772         output_extension = invoker.output_extension
 773       }
 774       if (defined(invoker.output_name)) {
 775         output_name = invoker.output_name
 776       }
 777       if (defined(invoker.public)) {
 778         public = invoker.public
 779       }
 780       if (defined(invoker.public_configs)) {
 781         public_configs = invoker.public_configs
 782       }
 783       if (defined(invoker.public_deps)) {
 784         public_deps = invoker.public_deps
 785       }
 786       if (defined(invoker.sources)) {
 787         sources = invoker.sources
 788       }
 789       if (defined(invoker.testonly)) {
 790         testonly = invoker.testonly
 791       }
 792       if (defined(invoker.visibility)) {
 793         visibility = invoker.visibility
 794       }
 795     }
 796   }
 797 }